Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MXMLDOM

MXMLDOM.m

Go to the documentation of this file.
  1. MXMLDOM ;SAIC/DKM - XML Parser - DOM model ;02/27/2002 13:24
  1. ;;7.3;TOOLKIT;**58**;Apr 25, 1995
  1. ;=================================================================
  1. ; This acts as an intermediate client between the event-based XML
  1. ; parser and a client requiring an in-memory document model.
  1. EN(DOC,OPTION) ;
  1. N CBK,SUCCESS,LEVEL,NODE,HANDLE
  1. K ^TMP("MXMLERR",$J)
  1. L +^TMP("MXMLDOM",$J):5
  1. E Q 0
  1. S HANDLE=$O(^TMP("MXMLDOM",$J,""),-1)+1,^(HANDLE)=""
  1. L -^TMP("MXMLDOM",$J)
  1. S CBK("STARTELEMENT")="STARTELE^MXMLDOM"
  1. S CBK("ENDELEMENT")="ENDELE^MXMLDOM"
  1. S CBK("COMMENT")="COMMENT^MXMLDOM"
  1. S CBK("CHARACTERS")="CHAR^MXMLDOM"
  1. S CBK("ENDDOCUMENT")="ENDDOC^MXMLDOM"
  1. S CBK("ERROR")="ERROR^MXMLDOM"
  1. S (SUCCESS,LEVEL,LEVEL(0),NODE)=0,OPTION=$G(OPTION,"V1")
  1. D EN^MXMLPRSE(DOC,.CBK,OPTION)
  1. D:'SUCCESS DELETE(HANDLE)
  1. Q $S(SUCCESS:HANDLE,1:0)
  1. ; Start element
  1. ; Create new child node and push info on stack
  1. STARTELE(ELE,ATTR) ;
  1. N PARENT
  1. S PARENT=LEVEL(LEVEL),NODE=NODE+1
  1. S:PARENT ^TMP("MXMLDOM",$J,HANDLE,PARENT,"C",NODE)=ELE
  1. S LEVEL=LEVEL+1,LEVEL(LEVEL)=NODE,LEVEL(LEVEL,0)=ELE
  1. S ^TMP("MXMLDOM",$J,HANDLE,NODE)=ELE,^(NODE,"P")=PARENT
  1. M ^("A")=ATTR
  1. Q
  1. ; End element
  1. ; Pops element stack
  1. ENDELE(ELE) ;
  1. K LEVEL(LEVEL)
  1. S LEVEL=LEVEL-1
  1. Q
  1. ; Comment data
  1. COMMENT(TXT) ;
  1. D TXT("X")
  1. Q
  1. ; Character data
  1. CHAR(TXT) ;
  1. D TXT("T")
  1. Q
  1. ; Store comment or character data
  1. TXT(SUB) N X,Y,Z
  1. S Y=$O(^TMP("MXMLDOM",$J,HANDLE,LEVEL(LEVEL),SUB,""),-1)
  1. I Y>0,($L($G(^(Y)))+$L(TXT)>200)!($G(BGN)["CDATA") S Y=Y+1 ;*rwf
  1. S:'Y Y=1
  1. F Z=$L(TXT,$C(10)):-1:1 Q:TXT="" D
  1. .S X=$P(TXT,$C(10)),TXT=$P(TXT,$C(10),2,9999)
  1. .S ^(Y)=$G(^(Y))_X
  1. .S:Z>1 Y=Y+1 ;*rwf old .S:Z>1 Y=Y+1,^(Y)=""
  1. Q
  1. ; End of document
  1. ENDDOC S SUCCESS=1
  1. Q
  1. ;Error reporting
  1. ERROR(ERR) ;
  1. N CNT
  1. S CNT=1+$G(^TMP("MXMLERR",$J)),^($J)=CNT
  1. M ^TMP("MXMLERR",$J,CNT)=ERR
  1. Q
  1. ;
  1. ; Below are the external API calls for the interface
  1. ;
  1. ; Delete document instance
  1. DELETE(HANDLE) ;
  1. K ^TMP("MXMLDOM",$J,HANDLE)
  1. Q
  1. ; Name of element at node
  1. NAME(HANDLE,NODE) ;
  1. Q $G(^TMP("MXMLDOM",$J,HANDLE,NODE))
  1. ; Node of next child
  1. CHILD(HANDLE,PARENT,CHILD) ;
  1. Q +$O(^TMP("MXMLDOM",$J,HANDLE,PARENT,"C",+$G(CHILD)))
  1. ; Node of next sibling
  1. SIBLING(HANDLE,NODE) ;
  1. Q +$O(^TMP("MXMLDOM",$J,HANDLE,$$PARENT(HANDLE,NODE),"C",NODE))
  1. ; Parent of node
  1. PARENT(HANDLE,NODE) ;
  1. Q +$G(^TMP("MXMLDOM",$J,HANDLE,NODE,"P"))
  1. ; Text associated with node
  1. TEXT(HANDLE,NODE,RTN) ;
  1. D GETTXT("T")
  1. Q:$Q $D(@RTN)>1
  1. Q
  1. ; Comment associate with node
  1. CMNT(HANDLE,NODE,RTN) ;
  1. D GETTXT("X")
  1. Q:$Q $D(@RTN)>1
  1. Q
  1. ; Retrieve text or comment
  1. GETTXT(SUB) ;
  1. K @RTN
  1. M @RTN=^TMP("MXMLDOM",$J,HANDLE,NODE,SUB)
  1. Q
  1. ; Retrieve next attribute
  1. ATTRIB(HANDLE,NODE,ATTR) ;
  1. Q $O(^TMP("MXMLDOM",$J,HANDLE,NODE,"A",$G(ATTR)))
  1. ; Retrieve attribute value
  1. VALUE(HANDLE,NODE,ATTR) ;
  1. Q $G(^TMP("MXMLDOM",$J,HANDLE,NODE,"A",ATTR))