Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LRBEPEND

LRBEPEND.m

Go to the documentation of this file. 
  1. LRBEPEND ;DALOI/JAH/FHS - PENDING PANEL REPORT ;11/26/2005
  1.  ;;5.2;LAB SERVICE;**291,337**;Sep 27, 1994;Build 2
  1.  ;
  1. EN ;Entry point from menu option LRBE PENDREP
  1.  N ZTDESC,ZTIO,ZTRTN,ZTSAVE,ZTSK
  1.  S ZTRTN="TASK^LRBEPEND"
  1.  S ZTDESC="Lab Report on Pending AMA/Billable Panels"
  1.  S ZTIO=""
  1.  S ZTSAVE("DUZ")=""
  1.  W !!,"This report option must be queued via TaskManager."
  1.  W !,"The report will be sent to you as a MailMan message.",!
  1.  D ^%ZTLOAD
  1.  I $G(ZTSK) D
  1.  .W !,"Report queued as Task #: ",ZTSK
  1.  W !
  1.  Q
  1.  ;
  1. TASK ;Entry point from Taskmgr
  1.  N LRBERLDT,DATX,YY,MM,STARTDT,ENDDT,TOTPAN
  1.  K ^TMP("LRPENDING",$J)
  1.  S ^TMP("LRPENDING",$J,0)=$$NOW^XLFDT_"^"
  1.  S LRBERLDT=$P(^LAB(69.9,1,"VSIT"),U,2)
  1.  I 'LRBERLDT S (STARTDT,ENDDT)=""
  1.  I LRBERLDT D
  1.  .S YY=$E(LRBERLDT,1,3),MM=+$E(LRBERLDT,4,5)
  1.  .S MM=$S(MM=1:12,1:MM-1) S YY=$S(MM=12:YY-1,1:YY) I $L(MM)=1 S MM="0"_MM
  1.  .S STARTDT=YY_MM_"01",ENDDT=YY_MM_"31"_".999999"
  1.  .S DATX=$O(^LRO(69,"APP",0))
  1.  .I DATX,DATX<STARTDT S STARTDT=DATX
  1.  .D START
  1.  S ^TMP("LRPENDING",$J,0)=^TMP("LRPENDING",$J,0)_$$NOW^XLFDT()
  1.  D MAILRPT
  1.  Q
  1.  ;
  1. START ;Loop thru pending panel xref in file #69
  1.  N LINE,LRXDT,LRODT,LRSN,LRTN
  1.  S LINE=100,TOTPAN=0
  1.  S LRXDT=STARTDT-1 F  S LRXDT=$O(^LRO(69,"APP",LRXDT)) Q:'LRXDT  Q:LRXDT>ENDDT  D
  1.  .S LRODT=0 F  S LRODT=$O(^LRO(69,"APP",LRXDT,LRODT)) Q:'LRODT  D
  1.  ..S LRSN=0 F  S LRSN=$O(^LRO(69,"APP",LRXDT,LRODT,LRSN)) Q:'LRSN  D
  1.  ...S LRTN=0 F  S LRTN=$O(^LRO(69,"APP",LRXDT,LRODT,LRSN,LRTN)) Q:'LRTN  D
  1.  ....D SET
  1.  ....I $D(LRBEY)>1 D SETRPT
  1.  ....D CLEAN
  1.  Q
  1.  ;
  1. SET ;Setup background variables for call to BAWRK^LRBEBA
  1.  N I,LRBET,LRBEIEN,NX,XX
  1.  S LRBEIEN=LRSN_","_LRODT_","
  1.  S LRDFN=$$GET1^DIQ(69.01,LRBEIEN,.01,"I")
  1.  S LRORDER=$$GET1^DIQ(69.01,LRBEIEN,9.5,"I")
  1.  S LRBEIEN=LRTN_","_LRSN_","_LRODT_","
  1.  S LRBETST=$$GET1^DIQ(69.03,LRBEIEN,.01,"I")
  1.  I LRBETST="" K ^LRO(69,"APP",LRXDT,LRODT,LRSN,LRTN) Q
  1.  S LRAD=+$$GET1^DIQ(69.03,LRBEIEN,2,"I")
  1.  S LRAA=+$$GET1^DIQ(69.03,LRBEIEN,3,"I")
  1.  S LRAN=+$$GET1^DIQ(69.03,LRBEIEN,4,"I")
  1.  S LRUID=$$GET1^DIQ(69.03,LRBEIEN,13,"I")
  1.  S LRBECDT=$$GET1^DIQ(69.03,LRBEIEN,22,"I")
  1.  S LRBEDFN=$$GET1^DIQ(63,LRDFN,.03,"I")
  1.  S LRSS=$$GET1^DIQ(68,LRAA,.02,"I")
  1.  I $G(^LRO(68,LRAA,1,LRAD,1,LRAN,4,LRBETST,0))="" K ^LRO(69,"APP",LRXDT,LRODT,LRSN,LRTN) Q
  1.  S LRIDT=$P($G(^LRO(68,LRAA,1,LRAD,1,LRAN,3)),U,5)
  1.  S I=$O(^LRO(68,LRAA,1,LRAD,1,LRAN,5,0))
  1.  I I S X=^LRO(68,LRAA,1,LRAD,1,LRAN,5,I,0),LRSPEC=$P(X,U,1),LRSAMP=$P(X,U,2)
  1.  S NX=0 F  S NX=$O(^LAB(60,LRBETST,2,NX)) Q:'NX  D
  1.  .S LRBET=+^LAB(60,LRBETST,2,NX,0)
  1.  .Q:('$P(^LAB(60,LRBET,0),U,17))
  1.  .S XX=$P($P(^LAB(60,LRBET,0),U,5),";",2)
  1.  .;if null XX, possibly another panel
  1.  .I 'XX D ARRS^LRBEBA5(LRBET,LRBETST) Q
  1.  .S LRSB(XX)=$G(^LR(LRDFN,LRSS,LRIDT,XX))
  1.  .I LRSB(XX)="" K LRSB(XX) Q
  1.  .I $P(LRSB(XX),U,1)["canc" K LRSB(XX) Q
  1.  .I $P(LRSB(XX),U,13) K LRSB(XX) Q
  1.  .S LRBEY(LRBETST,XX)=""
  1.  I $D(LRBEY)>1 D
  1.  .S LRTEST(1)=LRBETST_U_^LAB(60,LRBETST,0),LRTEST(1,"P")=LRBETST_U_$$NLT^LRVER1(LRBETST)
  1.  Q
  1.  ;
  1. CLEAN ;Clean-up variables
  1.  K LRBEY,LRTEST,LRSB,LRBECPT,LRDFN,LRBEDFN,LRORDER
  1.  K LRBETST,LRBEVST,LRAA,LRAN,LRAD,LRUID,LRBECDT,LRSS,LRIDT,LRSAMP,LRSPEC
  1.  Q
  1.  ;
  1. SETRPT ;Set veriables into ^TMP( for report
  1.  N SETLN,X,C,CX,PATNM,XCODE,LRBETST,LRBETSTN
  1.  S TOTPAN=TOTPAN+1
  1.  S SETLN="S LINE=LINE+1,^TMP(""LRPENDING"",$J,LINE,0)=X"
  1.  S X=$P(^DPT(LRBEDFN,0),U,1,9),PATNM=$E($P(X,U,1),1,20)_" ("_$E($P(X,U,9),6,9)_")"
  1.  S LRBETST=$P(LRTEST(1),U,1)
  1.  S LRBETSTN=$P(^LAB(60,LRBETST,0),U,1),LRBETSTN="["_LRBETST_"] "_$E(LRBETSTN,1,26)
  1.  S:$G(LRBECDT)="" LRBECDT=DT D PANEL^LRBEBA4
  1.  S X=$$SETSTR^VALM1(LRUID,"",1,10)
  1.  S X=$$SETSTR^VALM1(PATNM,X,14,28),X=$$SETSTR^VALM1(LRBETSTN,X,44,34) X SETLN
  1.  S C=$O(LRBECPT(LRBETST,1,0))
  1.  I C D
  1.  . S XCODE=$P($$CPT^ICPTCOD(C),U,2,3),XCODE=$TR(XCODE,"^"," "),XCODE=$E(XCODE,1,30)
  1.  . S X=$$SETSTR^VALM1("Panel CPT Code:","",14,16),X=$$SETSTR^VALM1(XCODE,X,32,40) X SETLN
  1.  . S CX=LRBECPT(LRBETST,1,C),X=$$SETSTR^VALM1(CX,"",32,40) X SETLN
  1.  I 'C D
  1.  . S X=$$SETSTR^VALM1("Panel CPT Code:","",14,16),X=$$SETSTR^VALM1("<No active CPT available>",X,32,40) X SETLN
  1.  S X=" " X SETLN
  1.  Q
  1.  ;
  1. MAILRPT ;Set intro & send pending panel report to user
  1.  N XMY,XMSUB,XMDUZ,XMTEXT,XMZ,X,X1,Y,SETLN,LINE,DASH,REPDT
  1.  S STARTDT=$P(STARTDT,".",1)
  1.  I ENDDT S ENDDT=$P(ENDDT,".",1),X=ENDDT D
  1.  .S X1=X,X=+$E(X,4,5),X=$S("^1^3^5^7^8^10^12^"[(U_X_U):31,X'=2:30,$E(X1,1,3)#4:28,1:29)
  1.  .I $E(X1,6,7)>X S $E(ENDDT,6,7)=X
  1.  S LINE=0,SETLN="S LINE=LINE+1,^TMP(""LRPENDING"",$J,LINE,0)=X"
  1.  S $P(DASH,"-",78)=""
  1.  S X=" " X SETLN
  1.  S X="This report provides a listing of AMA/Billable panel tests that are pending" X SETLN
  1.  S X="completion as of the Report Date/Time.  The Sample Collection Date for the" X SETLN
  1.  S X="panel test falls within the date range indicated by Start Date and End Date." X SETLN
  1.  S X="One or more of the 'required' atomic tests comprising the panel do not yet" X SETLN
  1.  S X="have a verified result." X SETLN
  1.  S X=" " X SETLN
  1.  S X="Normally, panel tests flagged as 'AMA/Billable' should be reported to PCE" X SETLN
  1.  S X="using the CPT Code of the panel.  In order for the panel CPT Code to be" X SETLN
  1.  S X="sent to PCE, a verified result must be present for each 'required' atomic" X SETLN
  1.  S X="test comprising the panel.  If all required atomic tests have not been" X SETLN
  1.  S X="verified by the Next Lab Roll-up Date, then the CPT Codes for the individual" X SETLN
  1.  S X="atomic tests will be sent to PCE." X SETLN
  1.  S X=" " X SETLN
  1.  S X="Note: This report may not show any panels if it is run after the roll-up to" X SETLN
  1.  S X="PCE but before the end of the month. Please consult the Roll-up to PCE Report" X SETLN
  1.  S X="sent to G.LIM for information on unbundled panels not reported here." X SETLN
  1.  S X=" " X SETLN
  1.  S X=" " X SETLN
  1.  S Y=$$NOW^XLFDT() D DD^%DT S REPDT=Y
  1.  S X="Report Date/Time         : "_REPDT X SETLN
  1.  I LRBERLDT S Y=LRBERLDT D DD^%DT S LRBERLDT=Y
  1.  S X="Next Lab Roll-up Date    : "_LRBERLDT X SETLN
  1.  I STARTDT S Y=STARTDT D DD^%DT S STARTDT=Y
  1.  S X="Start Date               : "_STARTDT X SETLN
  1.  I ENDDT S Y=ENDDT D DD^%DT S ENDDT=Y
  1.  S X="End Date                 : "_ENDDT X SETLN
  1.  S X="Total # Panels           : "_$G(TOTPAN) X SETLN
  1.  S X=" " X SETLN
  1.  S X=" " X SETLN
  1.  S X=$$SETSTR^VALM1("Unique","",1,10) X SETLN
  1.  S X=$$SETSTR^VALM1("Identifier",X,1,10),X=$$SETSTR^VALM1("Patient",X,14,28)
  1.  S X=$$SETSTR^VALM1("Panel Test",X,44,34) X SETLN
  1.  S X=$$SETSTR^VALM1(DASH,"",1,78) X SETLN
  1.  S XMSUB="AMA/Billable Panel Pending List "_REPDT
  1.  S XMDUZ=.5
  1.  S XMY(DUZ)=""
  1.  S XMTEXT="^TMP(""LRPENDING"",$J,"
  1.  D ^XMD
  1.  K ^TMP("LRPENDING",$J)
  1.  Q