Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: KMPRUTL3

KMPRUTL3.m

Go to the documentation of this file. 
  1. KMPRUTL3 ;OAK/RAK - Resource Usage Monitor Utilities ;5/28/03  09:16
  1.  ;;2.0;CAPACITY MANAGEMENT - RUM;;May 28, 2003
  1.  ;
  1. HRSDAYS(KMPRSDT,KMPREDT,KMPRKILL,KMPRRES) ;
  1.  ;-- number of days/hours in the date range
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPRSDT.. Start Date in internal fileman format
  1.  ; KMPREDT.. End Date in internal fileman format
  1.  ; KMPRKILL. Kill node after processing: 
  1.  ;              0 - do not kill
  1.  ;              1 - kill
  1.  ; KMPRRES.. Array (passed by reference) containing days/hours info
  1.  ;           in format: KMPRRES(KMPRSDT,Node)=Data 
  1.  ;              Where Data equals for the specified date range:
  1.  ;              '^' Piece 1 - Prime Time Days
  1.  ;              '^' Piece 2 - Prime Time Hours
  1.  ;              '^' Piece 3 - Non-Prime Time Days
  1.  ;              '^' Piece 4 - Non-Prime Time Hours
  1.  ;              '^' Piece 5 - Workday Days
  1.  ;              '^' Piece 6 - Workday Hours
  1.  ;              '^' Piece 7 - Non-Workday Days
  1.  ;              '^' Piece 8 - Non-Workday Hours
  1.  ;           Example for the specified date range:
  1.  ;              KMPRRES(3030418,"999A01")=5^45^7^123^5^120^2^48
  1.  ;              KMPRRES(3030418,"999A02")=5^40^7^120^5^110^2^45 <=partial
  1.  ;              KMPRRES(3030418,"999A03")=5^45^7^123^5^120^2^48
  1.  ;              KMPRRES(  ...  ,   ...  )=...
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  K KMPRRES
  1.  ;
  1.  Q:'$G(KMPRSDT)
  1.  Q:'$G(KMPREDT)
  1.  S KMPRKILL=+$G(KMPRKILL)
  1.  ;
  1.  N DATA,DATE,DAYS,HOURS,I,NODE
  1.  ;
  1.  D HOURS(KMPRSDT,KMPREDT,KMPRKILL,.HOURS)
  1.  Q:'$D(HOURS)
  1.  ;
  1.  S NODE=""
  1.  F  S NODE=$O(HOURS(NODE)) Q:NODE=""  D
  1.  .S (DATE,DAYS,HOURS)=0
  1.  .F  S DATE=$O(HOURS(NODE,DATE)) Q:'DATE  D
  1.  ..;
  1.  ..; piece 1 - prime time hours per day
  1.  ..; piece 2 - non-prime time hours per day
  1.  ..; piece 3 - workday hours per day
  1.  ..; piece 4 - non-workday hours per day
  1.  ..S DATA=HOURS(NODE,DATE)
  1.  ..;
  1.  ..F I=1:1:4 D
  1.  ...; total hours for the specified date range
  1.  ...S $P(HOURS,U,I)=$P(HOURS,U,I)+$P(DATA,U,I)
  1.  ...; if current day has hours then increment total days for the
  1.  ...; specified date range
  1.  ...S:$P(DATA,U,I) $P(DAYS,U,I)=$P(DAYS,U,I)+1
  1.  .;
  1.  .; back to NODE level
  1.  .S KMPRRES(KMPRSDT,NODE)=$P(DAYS,U)_"^"_$P(HOURS,U)_"^"_$P(DAYS,U,2)_"^"_$P(HOURS,U,2)_"^"_$P(DAYS,U,3)_"^"_$P(HOURS,U,3)_"^"_$P(DAYS,U,4)_"^"_$P(HOURS,U,4)
  1.  ;
  1.  Q
  1.  ;
  1. HOURS(KMPRSDT,KMPREDT,KMPRKILL,KMPRRES) ;
  1.  ;-- determine prime time & non-prime time hours per day
  1.  ;-- determine workday & non-workday hours per day
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPRSDT.. Start Date in internal fileman format
  1.  ; KMPREDT.. End Date in internal fileman format
  1.  ; KMPRKILL. Kill node after processing: 
  1.  ;              0 - do not kill
  1.  ;              1 - kill
  1.  ; KMPRRES.. Array (passed by reference) containing hours info
  1.  ;           in format: KMPRRES(Date,Node)=Data 
  1.  ;              Where Data equals:
  1.  ;              '^' Piece 1 - Prime Time Hours per day
  1.  ;              '^' Piece 2 - Non-Prime Time Hours per day
  1.  ;              '^' Piece 3 - Workday Hours per day
  1.  ;              '^' Piece 4 - Non-Workday Hours per day
  1.  ;           Example:
  1.  ;              KMPRRES(3030418,"999A01")=9^15^24^0  <= Friday
  1.  ;              KMPRRES(3030418,"999A02")=4^10^14^0  <= Friday (partial)
  1.  ;              KMPRRES(3030419,"999A01")=0^24^0^24  <= Saturday   
  1.  ;              KMPRRES(  ...  ,   ...  )= ...
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  K KMPRRES
  1.  ;
  1.  Q:'$G(KMPRSDT)
  1.  Q:'$G(KMPREDT)
  1.  S KMPRKILL=+$G(KMPRKILL)
  1.  ;
  1.  N DATA,DATE,DOW,END,HOURS,HRS,I,NODE,PIECE,WORKDAY
  1.  ;
  1.  ; end date
  1.  S END=KMPREDT
  1.  S DATE=KMPRSDT-.1,(DAYS,HOURS)=""
  1.  F  S DATE=$O(^KMPTMP("KMPR","HOURS",DATE)) Q:'DATE!(DATE>END)  D
  1.  .;
  1.  .Q:DATE<KMPRSDT!(DATE>END)
  1.  .;
  1.  .S NODE="",DOW=$$DOW^XLFDT(DATE,1),WORKDAY=$$WORKDAY^XUWORKDY(DATE)
  1.  .;
  1.  .; prime time (8am to 5pm)
  1.  .; if not saturday or sunday or holiday then prime time (piece 1)
  1.  .; if saturday or sunday then non-prime time (piece 2)
  1.  .S PIECE=$S(DOW'=0&(DOW'=6)&('$G(^HOLIDAY(DATE,0))):1,1:2)
  1.  .;
  1.  .F  S NODE=$O(^KMPTMP("KMPR","HOURS",DATE,NODE)) Q:NODE=""  D
  1.  ..S DATA=$G(^KMPTMP("KMPR","HOURS",DATE,NODE)) Q:DATA=""
  1.  ..S (HOURS,HRS)=0
  1.  ..;
  1.  ..;*** times are offset by 1  so zero hour is in piece 1
  1.  ..;***                            one hour is in piece 2
  1.  ..;***                            two hour is in piece 3
  1.  ..;***                            etc.
  1.  ..;
  1.  ..; prime time hours
  1.  ..F I=9:1:17 S HRS=HRS+$P(DATA,U,I)
  1.  ..S $P(HOURS,U,PIECE)=$P(HOURS,U,PIECE)+HRS
  1.  ..;
  1.  ..; non-prime time hours
  1.  ..S HRS=0
  1.  ..F I=1:1:8,18:1:24 S HRS=HRS+$P(DATA,U,I)
  1.  ..S $P(HOURS,U,2)=$P(HOURS,U,2)+HRS
  1.  ..;
  1.  ..; workday, non-workday hours
  1.  ..S HRS=0
  1.  ..F I=1:1:24 S HRS=HRS+$P(DATA,U,I)
  1.  ..I WORKDAY S $P(HOURS,U,3)=$P(HOURS,U,3)+HRS
  1.  ..E  S $P(HOURS,U,4)=$P(HOURS,U,4)+HRS
  1.  ..;
  1.  ..S KMPRRES(NODE,DATE)=HOURS
  1.  ..;
  1.  ..K:KMPRKILL ^KMPTMP("KMPR","HOURS",DATE,NODE)
  1.  ;
  1.  Q
  1.  ;
  1. PURGE(KMPRDDT,KMPRHRS) ;-- purge data in file #8971.1
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPRDDT.. Date to begin purge in internal fileman format. Purge will
  1.  ;           reverse $order and delete entries 'EARLIER' than KMPRDDT.
  1.  ; KMPRHRS.. Purge Hours/Days data from ^KMPTMP("KMPR","HOURS". Entries
  1.  ;           'EARLIER' than KMPRDDT will be deleted.
  1.  ;           0 - do not purge hours/days data.
  1.  ;           1 - purge hours/days data.
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$G(KMPRDDT)
  1.  S KMPRHRS=+$G(KMPRHRS)
  1.  ;
  1.  N DA,DATE,DIK,IEN
  1.  D:'$D(ZTQUEUED) EN^DDIOL("Deleting old records...")
  1.  S DATE=KMPRDDT
  1.  F  S DATE=$O(^KMPR(8971.1,"B",DATE),-1) Q:'DATE!(DATE>KMPRDDT)  D 
  1.  .F IEN=0:0 S IEN=$O(^KMPR(8971.1,"B",DATE,IEN)) Q:'IEN  D 
  1.  ..; delete if no zero node
  1.  ..I '$D(^KMPR(8971.1,IEN,0)) K ^KMPR(8971.1,"B",DATE,IEN) Q
  1.  ..; quit if not 'sent to cm database'.
  1.  ..Q:$P($G(^KMPR(8971.1,IEN,0)),U,2)=0
  1.  ..; Delete entry.
  1.  ..S DA=IEN,DIK="^KMPR(8971.1," D ^DIK
  1.  ;
  1.  Q:'KMPRHRS
  1.  D:'$D(ZTQUEUED) EN^DDIOL("Deleting old entries from ^KMPTMP(""KMPR"",""HOURS""...")
  1.  S DATE=KMPRDDT
  1.  F  S DATE=$O(^KMPTMP("KMPR","HOURS",DATE),-1) Q:'DATE!(DATE>KMPRDDT)  D 
  1.  .K ^KMPTMP("KMPR","HOURS",DATE)
  1.  ;
  1.  Q