Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MDKUTLR

MDKUTLR.m

Go to the documentation of this file.
  1. MDKUTLR ; HOIFO/DP - Renal Utilities RPC;11/29/07 14:45
  1. ;;1.0;CLINICAL PROCEDURES;**6**;Apr 01, 2004;Build 102
  1. ; Reference IA #10045 [Supported] XUSHSHP call
  1. ; #2241 [Supported] DECRYP^XUSRB1 call
  1. ; #10060 [Supported] FILE 200 references
  1. ;
  1. CP(STUDY) ; Check to see if the CP Study is logged
  1. N DFN,MDFDA,MDIEN
  1. S DFN=$P(^MDD(702,STUDY,0),U)
  1. D:'$D(^MDK(704.202,STUDY,0)) ; Build study record (1..1) with file 702
  1. .S MDFDA(704.202,"+1,",.01)=STUDY
  1. .;S MDFDA(704.202,"+1,",.02)=DFN
  1. .S MDFDA(704.202,"+1,",.09)=1
  1. .S MDIEN(1)=STUDY
  1. .D UPDATE^DIE("","MDFDA","MDIEN")
  1. .K MDFDA,MDIEN
  1. D:'$D(^MDK(704.201,DFN,0)) ; Build access point record (1..1) with file 2
  1. .S MDFDA(704.201,"+1,",.01)=DFN
  1. .S MDIEN(1)=DFN
  1. .D UPDATE^DIE("","MDFDA","MDIEN")
  1. .K MDFDA,MDIEN
  1. Q
  1. UPD(STUDY,NOTEID) ; Add entries to update CP_TRANSACTION_TIU_HISTORY
  1. N MDCHK,MDFDA,MDIEN
  1. Q:$G(STUDY)=""
  1. Q:$G(NOTEID)=""
  1. S MDCHK=$O(^MDD(702.001,"ASTUDY",+STUDY,NOTEID,0)) Q:+MDCHK
  1. D NOW^%DTC
  1. S MDFDA(702.001,"+1,",.01)=STUDY
  1. S MDFDA(702.001,"+1,",.02)=NOTEID
  1. S MDFDA(702.001,"+1,",.03)=%
  1. D UPDATE^DIE("","MDFDA")
  1. K %,X,MDFDA,MDIEN
  1. Q
  1. ;
  1. RPC(RESULTS,OPTION,P1,P2,P3,P4,P5,P6) ; [Procedure] Main RPC call
  1. ; RPC: [MDK UTILITIES]
  1. ;
  1. D CLEAN^DILF
  1. S RESULTS=$NA(^TMP("MDKUTL",$J)) K @RESULTS
  1. I $T(@OPTION)="" D Q
  1. .S @RESULTS@(0)="-1^Error in RPC: MDK UTILITIES at "_OPTION_U_$T(+0)
  1. D @OPTION S:'$D(@RESULTS) @RESULTS@(0)="-1^No return"
  1. D CLEAN^DILF
  1. Q
  1. ;
  1. ESIG ; [Procedure] Verify users electronic signature
  1. I $G(P1)="" D Q
  1. .S @RESULTS@(0)="-1^Must supply electronic signature code"
  1. S X=$$DECRYP^XUSRB1(P1)
  1. D HASH^XUSHSHP
  1. I X'=$$GET1^DIQ(200,DUZ_",",20.4,"I") S @RESULTS@(0)="-1^E-Sig Invalid^"
  1. E S @RESULTS@(0)="1^E-Sig Verifed^"_X
  1. Q
  1. ;
  1. LOCK ; [Procedure] Lock a record
  1. L @("+"_$$ROOT^DILFD(P1)_(+P2)_"):2")
  1. I '$T S @RESULTS@(0)="-1^Lock *NOT* acquired" Q
  1. E S @RESULTS@(0)="1^Lock acquired"
  1. Q
  1. ;
  1. UNLOCK ; [Procedure] Unlock a record
  1. L @("-"_$$ROOT^DILFD(P1)_(+P2)_")")
  1. S @RESULTS@(0)="1^Lock released"
  1. Q
  1. ;