Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MDRPCOP1

MDRPCOP1.m

Go to the documentation of this file. 
  1. MDRPCOP1 ; HOIFO/DP - Object RPCs (TMDPatient) - Cont. ; 01-09-2003 15:21
  1.  ;;1.0;CLINICAL PROCEDURES;**6**;Apr 01, 2004;Build 102
  1.  ; Integration Agreements:
  1.  ; IA# 3027 [Supported] Calls to DGSEC4
  1.  ; IA# 3266 [Subscription] Call to DPTLK1
  1.  ; IA# 10035 [Supported] DPT references
  1.  ; IA# 3267 [Subscription] Call to DPTLK1
  1.  ; IA# 3593 [Supported] Access to routine DPTLK6 utilities for lookup
  1.  ;
  1. ADD(X) ; [Procedure] Add line to @RESULTS@(...
  1.  S @RESULTS@(+$O(@RESULTS@(""),-1)+1)=X
  1.  Q
  1.  ;
  1. SELECT ; [Procedure] Select patient
  1.  I '$D(^DPT(+$G(DFN),0))#2 S @RESULTS@(0)="-1^No such patient" Q
  1.  S @RESULTS@(0)="1^Required Identifiers & messages"
  1.  S IENS=DFN_","
  1.  D FILE^DID(2,,"REQUIRED IDENTIFIERS","MDIDS")
  1.  F MDX=0:0 S MDX=$O(MDIDS("REQUIRED IDENTIFIERS",MDX)) Q:'MDX  D
  1.  .S MDFLD=MDIDS("REQUIRED IDENTIFIERS",MDX,"FIELD")
  1.  .S MDID="$$PTID^"_$$GET1^DID(2,MDFLD,"","LABEL")
  1.  .S MDID=MDID_U_$$GET1^DIQ(2,IENS,MDFLD)
  1.  .D:MDFLD=.03
  1.  ..S MDID=MDID_" ("_$$GET1^DIQ(2,IENS,.033)_")"
  1.  ..S MDID=MDID_U_$$DOB^DPTLK1(+IENS)
  1.  .D:MDFLD=.09
  1.  ..S X=$P(MDID,U,3),X=$E(X,1,3)_"-"_$E(X,4,5)_"-"_$E(X,6,10)
  1.  ..S $P(MDID,U,3)=X,$P(MDID,U,4)=$$SSN^DPTLK1(+IENS)
  1.  .S @RESULTS@($O(@RESULTS@(""),-1)+1)=MDID
  1.  S MDID="$$PTID^"_$$GET1^DID(2,.1,"","LABEL")
  1.  S MDID=MDID_U_$$GET1^DIQ(2,IENS,.1)
  1.  S @RESULTS@($O(@RESULTS@(""),-1)+1)=MDID
  1.  S MDID="$$PTID^"_$$GET1^DID(2,.101,"","LABEL")
  1.  S MDID=MDID_U_$$GET1^DIQ(2,IENS,.101)
  1.  S @RESULTS@($O(@RESULTS@(""),-1)+1)=MDID
  1.  K MDRET
  1.  D GUIBS5A^DPTLK6(.MDRET,DFN) D:MDRET(1)=1
  1.  .D ADD("$$MSGHDR^2^SAME LAST NAME AND LAST 4")
  1.  .S MDX=1
  1.  .F  S MDX=$O(MDRET(MDX)) Q:'MDX!(+$G(MDRET(MDX)))  D
  1.  ..D ADD($P(MDRET(MDX),U,2))
  1.  .D ADD(" ")
  1.  .S MDX=1
  1.  .F  S MDX=$O(MDRET(MDX)) Q:'MDX  D:+MDRET(MDX)
  1.  ..S MDDFN=+$P(MDRET(MDX),U,2)
  1.  ..D ADD($$GET1^DIQ(2,MDDFN_",",.01)_"    "_$$DOB^DPTLK1(MDDFN)_"    "_$$SSN^DPTLK1(MDDFN))
  1.  .D ADD(" ")
  1.  .D ADD("Please review carefully before continuing")
  1.  .D ADD("$$MSGEND")
  1.  K MDRET
  1.  D PTSEC^DGSEC4(.MDRET,DFN) D:MDRET(1)'=0
  1.  .D:MDRET(1)=3
  1.  ..D ADD("$$MSGHDR^0^CAN'T ACCESS YOUR OWN RECORD!!")
  1.  .D:MDRET(1)=-1
  1.  ..D ADD("$$MSGHDR^0^INCOMPLETE INFORMATION - CAN'T PROCEED")
  1.  .D:MDRET(1)=1
  1.  ..D ADD("$$MSGHDR^1^SENSITIVE RECORD ACCESS")
  1.  .D:MDRET(1)'=-1&(MDRET(1)'=3)&(MDRET(1)'=1)
  1.  ..D ADD("$$MSGHDR^3^SENSITIVE RECORD ACCESS")
  1.  .S MDX=1
  1.  .F  S MDX=$O(MDRET(MDX)) Q:'MDX  D ADD($TR(MDRET(MDX),"*"," "))
  1.  .D ADD("$$MSGEND")
  1.  D GUIMTD^DPTLK6(.MDRET,DFN) D:MDRET(1)=1
  1.  .D ADD("$$MSGHDR^1^NOTICE")
  1.  .F MDX=1:0 S MDX=$O(MDRET(MDX)) Q:'MDX  D ADD(MDRET(MDX))
  1.  .D ADD("$$MSGEND")
  1.  Q
  1.  ;
  1. X2FM(X) ; [Function] return FM date given relative date
  1.  N %DT S %DT="TS" D ^%DT
  1.  Q Y
  1.  ;