Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: KMPDU11

KMPDU11.m

Go to the documentation of this file. 
  1. KMPDU11 ;OAK/RAK - CM Tools Text Display Utility ;2/17/04  09:50
  1.  ;;3.0;KMPD;;Jan 22, 2009;Build 42
  1.  ;
  1. WP(KMPUAR,KMPUTM,KMPUBM,KMPULM,KMPURM,KMPUNW,KMPUXIT) ;-- word processing display.
  1.  ;--------------------------------------------------------------------
  1.  ; KMPUAR...  Array containing word processing text.
  1.  ;            Example: ^KMPUTMP(1001,1,0)="This is the"
  1.  ;                     ^KMPUTMP(1001,2,0)="text to display."
  1.  ;
  1.  ;  Optional parameters:
  1.  ;
  1.  ; KMPUTM.. Top margin of screen area.
  1.  ; KMPUBM.. Bottom margin of screen area.
  1.  ; KMPULM.. Left margin.
  1.  ; KMPURM.. Right margin.
  1.  ; KMPUNW.. Nowrap:
  1.  ;           0 - nowrap (print as entered)
  1.  ;           1 - wrap
  1.  ; KMPUXIT. Exit without 'continue' text.  This allows the programmer
  1.  ;          to use their own display for continuing
  1.  ;           0 - do not exit - display 'continue' text
  1.  ;           1 - exit
  1.  ;
  1.  ; If more than one page this routine allows the user to scroll back
  1.  ; and forth between pages. If KMPUTM and KMPUBM are not passed will
  1.  ; default to full screen (0 to 22).
  1.  ;--------------------------------------------------------------------
  1.  ;
  1.  Q:'$D(KMPUAR)
  1.  ;
  1.  N CLRSCR,I,KMPUI,KMPUOUT,LEN,LINES,PAGE,PAGES
  1.  N DIR,DIW,DIWF,DIWI,DIWL,DIWR,DIWT,DIWTC,DIWX,X,Y,Z
  1.  N IOBM,IOECH,IOELALL,IOELEOL,IORVON,IORVOFF,IOTM,IOSTBM
  1.  ;
  1.  S KMPUXIT=+$G(KMPUXIT)
  1.  S KMPUTM=+$G(KMPUTM),KMPUBM=$S(+$G(KMPUBM):KMPUBM,1:22)
  1.  S KMPULM=+$G(KMPULM),KMPURM=+$G(KMPURM),KMPUNW=+$G(KMPUNW)
  1.  S:KMPUBM>22 KMPUBM=22 S DIWL=KMPULM,DIWR=$S(KMPURM:KMPURM,1:IOM)
  1.  S KMPUNW=$S(KMPUNW=1:"",1:"N")
  1.  S X="IOECH;IOELALL;IOELEOL;IORVON;IORVOFF;IOSTKMPUBM" D ENDR^%ZISS
  1.  ; set CLRSCR (clear screen) 
  1.  ; clear full screen
  1.  I DIWL=0,(DIWR=IOM) D 
  1.  .S CLRSCR="F DY=(KMPUBM-1):-1:KMPUTM X IOXY W IOELALL,!"
  1.  ; clear left margin to end of screen
  1.  E  I DIWR=IOM D 
  1.  .S CLRSCR="S DX=DIWL F DY=(KMPUBM-1):-1:KMPUTM X IOXY W IOELEOL,!"
  1.  ; clear left margin to right margin
  1.  E  S CLRSCR="F DY=(KMPUBM-1):-1:KMPUTM F DX=DIWL:1:DIWR X IOXY W IOECH"
  1.  K ^UTILITY($J,"W") S DIWF=KMPUNW,X=""
  1.  ; use fileman to format text
  1.  F KMPUI=0:0 S KMPUI=$O(@KMPUAR@(KMPUI)) Q:'KMPUI  D 
  1.  .Q:'$D(@KMPUAR@(KMPUI,0))  S X=@KMPUAR@(KMPUI,0) D ^DIWP
  1.  Q:'$D(^UTILITY($J,"W",DIWL))  S LINES=$G(^(DIWL))
  1.  ; check for last line equal to null
  1.  I $G(^UTILITY($J,"W",DIWL,LINES,0))="" S LINES=LINES-1
  1.  S LEN=KMPUBM-KMPUTM,PAGES=LINES\LEN I LINES#LEN S PAGES=PAGES+1
  1.  ;
  1.  ; set up the pages() array -  first piece = starting line
  1.  ;                            second piece = ending line
  1.  F I=1:1:PAGES D 
  1.  .S PAGES(I)=$S(I=1:1,1:(I*LEN-LEN+1))
  1.  .I I=1 S $P(PAGES(I),U,2)=$S(LINES<LEN:LINES,1:LEN) Q
  1.  .S $P(PAGES(I),U,2)=(I*LEN)
  1.  S DY=(KMPUTM-1),PAGE=1,KMPUOUT=0
  1.  ; main loop
  1.  F  D  Q:KMPUOUT
  1.  .F KMPUI=$P(PAGES(PAGE),U):1:$P(PAGES(PAGE),U,2) D 
  1.  ..Q:'$D(^UTILITY($J,"W",DIWL,KMPUI,0))
  1.  ..S DX=DIWL,DY=DY+1 X IOXY W ^UTILITY($J,"W",DIWL,KMPUI,0),!
  1.  .I 'KMPUXIT D FTR X CLRSCR Q:KMPUOUT  S DY=DY-1
  1.  .E  S KMPUOUT=1
  1.  F DY=22,23 X IOXY W IOELALL
  1.  K ^UTILITY($J,"W")
  1.  Q
  1.  ;
  1. FTR ;-- footer designed for wp subroutine above.
  1.  N READ,READX S READ=""
  1.  S DX=0,DY=22 X IOXY W $$REPEAT^XLFSTR("_",IOM)
  1.  I PAGES=1 S READ="X",READ("A")=$J(" ",28)_"Press <RET> to continue"
  1.  I PAGES>1 S READ="X",READ("A")="E[x]it" D 
  1.  .I PAGE<PAGES S READ=READ_"N",READ("A")=READ("A")_", [N]ext Screen"
  1.  .I PAGE>1 S READ=READ_"P",READ("A")=READ("A")_", [P]revious Screen"
  1.  S READ("A")=READ("A")_": "
  1. FTR1 ;-- read
  1.  S DX=0,DY=23 X IOXY W IOELALL
  1.  S DX=62 X IOXY W " Page ",PAGE," of ",PAGES," "
  1.  S DX=0 X IOXY W READ("A")
  1.  R READX:DTIME S READX=$$UP^XLFSTR(READX)
  1.  I READX="X"!(READX="^")!(READ="X") S KMPUOUT=1 Q
  1.  I READX="N",(READ["N") S PAGE=PAGE+1 Q
  1.  I READX="P",(READ["P") S PAGE=PAGE-1 Q
  1.  I READX["?" D HELP G FTR1
  1.  W *7
  1.  G FTR1
  1.  ;
  1. HELP ;-- clear screen, print help text, repaint screen.
  1.  N I,READX X CLRSCR S DY=KMPUTM,DX=$S(DIWL>7:DIWL,1:7) X IOXY
  1.  F I=1:1:$L(READ) S DY=DY+1 X IOXY D 
  1.  .I $E(READ,I)="X" W "Enter 'X' (or '^') to exit.",!
  1.  .I $E(READ,I)="N" W "Enter 'N' to advance to the next screen.",!
  1.  .I $E(READ,I)="P" W "Enter 'P' to backup to the previous screen.",!
  1.  S DY=(KMPUBM-1) X IOXY R "Press <RET> to continue: ",READX:DTIME
  1.  ; repaint screen.
  1.  X CLRSCR S DY=(KMPUTM-1)
  1.  F I=$P(PAGES(PAGE),U):1:$P(PAGES(PAGE),U,2) D 
  1.  .Q:'$D(^UTILITY($J,"W",DIWL,I,0))
  1.  .S DX=DIWL,DY=DY+1 X IOXY W ^UTILITY($J,"W",DIWL,I,0),!
  1.  Q