Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MAGDSTV2

MAGDSTV2.m

Go to the documentation of this file. 
  1. MAGDSTV2 ;WOIFO/PMK - Process a Q/R Client RPC; Mar 31, 2020@13:00:30
  1.  ;;3.0;IMAGING;**231**;Mar 19, 2002;Build 9;Sep 03, 2013
  1.  ;; Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;; +---------------------------------------------------------------+
  1.  ;; | Property of the US Government.                                |
  1.  ;; | No permission to copy or redistribute this software is given. |
  1.  ;; | Use of unreleased versions of this software requires the user |
  1.  ;; | to execute a written test agreement with the VistA Imaging    |
  1.  ;; | Development Office of the Department of Veterans Affairs,     |
  1.  ;; | telephone (301) 734-0100.                                     |
  1.  ;; | The Food and Drug Administration classifies this software as  |
  1.  ;; | a medical device.  As such, it may not be changed in any way. |
  1.  ;; | Modifications to this software may result in an adulterated   |
  1.  ;; | medical device under 21CFR820, the use of which is considered |
  1.  ;; | to be a violation of US Federal Statutes.                     |
  1.  ;; +---------------------------------------------------------------+
  1.  ;;
  1.  ;
  1.  ; Supported IA #10103 reference $$NOW^XLFDT function call
  1.  ;
  1.  Q
  1.  ; M2MB server
  1.  ;
  1.  ; This routine is invoked by the M2M Broker RPC to handle a Q/R client.
  1.  ;
  1. ENTRY(RESULT,REQUEST) ; RPC = MAG DICOM Q/R CLIENT
  1.  N ARGS ; ---- argument string of the REQUEST item
  1.  N DATETIME ;- fileman date/time of the study
  1.  N DCMPID ;--- DICOM patient id
  1.  N DFN ;------ VistA's internal patient identifier
  1.  N ERRCODE ;-- code for an error, if encountered
  1.  N IREQUEST ;- pointer to item in REQUEST array
  1.  N MSG ; ----- error message array
  1.  N OPCODE ;--- operation code of the REQUEST item
  1.  N RETURN ;--- intermediate return code
  1.  N J ;-------- scratch variable
  1.  ;
  1.  ; pass the request list and determine what has to be done
  1.  F IREQUEST=2:1:$G(REQUEST(1)) D
  1.  . S OPCODE=$P(REQUEST(IREQUEST),"|")
  1.  . S ARGS=$P(REQUEST(IREQUEST),"|",2,999)
  1.  . ;
  1.  . I OPCODE="NEXT" D  Q
  1.  . . S NEXTIEN=$G(^MAGDSTT(2006.541,"ACOUNT"))+1
  1.  . . I '$D(^MAGDSTT(2006.541,NEXTIEN)) D RESULT("QR-REQUEST","NONE") Q
  1.  . . ; if another RPC is already processing this request, skip it
  1.  . . L +^MAGDSTT(2006.541,"ACOUNT"):0 E  D RESULT("QR-REQUEST","NONE") Q
  1.  . . S VALUE=^MAGDSTT(2006.541,NEXTIEN,0)_"^"_NEXTIEN
  1.  . . D RESULT("QR-REQUEST",VALUE)
  1.  . . S J=0
  1.  . . F  S J=$O(^MAGDSTT(2006.541,NEXTIEN,1,J)) Q:'J  D
  1.  . . . S VALUE=^MAGDSTT(2006.541,NEXTIEN,1,J,0)
  1.  . . . D RESULT("KEY",VALUE)
  1.  . . . Q
  1.  . . S ^MAGDSTT(2006.541,"ACOUNT")=NEXTIEN
  1.  . . L -^MAGDSTT(2006.541,"ACOUNT")
  1.  . . Q
  1.  . ;
  1.  . I OPCODE="QUERY RESULT" D  Q  ; save query results in ^XTMP
  1.  . . N V,VARS,VAR
  1.  . . S VARS="MAGXTMP^HOSTNAME^VISTAJOB^QRSTACK^IEN2006541^LEVEL^I^J^K^L^VARIABLE^VALUE"
  1.  . . F V=1:1:$L(VARS,"^") S VAR=$P(VARS,"^",V) N @VAR S @VAR=$P(ARGS,"|",V)
  1.  . . I LEVEL="PATIENT" D
  1.  . . . I I="" S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"PATIENT")=VALUE
  1.  . . . E  S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"PATIENT",I,VARIABLE)=VALUE
  1.  . . . Q
  1.  . . E  I LEVEL="STUDY" D
  1.  . . . I J="" S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"STUDY",I)=VALUE
  1.  . . . E  S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"STUDY",I,J,VARIABLE)=VALUE
  1.  . . . Q
  1.  . . E  I LEVEL="SERIES" D
  1.  . . . I K="" S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"SERIES",I,J)=VALUE
  1.  . . . E  S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"SERIES",I,J,K,VARIABLE)=VALUE
  1.  . . . Q
  1.  . . E  I LEVEL="IMAGE" D
  1.  . . . I L="" S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"IMAGE",I,J,K)=VALUE
  1.  . . . E  S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"IMAGE",I,J,K,L,VARIABLE)=VALUE
  1.  . . . Q
  1.  . . E  I LEVEL="DONE" D
  1.  . . . ; "DONE" uses the request IEN for proper synchronization
  1.  . . . S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"DONE",IEN2006541)=$$NOW^XLFDT_"^"_VARIABLE_"^"_VALUE
  1.  . . . Q
  1.  . . E  I LEVEL="WORKING..." D
  1.  . . . S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"WORKING...",IEN2006541)=$$NOW^XLFDT_"^"_VARIABLE_"^"_VALUE
  1.  . . . Q
  1.  . . E  I LEVEL="MESSAGE" D
  1.  . . . S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"MESSAGE",VARIABLE,I)=VALUE
  1.  . . . Q
  1.  . . E  S PI=CIRCUMFERENCE/DIAMETER ; throw an error (line of code written on 3/14)
  1.  . . Q
  1.  . I OPCODE="RETRIEVE RESULT" D  Q  ; save retrieve results in ^XTMP
  1.  . . S MAGXTMP=$P(ARGS,"|",1),HOSTNAME=$P(ARGS,"|",2),VISTAJOB=$P(ARGS,"|",3)
  1.  . . S QRSTACK=$P(ARGS,"|",4)
  1.  . . S IEN2006541=$P(ARGS,"|",5) ; IEN2006541 is not used here
  1.  . . S ACNUMB=$P(ARGS,"|",6),X=$P(ARGS,"|",7,999)
  1.  . . S ^XTMP(MAGXTMP,HOSTNAME,VISTAJOB,QRSTACK,"Q/R RETRIEVE STATUS",ACNUMB)=X
  1.  . . Q
  1.  . I OPCODE="CRASH" D  Q
  1.  . . S I=1/0 ; generate an error on the server to test error trapping
  1.  . . Q
  1.  . Q
  1.  Q
  1.  ;
  1. RESULT(OPCODE,ARGS) ; add an item to the RESULT list
  1.  S RESULT(1)=$G(RESULT(1),1)+1 ; first element in array is counter
  1.  S RESULT(RESULT(1))=OPCODE_"|"_ARGS
  1.  Q