Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7DVM

LA7DVM.m

Go to the documentation of this file. 
  1. LA7DVM ;SFCIOFO/MJM/DALOI/PWC - EXTRACTION ROUTINE FOR VERIFIED "MI" LAB RESULTS TO CAREVUE&LIFELOG;01/14/2000
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**53,58,62**;Sep 27, 1994
  1.  ;
  1.  ; Reference to ^DPT( supported by DBIA #10035
  1.  ; Reference to ^%DTC supported by DBIA #10000
  1.  ; Reference to ^DIC supported by DBIA #10006
  1.  ; Reference to INIT^HLFNC2 supported by DBIA #2161
  1.  ; Reference to GENERATE^HLMA supported by DBIA #2164
  1.  ; Reference to DEM^VADPT supported by DBIA #10061
  1.  ; Reference to $$EN^VAFHLPID supported by DBIA #263
  1.  ; Reference to $$FMTHL7^XLFDT supported by DBIA #10103
  1.  ; Reference to ^XMD supported by DBIA #10070
  1.  ;
  1. EN ;ENTRY POINT FROM VERIFICATION PROCESS
  1.  N I
  1.  S DFN=$P(^LR(LRDFN,0),"^",3)
  1.  S GMTS1=9999999-LRIDT,GMTS2=9999999-LRIDT,VFLAG=1 D DEM^VADPT
  1.  D INIT,RR^LR7OR1(DFN,,GMTS1,GMTS2,"MI"),HL7
  1.  K ^TMP("LRRR",$J),DFN,EXPAND,NXREC,MAX,SEX
  1.  Q
  1.  ;
  1. INIT ;Set up needed variables
  1.  S NXREC=0,MAX=75,EXPAND=1,SEX=$P(VADM(5),"^",1)
  1.  Q
  1.  ;
  1. HL7 ; Build the HL7 message and send to the Ward.
  1.  K HL,HLA,HLP,HLRESLT  ; Clean the enviroment
  1.  S DIC="^ORD(101,",DIC(0)="MNOZ",X="LA7D CARELIFE SERVER" D ^DIC
  1.  I Y=-1 S TEXT="Unable to send out test result to CAREVUE, Protocol Server is not setup" K Y,DIC D ERROR Q
  1.  S LA7DVEID=+Y  ; Server Protocol IEN
  1.  K Y,DIC
  1.  D INIT^HLFNC2(LA7DVEID,.HL)
  1.  I $G(HL) S TEXT="Unable to send out test result to CAREVUE, Protocol Server is downed" D ERROR Q
  1.  N COUNT
  1.  S LA7DVTYP="LM",LA7DVFMT=1
  1.  S HLFS=$E(HL("FS")),Z=$E(HL("ECH"),1),COUNT=1,S=HLFS
  1.  S HLA("HLS",COUNT)=$$EN^VAFHLPID(DFN,"2,3,5,7,8,19")
  1.  S HOLD=COUNT+1  ;  Hold the space for OBR segment
  1.  S COUNT=COUNT+2,LA7DVTXT=""
  1.  ; Start the NTE segment
  1.  F  S LA7DVTXT=$O(^TMP("LRRR",$J,DFN,"MI",LRIDT,"N",LA7DVTXT)) Q:LA7DVTXT=""  D
  1.  . S HLA("HLS",COUNT)="NTE"_HLFS_HLFS_"L"_HLFS_^TMP("LRRR",$J,DFN,"MI",LRIDT,"N",LA7DVTXT)
  1.  . S COUNT=COUNT+1
  1.  ; Start the OBX segment
  1.  S (OBX,LA7DVSCR)=""
  1.  F  S OBX=$O(^TMP("LRRR",$J,DFN,"MI",LRIDT,OBX)) Q:+OBX=0  D
  1.  . S LA7DVOBX=^TMP("LRRR",$J,DFN,"MI",LRIDT,OBX)
  1.  . S LINE1="OBX"_HLFS_HLFS_"TX"_HLFS_"TX"_HLFS_HLFS_$P(LA7DVOBX,"^",2)_HLFS_HLFS
  1.  . S HLA("HLS",COUNT)=LINE1_HLFS_HLFS_HLFS_HLFS
  1.  . S COUNT=COUNT+1
  1.  . K LINE1
  1.  ; Start the OBR segment
  1.  S LA7DVTMP=0,LA7DVTMP=$O(^LR(LRDFN,"MI",LA7DVTMP)) ; Get the first entry of this collection
  1.  S SITE=$P(^LR(LRDFN,"MI",LA7DVTMP,0),"^",5),LA7DVSCR=$P(^LAB(61,SITE,0),"^",1)
  1.  ; change all $$HLDATE^HLFNC calls to $$FMTHL7^XLFDT   pwc-10/6/2000
  1.  S LA7DVCOL=$$FMTHL7^XLFDT($P(^LR(LRDFN,"MI",LA7DVTMP,0),"^"))  ; Get theCollection date/time
  1.  S LA7DVRCV=$$FMTHL7^XLFDT($P(^LR(LRDFN,"MI",LA7DVTMP,0),"^",10)) ; Get the Specimen Received Date/time
  1.  S LA7DVRCP=$$FMTHL7^XLFDT($P(^LR(LRDFN,"MI",LA7DVTMP,0),"^",3))  ; Get the Report Complete Date/time
  1.  S LA7DVACC=$P(^LR(LRDFN,"MI",LA7DVTMP,0),"^",6)  ; Get the Accession #
  1.  S HLA("HLS",HOLD)="OBR"_HLFS_HLFS_HLFS_LA7DVACC_HLFS_"MI"
  1.  S $P(HLA("HLS",HOLD),HLFS,8)=LA7DVCOL
  1.  S $P(HLA("HLS",HOLD),HLFS,15,16)=LA7DVRCV_HLFS_LA7DVSCR
  1.  S $P(HLA("HLS",HOLD),HLFS,23,29)=LA7DVRCP_S_S_"LAB"_S_S_S_S_LA7DVL
  1.  S HLP("NAMESPACE")="LA"
  1.  D GENERATE^HLMA(LA7DVEID,LA7DVTYP,LA7DVFMT,.HLRESLT,"",.HLP)
  1.  I $P(HLRESLT,"^",2) D ERROR
  1.  K LA7DVRCP,LA7DVSCR,HOLD,LA7DVCOL,LA7DVACC,LA7DVTMP,LA7DVOBX,COUNT
  1.  K LA7DVTXT,LA7DVFMT,LA7DVEID,LA7DVTYP,OBX,GMTS1,GMTS2,HLFS,HLP,HLRESLT
  1.  K LA7DVRCV,LRSPEC,S,SITE,SPEC,TEXT,VADM,VAIN,VFLAG,XMDT
  1.  K XMDUZ,XMSUB,XMTEXT,XMY,Z
  1.  Q
  1. ERROR ; Send out error message when HL7 fail to build the message
  1.  D INP^VADPT
  1.  S XMSUB="ERROR IN SENDING LAB RESULTS TO "_$P(VAIN(4),"^",2)_" WARD"
  1.  D NOW^%DTC S XMDT=X K X
  1.  S XMDUZ=.5,XMY("G.CARELIFE RESULT ERROR")=""
  1.  S A(1)="There was an error in building an HL7 Lab Result Message for accession"
  1.  I LA7DVACC'="" D
  1.  . S A(2)=" # "_LA7DVACC_"of patient name: "_$P(^DPT(DFN,0),"^")_" at "_$P(VAIN(4),"^",2)_" Ward."
  1.  . S A(3)="The error was "_$P(HLRESLT,"^",3)_"."
  1.  E  D
  1.  . S A(2)="The error was "_TEXT_"."
  1.  . S A(3)=""
  1.  S A(4)="Please make a note of it and take any actions that necessary"
  1.  S XMTEXT="A(" D ^XMD
  1.  K A
  1.  Q