Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: KMPDTU01

KMPDTU01.m

Go to the documentation of this file. 
  1. KMPDTU01 ;OAK/RAK - CM Tools Timing Utility ;4/6/06  08:40
  1.  ;;3.0;KMPD;;Jan 22, 2009;Build 42
  1.  ;
  1. DAILY(KMPDT) ;-- transmit daily stats to national database
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPDT.... Compression date in internal fileman formt. It represents 
  1.  ;           the date from which the previous days data should be
  1.  ;           transmitted. 
  1.  ;           Example: if KMPDT = 2981011  then tranmission will be
  1.  ;                    on 2981010 (KMPDT-1)
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$G(KMPDT)
  1.  ;
  1.  N DATE,DATA,DELTA,ERROR,FDA,HOUR,I,IEN,PIECE,PTNP,SDTM,SITE,SS
  1.  N STR
  1.  ;
  1.  ; storage  processed
  1.  K ^TMP($J),^TMP("KMPDTU01",$J)
  1.  ; site info.
  1.  S SITE=$$SITE^VASITE Q:SITE=""
  1.  S IEN=0
  1.  W:'$D(ZTQUEUED) !,"Compressing data into daily format..."
  1.  F  S IEN=$O(^KMPD(8973.2,"ADT",KMPDT,IEN)) Q:'IEN  D 
  1.  .Q:'$D(^KMPD(8973.2,IEN,0))  S DATA(0)=^(0)
  1.  .; quit if daily data has already been sent to national database
  1.  .;Q:$P(DATA(0),U,10)
  1.  .W:'$D(ZTQUEUED)&('(IEN#1000)) "."
  1.  .; start date/time      date w/no time    delta
  1.  .S SDTM=$P(DATA(0),U,3),DATE=$P(SDTM,"."),DELTA=$P(DATA(0),U,4)
  1.  .; hour
  1.  .S HOUR=+$E($P(SDTM,".",2),1,2)
  1.  .; quit if no kmptmp subscript
  1.  .S SS=$P(DATA(0),U,7)  Q:SS=""
  1.  .;
  1.  .S PTNP=$$PTNP^KMPDHU03(SDTM) Q:'PTNP
  1.  .; piece 4 - prime time
  1.  .; piece 5 - non-prime time
  1.  .S PIECE=$S(PTNP=1:4,1:5)
  1.  .;
  1.  .S $P(^TMP($J,KMPDT,SS),U)=KMPDT
  1.  .S $P(^TMP($J,KMPDT,SS),U,3)=SS
  1.  .S $P(^TMP($J,KMPDT,SS),U,PIECE)=$P(^TMP($J,KMPDT,SS),U,PIECE)+DELTA
  1.  .S $P(^TMP($J,KMPDT,SS),U,(PIECE+2))=$P(^TMP($J,KMPDT,SS),U,(PIECE+2))+1
  1.  .; hourly delta
  1.  .S $P(^TMP($J,KMPDT,SS,PTNP),U,(HOUR+1))=$P($G(^TMP($J,KMPDT,SS,PTNP)),U,(HOUR+1))+DELTA
  1.  .; hourly occurrences
  1.  .S $P(^TMP($J,KMPDT,SS,PTNP+.1),U,(HOUR+1))=$P($G(^TMP($J,KMPDT,SS,PTNP+.1)),U,(HOUR+1))+1
  1.  .; node 99.1 is for national database (end date^facility name)
  1.  .S ^TMP($J,KMPDT,SS,99.1)=KMPDT_"^"_$P(SITE,U,2)_"^"_$P(SITE,U,3)_"^"_$$WORKDAY^XUWORKDY(DATE)
  1.  .; add to processed array.
  1.  .S ^TMP("KMPDTU01",$J,IEN)=""
  1.  ;
  1.  D:$D(^TMP($J)) TRANSMIT(2)
  1.  K ^TMP($J)
  1.  ;
  1.  ; update field .1 (DAILY - SENT TO CM NATIONAL DB) to 'YES' for all
  1.  ; processed entries.
  1.  W:'$D(ZTQUEUED) !!,"Updating records to reflect transmission..."
  1.  S IEN=0
  1.  F  S IEN=$O(^TMP("KMPDTU01",$J,IEN)) Q:'IEN  D 
  1.  .K FDA,ERROR W:'$D(ZTQUEUED)&('(IEN#1000)) "."
  1.  .S FDA($J,8973.2,IEN_",",.1)=1
  1.  .D FILE^DIE("","FDA($J)","ERROR")
  1.  ;
  1.  K ^TMP("KMPDTU01",$J)
  1.  ;
  1.  W:'$D(ZTQUEUED) !!,"Finished!"
  1.  ;
  1.  Q
  1.  ;
  1. TRANSMIT(KMPDTWD) ;-- format data into e-mail and send to cm national database
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPDTWD... Weekly/Daily
  1.  ;             1 - weekly
  1.  ;             2 - daily
  1.  ;
  1.  ; D = date
  1.  ; S = subscript
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$G(KMPDTWD)
  1.  Q:'$D(^TMP($J))
  1.  ;
  1.  N CPU,D,DATE,I,IEN,LN,S,TL,TRANSTO,XMSUB,X,XMTEXT,XMY,XMZ,Y,Z
  1.  ;
  1.  K ^TMP("KMPDTU01-2",$J)
  1.  ;
  1.  S DATE=$S(KMPDTWD=1:$G(START),1:$G(KMPDT))
  1.  S LN=0
  1.  ; version and patch info
  1.  S LN=LN+1,^TMP("KMPDTU01-2",$J,LN)="VERSION="_$$VERSION^KMPDUTL
  1.  ; system information
  1.  S LN=LN+1,^TMP("KMPDTU01-2",$J,LN)="SYSINFO="_$$SYSINFO^KMPDUTL1()
  1.  ; send cpu data to national database
  1.  D CPU^KMPDUTL5(.CPU) I $D(CPU) S I="" F  S I=$O(CPU(I)) Q:I=""  D 
  1.  .S LN=LN+1,^TMP("KMPDTU01-2",$J,LN)="CPU="_I_U_CPU(I)
  1.  ;
  1.  W:'$D(ZTQUEUED) !!,"Formatting ",$$FMTE^XLFDT($G(START))," data for mail delivery..."
  1.  ; reformat so that data is in ^TMP("KMPR UPLOAD",$J,LN)= format.
  1.  S IEN=0,D=""
  1.  F  S D=$O(^TMP($J,D)) Q:D=""  S S="" W "." D 
  1.  .W !,D
  1.  .F  S S=$O(^TMP($J,D,S)) Q:S=""  D 
  1.  ..S IEN=IEN+1,LN=LN+1
  1.  ..S ^TMP("KMPDTU01-2",$J,LN)=IEN_",0)="_^TMP($J,D,S)
  1.  ..; if prime time
  1.  ..I $D(^TMP($J,D,S,1)) D 
  1.  ...S LN=LN+1
  1.  ...S ^TMP("KMPDTU01-2",$J,LN)=IEN_",1)="_^TMP($J,D,S,1)
  1.  ...S LN=LN+1
  1.  ...S ^TMP("KMPDTU01-2",$J,LN)=IEN_",1.1)="_^TMP($J,D,S,1.1)
  1.  ..; if non-prime time
  1.  ..I $D(^TMP($J,D,S,2)) D 
  1.  ...S LN=LN+1
  1.  ...S ^TMP("KMPDTU01-2",$J,LN)=IEN_",2)="_^TMP($J,D,S,2)
  1.  ...S LN=LN+1
  1.  ...S ^TMP("KMPDTU01-2",$J,LN)=IEN_",2.1)="_^TMP($J,D,S,2.1)
  1.  ..; node 99.1 for national database
  1.  ..S LN=LN+1,^TMP("KMPDTU01-2",$J,LN)=IEN_",99.1)="_$G(^TMP($J,D,S,99.1))
  1.  ;
  1.  ; quit if no data to transmit.
  1.  Q:'$D(^TMP("KMPDTU01-2",$J))
  1.  S TL=$$TESTLAB^KMPDUT1
  1.  ; send packman message.
  1.  S XMTEXT="^TMP(""KMPDTU01-2"","_$J_","
  1.  S XMSUB=$S(KMPDTWD=1:"CM TIMING DATA~",1:"CM TIMING DATA-DAILY~")_$P(TL,U,2)_$P(SITE,U,2)_" ("_$P(SITE,U,3)_")~"_$$FMTE^XLFDT(DATE,2)
  1.  D TRANSTO^KMPDUTL7(1,4,.TRANSTO) Q:'$D(TRANSTO)
  1.  S I=""
  1.  F  S I=$O(TRANSTO(I)) Q:I=""  S XMY(I)=""
  1.  D ^XMD
  1.  W:'$D(ZTQUEUED) !,"Message #",$G(XMZ)," sent..."
  1.  K ^TMP("KMPDTU01-2",$J)
  1.  ;
  1.  Q