Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MAGGA03U

MAGGA03U.m

Go to the documentation of this file. 
  1. MAGGA03U ;WOIFO/GEK,MLH - USERS CAPTURED IMAGES IN DATE RANGE ; 6/6/2011 5:23 PM
  1.  ;;3.0;IMAGING;**93,117**;Mar 19, 2002;Build 2238;Jul 15, 2011
  1.  ;; Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;; +---------------------------------------------------------------+
  1.  ;; | Property of the US Government.                                |
  1.  ;; | No permission to copy or redistribute this software is given. |
  1.  ;; | Use of unreleased versions of this software requires the user |
  1.  ;; | to execute a written test agreement with the VistA Imaging    |
  1.  ;; | Development Office of the Department of Veterans Affairs,     |
  1.  ;; | telephone (301) 734-0100.                                     |
  1.  ;; | The Food and Drug Administration classifies this software as  |
  1.  ;; | a medical device.  As such, it may not be changed in any way. |
  1.  ;; | Modifications to this software may result in an adulterated   |
  1.  ;; | medical device under 21CFR820, the use of which is considered |
  1.  ;; | to be a violation of US Federal Statutes.                     |
  1.  ;; +---------------------------------------------------------------+
  1.  ;;
  1.  Q
  1.  ;***** RETURNS USERS THAT HAVE CAPTURED IMAGES IN THE DATE RANGE
  1.  ; RPC: MAGG CAPTURE USERS
  1.  ; .MAGRY        Reference to a local variable where the results
  1.  ;               are returned to.
  1.  ;
  1.  ; FLAGS         Controls which users are returned.
  1.  ;               FLAGS refers to field #8.1 CAPTURE APPLICATION 
  1.  ;               That field tells which device captured this image.
  1.  ;               C =  Capture Application 
  1.  ;                    Images that were captured by VI Capture Client
  1.  ;               I =  Import API
  1.  ;                    Images that were captured by VI Import API
  1.  ;               If Flags is 'null' it defaults to 'CI'
  1.  ;               So, it returns Users that have capture C and/or
  1.  ;               I images, in the date range.
  1.  ;               
  1.  ; [FROMDATE]    Date range for image selection. Dates can be in
  1.  ; [TODATE]      internal or external FileMan format. If a date
  1.  ;               parameter is not defined or empty, then an error
  1.  ;               is returned.
  1.  ;
  1.  ;               Time parts of parameter values are ignored and both
  1.  ;               ends of the date range are included in the search.
  1.  ;               For example, in order to search images for May 21,
  1.  ;               2008, the internal value of both parameters should
  1.  ;               be 3080521.
  1.  ;
  1.  ;               If the FROMDATE is after the TODATE, then values of
  1.  ;               the parameters are swapped.
  1.  ; 
  1.  ; Return Values
  1.  ; =============
  1.  ;     
  1.  ; MAGRY(0)     is in the format:   0^<error message> if error during execution
  1.  ;                            or    1^<success message>  
  1.  ; MAGRY(1..n) are in the format:   Last First Middle ^ DUZ
  1.  ; Notes
  1.  ; =====
  1.  ;
  1.  ; Temporary global nodes ^TMP("MAGGA03U",$J) and ^TMP($J,"MAGUSERS" 
  1.  ;   and ^TMP($J,"MAGDUZ"  are used by this procedure.
  1.  ;
  1. USERS(MAGRY,FROMDATE,TODATE,FLAGS) ;  [RPC MAGG CAPTURE USERS]
  1.  N I,EDT,N0,N2,CT,TMP,MERR,CAPAPP,IDUZ,INM,MSG,X,Y
  1.  S MAGRY=$NA(^TMP("MAGGA03U",$J))
  1.  K @MAGRY,^TMP($J,"MAGUSERS"),^TMP($J,"MAGDUZ")
  1.  ;
  1.  ; Validate parameters.
  1.  S MERR=0
  1.  D
  1.  . S FLAGS=$G(FLAGS) I FLAGS="" S FLAGS="CI"
  1.  . I $TR(FLAGS,"CI")'="" S MERR=1,MSG="Invalid Flags: '"_FLAGS_"'.  Only 'C' and/or 'I'" Q
  1.  . S X=$G(FROMDATE) D ^%DT I Y=-1 S MERR=1,MSG="Invalid date "_FROMDATE Q
  1.  . S FROMDATE=Y
  1.  . S X=$G(TODATE) D ^%DT I Y=-1 S MERR=1,MSG="Invalid date "_TODATE Q
  1.  . S TODATE=Y
  1.  I MERR S @MAGRY@(0)="0^"_MSG Q
  1.  ;
  1.  ; Swap the dates if necessary
  1.  K TMP I FROMDATE>TODATE S TMP=FROMDATE,FROMDATE=TODATE,TODATE=TMP
  1.  ;
  1.  ;  Loop through ADTDUZ Cross ref and find users that have captured images.
  1.  ;  
  1.  F I=1:1 S CAPAPP=$E(FLAGS,I) Q:CAPAPP=""  D
  1.  . S EDT=$$FMADD^XLFDT(TODATE,1)
  1.  . F  S EDT=$O(^MAG(2005,"ADTDUZ",CAPAPP,EDT),-1) Q:EDT<FROMDATE  D
  1.  . . S IDUZ="" F  S IDUZ=$O(^MAG(2005,"ADTDUZ",CAPAPP,EDT,IDUZ)) Q:IDUZ=""  D
  1.  . . . S ^TMP($J,"MAGDUZ",IDUZ)=""
  1.  . . . Q
  1.  . . Q
  1.  . Q
  1.  ;  convert DUZ to Names using Kernel API
  1.  I '$D(^TMP($J,"MAGDUZ")) S @MAGRY@(0)="0^No users found." Q
  1.  S IDUZ="" F  S IDUZ=$O(^TMP($J,"MAGDUZ",IDUZ)) Q:'IDUZ  D
  1.  . S INM=$$GETNAME(IDUZ)
  1.  . S ^TMP($J,"MAGUSERS",INM,IDUZ)=""
  1.  . Q
  1.  ;
  1.  ; Result array from Names and DUZs
  1.  S CT=0,(INM,IDUZ)=""
  1.  F  S INM=$O(^TMP($J,"MAGUSERS",INM)) Q:INM=""  D
  1.  . F  S IDUZ=$O(^TMP($J,"MAGUSERS",INM,IDUZ)) Q:IDUZ=""  D
  1.  . . S CT=CT+1,@MAGRY@(CT)=INM_"^"_IDUZ
  1.  S @MAGRY@(0)=1_"^Success: "_CT_" users found"
  1.  K ^TMP($J,"MAGUSERS"),^TMP($J,"MAGDUZ")
  1.  Q
  1.  ;
  1.  ;***** RETURN NAME FROM NAME COMPONENTS
  1.  ;  IDUZ is the DUZ of the User.
  1.  ;  Uses supported API #3065 to call $$NAMEFMT^XLFNAME()
  1.  ; ===== Return values
  1.  ;   Returns the name in mixed case "Last,First Middle" format
  1. GETNAME(IDUZ) ;
  1.  N MAGN,MN
  1.  ; set the needed parameters for the API Call.
  1.  S MAGN("FILE")=200
  1.  S MAGN("IENS")=IDUZ_","
  1.  S MAGN("FIELD")=".01"
  1.  ; make the call
  1.  S MN=$$NAMEFMT^XLFNAME(.MAGN,"F","FMC")
  1.  ; handle problems with call
  1.  I MN="" S MN="Undefined User "_IDUZ
  1.  Q MN