Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MPIFRESS

MPIFRESS.m

Go to the documentation of this file. 
  1. MPIFRESS ;BHM/RGY-Process a CMOR result ;FEB 27, 1998
  1.  ;;1.0; MASTER PATIENT INDEX VISTA ;**1,6,11,30**;30 Apr 99
  1.  ;
  1.  ; Integration Agreements Utilized:
  1.  ;
  1.  ;   EXC^RGHLLOG     IA #2796
  1.  ;   START^RGHLLOG   IA #2796
  1.  ;   STOP^RGHLLOG    IA #2796
  1.  ;   $$EN^VAFCPID    IA #3015
  1.  ;
  1. EN(REQNO) ;
  1.  N RGL,ID,COMMENTS,STATUS,NDATE,PHONE,REVIEWER,N0,CNT,HL,HLA,XX,ERROR
  1.  S CNT=0,HL=0
  1.  S N0=$G(^MPIF(984.9,REQNO,0))
  1.  I N0="" D  Q
  1.  .D START^RGHLLOG()
  1.  .D EXC^RGHLLOG(210,"CMOR Request # "_REQNO_" Does Not Exist attempting to generate approved/not approved msg")
  1.  .D STOP^RGHLLOG()
  1.  S ID=$P(N0,"^")
  1.  S STATUS=$P(N0,"^",6)
  1.  S COMMENTS=$P($G(^MPIF(984.9,REQNO,3)),"^",2)
  1.  I $P($G(^MPIF(984.9,REQNO,3)),"^")]"" S REVIEWER=$P(^(3),"^")
  1.  I $P($G(^MPIF(984.9,REQNO,3)),"^")']"" D
  1.  .N DIC,X,Y
  1.  .S DIC="^VA(200,",DIC(0)="ZMO",X="`"_+$P(^MPIF(984.9,REQNO,2),"^")
  1.  .D ^DIC
  1.  .I $G(Y)>1 S REVIEWER=$G(Y(0,0))
  1.  .I $G(Y)<1 S REVIEWER=""
  1.  S NDATE=$P($G(^MPIF(984.9,REQNO,2)),"^",2)
  1.  S PHONE=$P($G(^MPIF(984.9,REQNO,2)),"^",3)
  1.  S COMMENTS=$P($G(^MPIF(984.9,REQNO,3)),"^",2)
  1.  K HLA
  1.  D INIT^HLFNC2("MPIF CMOR APPROVE/DISAPPROVE",.HL)
  1.  I HL S ERROR=HL D  Q
  1.  .D START^RGHLLOG()
  1.  .D EXC^RGHLLOG(220,"Unable to setup HL7 for Change CMOR Request # "_REQNO_" for Approved/Not Approved msg HL Error"_HL,$P(N0,"^",4))
  1.  .D STOP^RGHLLOG()
  1.  K HLL("LINKS") N MPILK
  1.  S MPILK=$$MPILINK^MPIFAPI ;routing all messages through the MPI
  1.  I +MPILK<0 D  Q
  1.  .D START^RGHLLOG()
  1.  .D EXC^RGHLLOG(224,"No MPI link found for Change CMOR Request # "_REQNO_" for ICN="_ICN,DFN)
  1.  .D STOP^RGHLLOG()
  1.  .S ERROR="-1^LINK FOR MPI NOT FOUND"
  1.  ;Broadcast MSG to MPI which will send it to the requestor site
  1.  S HLL("LINKS",1)="MPIF CMOR APP/DIS^"_MPILK
  1.  S CNT=CNT+1,HLA("HLS",CNT)="EVN"_HL("FS")_"A31"_HL("FS")_NDATE_HL("FS")_HL("FS")_""_HL("FS")_REVIEWER
  1.  S CNT=CNT+1,HLA("HLS",CNT)="NTE"_HL("FS")_HL("FS")_"P"_HL("FS")_PHONE_HL("FS")_COMMENTS_HL("FS")_STATUS_HL("FS")_ID
  1.  S CNT=CNT+1,HLA("HLS",CNT)=$$EN^VAFCPID(+$P(N0,"^",4),"1,2,4,5,6,7,8,11,12,13,14,16,17,19")
  1.  N RLST
  1.  D GENERATE^HLMA("MPIF CMOR APPROVE/DISAPPROVE","LM",1,.RLST,"",.HL)
  1.  I 'RLST S ERROR=RLST D START^RGHLLOG(),EXC^RGHLLOG(220,"Error Generating HL7 msg for Approve/Not Approved CMOR Request # "_REQNO,$P(N0,"^",4))
  1.  Q
  1.  ;
  1. IN ;
  1.  ; Processing approve/not approve msg to update Request in 984.9 file
  1.  N DFN,ENT,XMY,XMDUZ,XMTEXT,MPIF,XMSUB,FSITE,CMOR,PHONE,RESULT,REVIEWER,COMMENTS,NDATE,II,ICN
  1.  S (HLQUIT,ID,COMMENTS,PHONE,REVIEWER)=""
  1.  F II=1:1 X HLNEXT Q:HLQUIT'>0  D
  1.  .I $P(HLNODE,HL("FS"),1)="NTE" D
  1.  ..S ID=$P(HLNODE,HL("FS"),7),RESULT=$P(HLNODE,HL("FS"),6)
  1.  ..S PHONE=$P(HLNODE,HL("FS"),4)
  1.  ..S COMMENTS=$P(HLNODE,HL("FS"),5)
  1.  .I $P(HLNODE,HL("FS"),1)="EVN" D
  1.  ..S NDATE=$P(HLNODE,HL("FS"),3)
  1.  ..S REVIEWER=$P(HLNODE,HL("FS"),6)
  1.  .I $P(HLNODE,HL("FS"),1)="PID" D
  1.  ..S ICN=+$P(HLNODE,HL("FS"),3)
  1.  S ENT=$O(^MPIF(984.9,"B",ID,0))
  1.  ;; CHANGE FOR NOIS MAD-0900-42526
  1.  I ENT="" D
  1.  .D START^RGHLLOG()
  1.  .D EXC^RGHLLOG(210,"CMOR Request # "_ID_" Does Not Exist CMORs may be out of sync for ICN "_ICN_". HL7 msg# "_HL("MID"))
  1.  .D STOP^RGHLLOG()
  1.  Q:ENT=""
  1.  Q:'$D(^MPIF(984.9,ENT,0))
  1.  S DFN=$P($G(^MPIF(984.9,ENT,0)),"^",4),FSITE=$P($G(^(0)),"^",7)
  1.  S DIC="^DIC(4,",DIC(0)="MXNZ",X=FSITE D ^DIC
  1.  I $G(Y)>0 S FSITE=$P(Y,"^",2)
  1.  K Y,X,DIC
  1.  S DIE="^MPIF(984.9,",DA=ENT,DR="[MPIF RESULT INCOMING]" D ^DIE K DIE,DA,DR
  1.  S XMDUZ="MPI VISTA Package"
  1.  S XMSUB="Request "_ID_" is "_$S(RESULT=4:"approved",1:"disapproved")
  1.  N REQR S REQR=$P($G(^MPIF(984.9,ENT,0)),"^",2) I REQR="" S REQR="AUTO"
  1.  S XMY(REQR)="",XMTEXT="MPIF(1,"
  1.  S MPIF(1,1)=FSITE_" received CMOR request for "_$P($G(^DPT(+$P(^MPIF(984.9,ENT,0),"^",4),0)),"^")_" ("_$E($P(^(0),"^",9),6,9)_")."
  1.  S MPIF(1,2)=XMSUB_"."
  1.  S MPIF(1,3)="Processed by: "_$G(REVIEWER)
  1.  S MPIF(1,4)="Phone: "_$G(PHONE)
  1.  S MPIF(1,5)="Comments: "_$G(COMMENTS)
  1.  D ^XMD
  1.  Q