Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: OCXOCMP1

OCXOCMP1.m

Go to the documentation of this file.
  1. OCXOCMP1 ;SLC/RJS,CLA - ORDER CHECK CODE COMPILER (Compile Data Field Navigation Code) ;12/22/98 13:37
  1. ;;3.0;ORDER ENTRY/RESULTS REPORTING;**32**;Dec 17,1997
  1. ;; ;;ORDER CHECK EXPERT version 1.01 released OCT 29,1998
  1. ;
  1. EN() ;
  1. ;
  1. Q:$G(OCXWARN) OCXWARN
  1. S OCXDF=0 F S OCXDF=$O(^TMP("OCXCMP",$J,"DATA FIELD",OCXDF)) Q:'OCXDF D Q:OCXWARN
  1. .N OCXGETC,OCXGETN,OCXCOD2,OCXERR,OCXNAM,OCXPARM
  1. .N OCXPATH,OCXCON,OCXFCODE,OCXDPTR,OCXREC,OCXATT
  1. .K OCXREC(4) M OCXREC(4)=^OCXS(860.4,OCXDF)
  1. .S OCXNAM=$P($G(OCXREC(4,0)),U,1) Q:'$L(OCXNAM)
  1. .S OCXCON=0 F S OCXCON=$O(OCXREC(4,"LINK",OCXCON)) Q:'OCXCON D Q:$G(OCXWARN)
  1. ..K OCXREC(6) M OCXREC(6)=^OCXS(860.6,OCXCON)
  1. ..S OCXCONN=$P($G(OCXREC(6,0)),U,1) I '$L(OCXCONN) D WARN^OCXOCMPV("Data context IEN #"_(+OCXCON)_" not defined in Data Context file...",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..S OCXCONA=$P($G(OCXREC(6,0)),U,2) I '$L(OCXCONA) D WARN^OCXOCMPV("Data context abbreviation for '"_OCXCONN_"' not defined in Data Context file...",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..S OCXPATH=$G(OCXREC(4,"LINK",OCXCON,"DATAPATH")) I '$L(OCXPATH) D WARN^OCXOCMPV("Data Link-Path not defined",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..S OCXLNK=$O(^OCXS(863.3,"B",OCXPATH,0)) I 'OCXLNK D WARN^OCXOCMPV("Data Link-Path '"_OCXPATH_"' not defined in Meta-Dictionary Link file...",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..S OCXATT=$P($G(^OCXS(863.3,OCXLNK,0)),U,5) I 'OCXATT D WARN^OCXOCMPV("Data Link-Attribute '"_OCXPATH_"' ("_OCXLNK_") not defined in Meta-Dictionary Attribute file...",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..I '$G(OCXAUTO) W:($X>60) ! W "."
  1. ..S $P(OCXREC(4,0),U,3)=""
  1. ..F OCXPARM="OCXO EXTERNAL FUNCTION CALL","OCXO VARIABLE NAME","OCXO VT-BAR PIECE NUMBER","OCXO UP-ARROW PIECE NUMBER","OCXO SEMI-COLON PIECE NUMBER","OCXO HL7 SEGMENT ID","OCXO FILE POINTER" D
  1. ...Q:'$O(^OCXS(863.8,"B",OCXPARM,0))
  1. ...S OCXPARM(OCXPARM)=$$GETPARM(33,OCXPATH,OCXPARM) I '$L(OCXPARM(OCXPARM)) K OCXPARM(OCXPARM) Q
  1. ..S OCXDTYP=$$GETPARM(34,OCXATT,"DATA TYPE")
  1. ..I '$L(OCXDTYP) D WARN^OCXOCMPV("Data Link-Attribute '"_OCXPATH_"' Data Type not defined in Meta-Dictionary Attribute file...",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..S:'OCXDTYP OCXDTYP=$O(^OCXS(864.1,"B",OCXDTYP,0)) S OCXDTYPN=$P($G(^OCXS(864.1,+OCXDTYP,0)),U,1)
  1. ..I '$L(OCXDTYPN) D WARN^OCXOCMPV("Data Link-Attribute '"_OCXPATH_"' Data Type '"_OCXDTYP_"' not defined in Meta-Dictionary Data Type file...",4,OCXDF,$P($T(+1)," ",1)) Q
  1. ..;
  1. ..S OCXFCODE(OCXCON,"AN")=OCXNAM
  1. ..S OCXFCODE(OCXCON,"AV")="OCXDF("_(+OCXDF)_")"
  1. ..S OCXFCODE(OCXCON,"CN")=OCXCONN
  1. ..S OCXFCODE(OCXCON,"CA")=OCXCONA
  1. ..S OCXFCODE(OCXCON,"DTYP","DATA TYPE INDEX")=OCXDTYP
  1. ..S OCXFCODE(OCXCON,"DTYP","DATA TYPE NAME")=OCXDTYPN
  1. ..S OCXFCODE(OCXCON,"DA MODE")=+$P($G(OCXREC(6,0)),U,3)
  1. ..;
  1. ..S $P(^OCXS(860.4,OCXDF,0),U,3)=OCXDTYP
  1. ..Q:$G(OCXERR)
  1. ..;
  1. ..I $L($G(OCXPARM("OCXO EXTERNAL FUNCTION CALL"))) D
  1. ...I '$L($G(OCXPARM("OCXO VARIABLE NAME"))) D
  1. ....I ($E(OCXPARM("OCXO EXTERNAL FUNCTION CALL"),1)="(") S OCXGETC=OCXPARM("OCXO EXTERNAL FUNCTION CALL")
  1. ....E S OCXGETC="$$"_OCXPARM("OCXO EXTERNAL FUNCTION CALL")
  1. ...I $L($G(OCXPARM("OCXO VARIABLE NAME"))) D
  1. ....I (OCXTLOG),((OCXPARM("OCXO EXTERNAL FUNCTION CALL")?.8AN1"^"1.8AN1"(".E)!(OCXPARM("OCXO EXTERNAL FUNCTION CALL")?1.8AN1"(".E)) D I 1
  1. .....N OCXX
  1. .....S OCXX="S OCXOERR=$$TIMELOG(""O"","""_$P(OCXPARM("OCXO EXTERNAL FUNCTION CALL")_"(","(",1)_""")"
  1. .....S OCXX=OCXX_" D "_OCXPARM("OCXO EXTERNAL FUNCTION CALL")
  1. .....S OCXX=OCXX_" S OCXOERR=$$TIMELOG(""I"","""_$P(OCXPARM("OCXO EXTERNAL FUNCTION CALL")_"(","(",1)_""")"
  1. .....D FILECODE(OCXCON,OCXX,"SDS")
  1. ....E D FILECODE(OCXCON,"D "_OCXPARM("OCXO EXTERNAL FUNCTION CALL"),"D")
  1. ....S OCXGETC=$G(OCXPARM("OCXO VARIABLE NAME"))
  1. ..;
  1. ..I '$L($G(OCXPARM("OCXO EXTERNAL FUNCTION CALL"))) D
  1. ...I '$L($G(OCXPARM("OCXO VARIABLE NAME"))) D
  1. ....D WARN^OCXOCMPV("Not enough information in the MetaDictionary link file to generate navigation code.",4,OCXDF,$P($T(+1)," ",1)) S OCXERR=1 Q
  1. ...I $L($G(OCXPARM("OCXO VARIABLE NAME"))) S OCXGETC="$G("_$G(OCXPARM("OCXO VARIABLE NAME"))_")"
  1. ..;
  1. ..Q:OCXWARN
  1. ..;
  1. ..S:$L($G(OCXPARM("OCXO VT-BAR PIECE NUMBER"))) OCXGETC="$P("_OCXGETC_",""|"","_(OCXPARM("OCXO VT-BAR PIECE NUMBER")+1)_")"
  1. ..S:$G(OCXPARM("OCXO UP-ARROW PIECE NUMBER")) OCXGETC="$P("_OCXGETC_",""^"","_OCXPARM("OCXO UP-ARROW PIECE NUMBER")_")"
  1. ..S:$G(OCXPARM("OCXO SEMI-COLON PIECE NUMBER")) OCXGETC="$P("_OCXGETC_","";"","_OCXPARM("OCXO SEMI-COLON PIECE NUMBER")_")"
  1. ..;
  1. ..I ($L($G(OCXPARM("OCXO FILE POINTER")))) D
  1. ...N OCXX S OCXX=OCXPARM("OCXO FILE POINTER")
  1. ...I (OCXX=(+OCXX)) S OCXGETC="$$POINTER("_(+OCXX)_","_OCXGETC_")"
  1. ...E S OCXGETC="$$POINTER("""_(OCXX)_""","_OCXGETC_")"
  1. ..S:(OCXDTYPN="DATE/TIME") OCXGETC="$$DT2INT("_OCXGETC_")"
  1. ..Q:'$L(OCXGETC)
  1. ..S OCXFCODE(OCXCON,"G")=OCXGETC
  1. ..D FILECODE(OCXCON,"S OCXDF("_(+OCXDF)_")="_OCXGETC)
  1. ..I $G(OCXTRACE) D
  1. ...N OCXTXT
  1. ...I $D(OCXPARM("OCXO VARIABLE NAME")) D
  1. ....S OCXTXT="W:$D("_OCXPARM("OCXO VARIABLE NAME")_") !,||LNTAG||,?30,""Data Field: "_$E(OCXNAM,1,25)_" : "",?30,"" ("
  1. ....I $D(OCXCONA) S OCXTXT=OCXTXT_" "_OCXCONA
  1. ....I $D(OCXPARM("OCXO VARIABLE NAME")) S OCXTXT=OCXTXT_" "_$$DBLQT(OCXPARM("OCXO VARIABLE NAME"))
  1. ....I $D(OCXPARM("OCXO HL7 SEGMENT ID")) S OCXTXT=OCXTXT_" "_OCXPARM("OCXO HL7 SEGMENT ID")
  1. ....I $D(OCXPARM("OCXO VT-BAR PIECE NUMBER")) S OCXTXT=OCXTXT_" "_OCXPARM("OCXO VT-BAR PIECE NUMBER")
  1. ....I $D(OCXPARM("OCXO UP-ARROW PIECE NUMBER")) S OCXTXT=OCXTXT_" piece "_OCXPARM("OCXO UP-ARROW PIECE NUMBER")
  1. ....I (OCXDTYPN="DATE/TIME") S OCXTXT=OCXTXT_" ) "",$$INT2DT("_OCXGETC_",1)"
  1. ....E I (OCXDTYPN="BOOLEAN") S OCXTXT=OCXTXT_" ) "",$S(+"_OCXGETC_":""TRUE"",1:""FALSE"")"
  1. ....E S OCXTXT=OCXTXT_" ) "","_OCXGETC
  1. ....I $L($G(OCXPARM("OCXO HL7 SEGMENT ID"))) D
  1. .....S ^TMP("OCXCMP",$J,"DATA FIELD TRACE","HL7",$G(OCXPARM("OCXO HL7 SEGMENT ID")," "),+$G(OCXPARM("OCXO VT-BAR PIECE NUMBER")),+$G(OCXPARM("OCXO UP-ARROW PIECE NUMBER")),OCXDF)=OCXTXT
  1. ....E S ^TMP("OCXCMP",$J,"DATA FIELD TRACE",OCXCON,0,0,+$G(OCXPARM("OCXO UP-ARROW PIECE NUMBER")),OCXDF)=OCXTXT
  1. ...;
  1. ...D FILECODE(OCXCON,"W:$G(OCXTRACE) !,||LNTAG||,?30,""Data Field: "_OCXNAM_" = """""",OCXDF("_(+OCXDF)_"),""""""""")
  1. ..I 0 D FILECODE(OCXCON,"S OCXOERR=$$LOGDF("_(+OCXDF)_","_(+OCXCON)_",OCXDF("_(+OCXDF)_"))")
  1. .;
  1. .;
  1. .M ^TMP("OCXCMP",$J,"DATA FIELD",OCXDF)=OCXFCODE
  1. ;
  1. D BLDDF^OCXOCMPH
  1. ;
  1. Q OCXWARN
  1. ;
  1. DBLQT(X) ;
  1. N A,C F A=35:1:126,0 I A S C=$C(A) Q:'(X[C)
  1. Q:'A X S C=$C(C) S X=$TR(X,"""",C) F Q:'(X[C) S X=$P(X,C,1)_""""""_$P(X,C,2,999)
  1. Q X
  1. ;
  1. FILECODE(OCXCON,CODE,OPLIST) ;
  1. ;
  1. N OCXNDX S OCXNDX=$O(OCXFCODE(OCXCON,9999),-1)+1,OCXFCODE(OCXCON,OCXNDX)=CODE
  1. S:$L($G(OPLIST)) OCXFCODE(OCXCON,OCXNDX,"OPLIST")=OPLIST
  1. Q
  1. ;
  1. UDEFPARM(PARM) ;
  1. Q:$D(OCXPARM(PARM)) 0
  1. D WARN^OCXOCMPV(" '"_PARM_"' parameter missing, in MetaDictionary link file.",4,OCXDF,$P($T(+1)," ",1)) Q 1
  1. ;
  1. GETPARM(FILE,INST,PARM) ;
  1. Q:'$L(FILE) "" Q:'$L(INST) "" Q:'$L(PARM) ""
  1. N OCXP,OCXP1,OCXI,OCXGL
  1. S OCXGL="^OCXS" S:(FILE=1) OCXGL="^OCXD" S:(FILE=7) OCXGL="^OCXD" S:(FILE=10) OCXGL="^OCXD" S FILE=FILE/10+860
  1. Q:'$D(@OCXGL@(+FILE,0)) ""
  1. I (PARM=+PARM),$D(^OCXS(863.8,PARM,0)) S OCXP=PARM
  1. E S OCXP=$O(^OCXS(863.8,"B",PARM,0))
  1. Q:'OCXP ""
  1. I (INST=+INST),$D(@OCXGL@(FILE,INST,0)) S OCXI=INST
  1. E S OCXI=$O(@OCXGL@(FILE,"B",INST,0))
  1. Q:'OCXI "" S OCXP1=$O(@OCXGL@(FILE,OCXI,"PAR","B",OCXP,0)) Q:'OCXP1 ""
  1. Q $G(@OCXGL@(FILE,OCXI,"PAR",OCXP1,"VAL"))
  1. ;