Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: KMPDUTL8

KMPDUTL8.m

Go to the documentation of this file. 
  1. KMPDUTL8 ;OAK/RAK - CM Tools Utility ;2/17/04  10:52
  1.  ;;3.0;KMPD;;Jan 22, 2009;Build 42
  1.  ;
  1. ADD(KMPDNAME,KMPDARRY,KMPDIEN) ;-- add new entry to file #8972.1
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPDNAME... Field #.01 (free text).
  1.  ; KMPDARRY(). Array containing data to file in format (passed by value):
  1.  ;               KMPDARRY(FieldNumber)=InternalEntryValue.
  1.  ;               Example: KMPDARRY(.02)=2990719.1001
  1.  ;                        KMPDARRY(.03)=12345
  1.  ;                        KMPDARRY(.04)="1290"
  1.  ;                        KMPDARRY(...)="..."
  1.  ;                        KMPDARRY(10,1,0)="This contains word"
  1.  ;                        KMPDARRY(10,2,0)="processing text for the"
  1.  ;                        KMPDARRY(10,3,0)="COMMENTS field."
  1.  ; KMPDIEN... New ien for entry (if not successful KMPDIEN will be null).
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:$G(KMPDNAME)=""
  1.  ; convert disallowed characters.
  1.  S KMPDNAME=$$CONVERT^KMPDUTL7(KMPDNAME)
  1.  Q:KMPDNAME=""
  1.  ;
  1.  N FDA,I,MESSAGE,ZIEN
  1.  ; name.
  1.  S FDA($J,8972.1,"+1,",.01)=KMPDNAME
  1.  ; additional fields.
  1.  F I=.02:.01:.09 I $G(@KMPDARRY@(I))'="" D 
  1.  .S FDA($J,8972.1,"+1,",I)=@KMPDARRY@(I)
  1.  ; 'comments' word-processing field.
  1.  S:$O(@KMPDARRY@(10,0)) FDA($J,8972.1,"+1,",10)=KMPDARRY_"(10)"
  1.  ;
  1.  ; update file 8971.1.
  1.  D UPDATE^DIE("","FDA($J)","ZIEN","MESSAGE")
  1.  S KMPDIEN=$G(ZIEN(1)) Q:'KMPDIEN
  1.  ; if error message.
  1.  I $D(MESSAGE) D MSG^DIALOG("W","",60,10,"MESSAGE")
  1.  ;
  1.  Q
  1.  ;
  1. EDIT(KMPDIEN,KMPDARRY) ;-- edit entry in file #8972.1
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPDIEN... Ien for file #8972.1 (CM CODE EVALUATOR)
  1.  ; KMPDARRY(). Array containing data to file in format (passed by value):
  1.  ;               KMPDARRY(FieldNumber)=InternalEntryValue.
  1.  ;               Example: KMPDARRY(.02)=2990719.1001
  1.  ;                        KMPDARRY(.03)=12345
  1.  ;                        KMPDARRY(.04)="1290"
  1.  ;                        KMPDARRY(...)="..."
  1.  ;                        KMPDARRY(10,1,0)="This contains word"
  1.  ;                        KMPDARRY(10,2,0)="processing text for the"
  1.  ;                        KMPDARRY(10,3,0)="COMMENTS field."
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$G(KMPDIEN)
  1.  Q:'$D(^KMPD(8972.1,+KMPDIEN,0))#5
  1.  Q:$G(KMPDARRY)=""
  1.  ;
  1.  N DATA,FDA,I,MESSAGE,ZIEN
  1.  ;
  1.  ; data already stored for this entry
  1.  S DATA(0)=$G(^KMPD(8972.1,+KMPDIEN,0))
  1.  ;
  1.  ; date/time last edited
  1.  S FDA($J,8972.1,KMPDIEN_",",2.01)=$$NOW^XLFDT
  1.  ;
  1.  ; last edited by
  1.  S:$G(DUZ) FDA($J,8972.1,KMPDIEN_",",2.02)=DUZ
  1.  ;
  1.  ; add data elements to current data
  1.  F I=.04:.01:.09 D 
  1.  .S FDA($J,8972.1,KMPDIEN_",",I)=@KMPDARRY@(I)+$P(DATA(0),U,(I*100))
  1.  .; make sure not negative number
  1.  .S FDA($J,8972.1,KMPDIEN_",",I)=$$NUMBER^KMPDUTL7(FDA($J,8972.1,KMPDIEN_",",I))
  1.  .; if number has grown to 15 characters or more then make this code
  1.  .; evaluator inactive
  1.  .S:$L(FDA($J,8972.1,KMPDIEN_",",I))>14 FDA($J,8971.1,KMPDIEN_",",.11)=0
  1.  ;
  1.  ; increment count
  1.  S FDA($J,8972.1,KMPDIEN_",",.1)=$P(DATA(0),U,10)+1
  1.  ;
  1.  ; 'comments' word-processing field.
  1.  S:$O(@KMPDARRY@(10,0)) FDA($J,8972.1,KMPDIEN_",",10)=KMPDARRY_"(10)"
  1.  ;
  1.  ; update file 8971.1.
  1.  D UPDATE^DIE("","FDA($J)","ZIEN","MESSAGE")
  1.  ;
  1.  S KMPDIEN=$G(ZIEN(1)) Q:'KMPDIEN
  1.  ;
  1.  ; if error message.
  1.  I $D(MESSAGE) D MSG^DIALOG("W","",60,10,"MESSAGE")
  1.  ;
  1.  Q
  1.  ;
  1. ID(KMPDIEN) ;-- display fields during lookup
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPDIEN.... Ien for file #8972.1.
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$D(^KMPD(8972.1,+$G(KMPDIEN),0))
  1.  ;
  1.  N DATA,TXT
  1.  S DATA=$G(^KMPD(8972.1,+KMPDIEN,0))
  1.  S TXT(1)=$$FMTE^DILIBF($P(DATA,U,2),6)
  1.  S TXT(1)=TXT(1)_"   "_$$GET1^DIQ(8972.1,KMPDIEN,.03)
  1.  S TXT(1,"F")="?35"
  1.  S TXT(2)="cpu tm="_$P(DATA,U,4)_"  dio ref="_$P(DATA,U,5)_"  "
  1.  S TXT(2)=TXT(2)_"bio ref="_$P(DATA,U,6)_"  page flts="_$P(DATA,U,7)_"  "
  1.  S TXT(2)=TXT(2)_"m com="_$P(DATA,U,8)_"  global ref="_$P(DATA,U,9)
  1.  S TXT(2,"F")="!?5",TXT(3)="",TXT(3,"F")="!"
  1.  D EN^DDIOL(.TXT)
  1.  ;
  1.  Q
  1.  ;
  1. ELEDATA(KMPDIEN) ;-- extrinsic function - if element data
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPDIEN... Ien for file #8972.1 (CM CODE EVALUATOR)
  1.  ;
  1.  ; Return: 0 - element data is NOT present
  1.  ;         1 - element data is present
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$G(KMPDIEN) 0
  1.  Q:'$D(^KMPD(8972.1,+KMPDIEN,0))#5 0
  1.  ;
  1.  N DATA,I,RETURN
  1.  S DATA(0)=$G(^KMPD(8972.1,+KMPDIEN,0))
  1.  S RETURN=1
  1.  F I=4,5,6,8,9 I $P(DATA(0),U,I)']"" S RETURN=0 Q
  1.  Q RETURN