Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MCORMN0

MCORMN0.m

Go to the documentation of this file. 
  1. MCORMN0 ;WISC/DCB-HL7 MESSAGE BUILDER ;7/23/99  09:08
  1.  ;;1.0;CLINICAL PROCEDURES;**5**;Apr 01, 2004;Build 1
  1.  W !,"This is not a valid entry point" Q
  1. BUILD(RAP,MCDFN,SAP,SNF,RNF,MST,PCI,VID,MCLINE,MSTR,MCDEST,MCPROC,MCFILE,MCREC,SDATE,ATYPE) ; Build the message
  1.  K ^TMP("MCORMN",$J)
  1.  N MCERR,MCOR,MCOR1,MCOR2,MCOR3,MCOR4,MSE,OBR,HLECH
  1.  N LOOP,MCDS,ST,MSE,MCHOLD,MCHOLD
  1.  S MSE=0,HLECH=$E(MSTR,2,4) D SLIP(MSTR)
  1.  S MCHOLD=+$O(^MCAR(697.2,"B",MCPROC,""))
  1.  S MCHOLD=$P($G(^MCAR(697.2,MCHOLD,0)),U,8)
  1.  S MCERR=$$GETDATA^MCORMN1(MCPROC,MCREC,"^TMP(""MCORMN"",$J)",MCFILE,ATYPE) Q:MCERR=0 1
  1.  S MCHOLD=$S(MCHOLD="":MCPROC,1:MCHOLD)
  1.  D SETNODE(MCDEST,$$MSH^MCORMN01(MCHOLD,SAP,SNF,RAP,RNF,MST,PCI,VID))
  1.  D SETNODE(MCDEST,$$PID^MCORMN01(MCDFN))
  1.  D SETNODE(MCDEST,$$OBR1^MCORMN01(SDATE,MCPROC,MCREC,MCFILE)) S OBR=MCLINE
  1.  S MCOR1=""
  1.  F  S MCOR1=$O(^TMP("MCORMN",$J,"E",MCOR1)) Q:MCOR1=""  D
  1.  .S MCOR2=""
  1.  .F  S MCOR2=$O(^TMP("MCORMN",$J,"E",MCOR1,MCOR2)) Q:MCOR2=""  D
  1.  ..S MCOR3=""
  1.  ..F  S MCOR3=$O(^TMP("MCORMN",$J,"E",MCOR1,MCOR2,MCOR3)) Q:MCOR3=""  D
  1.  ...D GETDATA(RAP,MCDEST,OBR,MCOR1,MCOR2,MCOR3)
  1.  I +$P($G(^MCAR(MCFILE,MCREC,2005,0)),U,4)>0 D
  1.  .N OBI,OBR,OSI,VTI,UNT,RNG
  1.  .S OBI=MCFILE_ST(3)_"2005"_ST(3)_"P"_ST(2)_"IMAGES?"_ST(2)_"DD"
  1.  .S OBR="Images are associated with this procedure"
  1.  .S OSI="",VTI="",FILETYPE="P",UNT="",RNG=""
  1.  .D SETOBX1(FILETYPE,VTI,OBI,OSI,OBR),SETOBX2(UNT,RNG)
  1.  Q 0
  1. GETDATA(RAP,MCDEST,OBR,MCOR1,MCOR2,MCOR3) ; Process the Data
  1.  N TMP1,TMP,HL7,TYPE
  1.  S TMP=$G(^TMP("MCORMN",$J,"F",MCOR1,MCOR3,0))
  1.  S HL7=$G(^TMP("MCORMN",$J,"F",MCOR1,MCOR3,1))
  1.  S TYPE=$P(HL7,U,7)
  1.  I (TYPE'="OBR"),(TYPE'="INFO"),(RAP="Health Summary") S TYPE="DD"
  1.  Q:(TYPE="INFO")!(TYPE="MISC")!(TYPE="")
  1.  S TMP1="D "_TYPE_"(TMP,HL7,OBR,MCOR1,MCOR2,MCOR3)" X TMP1
  1.  Q
  1. ICD9(TMP,HL7,OBX,MCOR1,MCOR2,MCOR3) ; This is the ICD9 message builder for OBX
  1.  N OID,VT1,UNT,OSI,OBI,RNG,RST,DA,DIC,DR,DIQ,XTMP,CONT
  1.  S OBI="ICD9",OSI="",MST=$G(MST)+1,OSI=MST,CONT=""
  1.  S VTI=$P(HL7,U,2) S:VTI="" VTI="CE"
  1.  S UNT="",RNG="",RST=$G(^TMP("MCORMN",$J,"E",MCOR1,MCOR2,MCOR3,1)) Q:RST=""
  1.  ;S DA=$O(^ICD9("B",RST,"")) Q:DA=""
  1.  Q
  1.  S DIC="^ICD9(",DR=".01;3",DIQ="XTMP(" D EN^DIQ1
  1.  S RST=XTMP(80,DA,.01)_ST(2)_XTMP(80,DA,3)_ST(2)_"ICD9"
  1.  D SETOBX1("",VTI,OBI,OSI,RST)
  1.  Q
  1. ASTM(TMP,HL7,OBX,MCOR1,MCOR2,MCOR3) ; This is the ASTM message builder for OBX
  1.  N ASTM,ASTME,VTI,UNT,RNG,RST,OSI,OBI,FILETYPE
  1.  S FILETYPE=$P(TMP,U,2),OSI=""
  1.  S ASTM=$P(HL7,U,1),ASTME=$G(^MCAR(690.5,ASTM,0))
  1.  S ASTM=$P(ASTME,U,1)_$P(ASTME,U,2),VTI=$P(HL7,U,2)
  1.  S OBI=ASTM_ST(2)_$P(ASTME,U,3)_ST(2)_"CPT4"
  1.  S UNT=$P(HL7,U,3),RNG=$P(HL7,U,4)
  1.  D RDATA(VTI,OBI,OSI,UNT,RNG,FILETYPE,MCOR1,MCOR2,MCOR3)
  1.  Q
  1. SUM(TMP,HL7,OBX,MCOR1,MCOR2,MCOR3) ; This is the miss. message builder for OBX
  1.  N FILETYPE,VTI,UNT,RNG,RST,OSI,OBI
  1.  S FILETYPE=$P(TMP,U,2),OSI=""
  1.  S OBI="SST",(UNT,RNG)="",OSI=""
  1.  S VTI="TX"
  1.  D RDATA(VTI,OBI,OSI,UNT,RNG,FILETYPE,MCOR1,MCOR2,MCOR3)
  1.  Q
  1. DD(TMP,HL7,OBX,MCOR1,MCOR2,MCOR3) ; This is the DD mesage builder for OBX
  1.  N FLDNAME,VTI,OBI,OSI,UNT,RNG,FILETYPE,FLDNAME
  1.  S FILETYPE=$P(TMP,U,2),FLDNAME=$P(TMP,"^",1),OSI=""
  1.  S VTI=$P(HL7,U,2),OBI=MCOR1_ST(3)_MCOR3_ST(3)_FILETYPE_ST(2)_FLDNAME_ST(2)_"DD"
  1.  S UNT=$P(HL7,U,3),RNG=$P(HL7,U,4)
  1.  D RDATA(VTI,OBI,OSI,UNT,RNG,FILETYPE,MCOR1,MCOR2,MCOR3)
  1.  Q
  1. OBR(TMP,HL7,OBX,MCOR1,MCOR2,MCOR3) ; This is the OBR add on message
  1.  N RST,PIECE,FILETYPE
  1.  S FILETYPE=$P(TMP,U,2),RST=$G(^TMP("MCORMN",$J,"E",MCOR1,MCOR2,MCOR3,1))
  1.  S RST=$$CONVERT^MCORMN01(FILETYPE,RST),PIECE=$P(HL7,U,6)+1
  1.  S $P(@MCDEST@(OBX),ST(1),PIECE)=RST
  1.  Q
  1. RDATA(VTI,OBI,OSI,UNT,RNG,FILETYPE,MCOR1,MCOR2,MCOR3) ;
  1.  N MCOR4,CONT,LEN,RSTT,TEMP,COUNT,END,RST,CNT,LOOP,LOOP2,X,DIWL,DIWR,DIWF
  1.  S MCOR4=""
  1.  F LOOP=1:1 S MCOR4=$O(^TMP("MCORMN",$J,"E",MCOR1,MCOR2,MCOR3,MCOR4)) Q:MCOR4=""  D
  1.  .S X=^TMP("MCORMN",$J,"E",MCOR1,MCOR2,MCOR3,MCOR4)
  1.  .;I $L(X)>80 D WP
  1.  .I $L(X)>80 D
  1.  ..D WP
  1.  .E  D
  1.  ..D:LOOP=1 SETOBX1(FILETYPE,VTI,OBI,OSI,X)
  1.  ..D:LOOP'=1 SETNODE(MCDEST,X)
  1.  D SETOBX2(UNT,RNG)
  1.  Q
  1. WP ;
  1.  K ^UTILITY($J,"W") S DIWL=0,DIWR=80,DIWF="" D ^DIWP
  1.  S CNT=^UTILITY($J,"W",0)
  1.  F LOOP2=1:1:CNT S RST=^UTILITY($J,"W",0,LOOP2,0) D
  1.  .I (LOOP2>1)!(LOOP>1) D SETNODE(MCDEST,RST)
  1.  .E  D SETOBX1(FILETYPE,VTI,OBI,OSI,RST)
  1.  K ^UTILITY($J,"W")
  1.  Q
  1. SETOBX1(FILETYPE,VTI,OBI,OSI,OBR) ; Sets the first part of QBX line
  1.  S:VTI="" VTI="ST"
  1.  S:OSI="" (MSE,OSI)=$G(MSE)+1
  1.  D SETNODE(MCDEST,$$OBX1^MCORMN01(FILETYPE,VTI,OBI,OSI,OBR))
  1.  Q
  1. SETOBX2(RNG,UNT) ;Sets the second part of OBX line
  1.  S @MCDEST@(MCLINE,0)=@MCDEST@(MCLINE,0)_$$OBX2^MCORMN01(RNG,UNT)
  1.  Q
  1. SETNODE(NODE,VALUE) ;Set the node with the HL7 message string
  1.  S MCLINE=MCLINE+1,@NODE@(MCLINE,0)=VALUE
  1.  Q
  1. SLIP(MSTR) ;Seperate the delimiters
  1.  F LOOP=1:1:5 S ST(LOOP)=$E(MSTR,LOOP,LOOP)
  1.  Q