Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: OOPSEMP1

OOPSEMP1.m

Go to the documentation of this file. 
  1. OOPSEMP1 ;HINES/WAA,GTD-E/E Employee data Routines ;3/25/98
  1.  ;;2.0;ASISTS;;Jun 03, 2002
  1.  ;;
  1.  ; Employee/Person Address is now only stored in the 2162A node
  1.  ; of file 2260.  Prior to patch 3 it was stored in the CA1A and
  1.  ; CA2A nodes depending on which form was entered.  The address
  1.  ; is only 'pulled' from this location when printing either form.
  1.  ;
  1. EN1(CALLER) ;  Main Entry Point
  1.  ;INPUT:
  1.  ;     CALLER = "E" FOR EMPLOYEE
  1.  ;            = "S" FOR SUPERVISOR
  1.  ;            = "O" FOR SAFETY OFFICER
  1.  ;            = "W" FOR WORKERS COMP
  1.  ;
  1.  N SSN,IEN,FLD,ODESC,CAT,PAYP,OUT
  1.  S IEN=0,MAX1=528
  1.  Q:DUZ<1
  1.  Q:$G(^VA(200,DUZ,1))=""
  1.  I CALLER="E" D  Q:$G(SSN)=""  Q:$D(^OOPS(2260,"SSN",SSN))<1
  1.  .S SSN=$P(^VA(200,DUZ,1),U,9)
  1.  .I '$G(SSN) W !!,"No SSN on file for this Employee" Q
  1.  .I $D(^OOPS(2260,"SSN",SSN))<1 D
  1.  ..W !!,"An Accident Report has not been created for this Employee"
  1.  D  Q:IEN<1
  1.  .N DIC,X,INT
  1.  .S DIC="^OOPS(2260,"
  1.  .I CALLER="E" S DIC("S")="I $$EMP^OOPSUTL1(Y,SSN)"
  1.  .I CALLER="S" S DIC("S")="I $$SUP^OOPSEMP1(DUZ,Y)"
  1.  .I CALLER="O" S DIC("S")="I $$SAFE^OOPSEMP1(Y)"
  1.  .; PATCH 10
  1.  .I CALLER="W" S DIC("S")="I $$SCR^OOPSWCSE(Y)"
  1.  . ; Patch 5 - new Personnel status logic, make sure it's an employee
  1.  .S DIC("S")=DIC("S")_",$$ISEMP^OOPSUTL4(Y)"
  1.  .S DIC(0)="AEMNZ",DIC("A")="   Select Case: "
  1.  .D ^DIC
  1.  .Q:Y<1
  1.  .Q:$D(DTOUT)!($D(DUOUT))
  1.  .S IEN=$P(Y,U)
  1.  .Q
  1. FORM S FORM=$$GET1^DIQ(2260,IEN,52,"I")
  1.  S FORM=$S(FORM=1:"CA1",FORM=2:"CA2",1:"")
  1.  Q:FORM=""
  1.  ; Patch 8 - changed call from local subroutine, only Signature that
  1.  ; can be cleared is Employee.
  1.  I CALLER="E" D CLRES^OOPSUTL1(IEN,CALLER,FORM)
  1.  ; Patch 8 - Get Occupation Desc from paid, only call if employee
  1.  S FLD=16,ODESC=""
  1.  I $$GET1^DIQ(2260,IEN,2,"I")=1 S ODESC=$$PAID^OOPSUTL1(IEN,FLD)
  1.  ; Get Pay Plan from PAID, if Per Status (CAT) = 2 Set PAYP = "VO"
  1.  S PAYP="",CAT=""
  1.  S CAT=$$GET1^DIQ(2260,IEN,2,"I")
  1.  I CAT<3 D
  1.  . I CAT=1 S PAYP=$$PAID^OOPSUTL1(IEN,20) I $G(PAYP)'="" S PAYP=$$PAYP^OOPSUTL1(PAYP)
  1.  . I CAT=2 S PAYP="VO"
  1.  ; patch 10 - Bill of Rights enhancement
  1.  I CALLER="E" S OUT="" D  I OUT G EXIT      ; if OUT, ^'d out of option
  1.  . I $$GET1^DIQ(2260,IEN,71,"I")'="Y" D BOR
  1.  . I $$GET1^DIQ(2260,IEN,71,"I")'="Y" D WCPBOR^OOPSMBUL(IEN)
  1.  . Q:OUT
  1.  N DR,DIE,SIGN2,OOPS
  1.  ; Patch 8 - had to split routine due to size
  1.  I FORM="CA1" D ^OOPSEMPB
  1.  I FORM="CA2" D ^OOPSEMP2
  1.  S DIE="^OOPS(2260,",DA=IEN
  1.  D ^DIE
  1.  I $D(Y)'=0 G EXIT
  1.  I CALLER="E" D
  1.  . N SIGN
  1.  . ; patch 10 - bill of rights enhancement
  1.  . I $$GET1^DIQ(2260,IEN,71,"I")'="Y" D  Q
  1.  .. W !?5,"Claim cannot be signed until the Bill of Rights Statement is understood."
  1.  . D SIGN(FORM)
  1.  . Q:$G(SIGN)=""
  1.  . I $P(SIGN,U) D EMP^OOPSVAL1          ; new call patch 8
  1.  I CALLER="W" D
  1.  . W !!,"Checking for Safety and Emp Health Ok to sign for Employee."
  1.  . D WCPS4E^OOPSWCSE
  1. EXIT ; quit the routine
  1.  K HSA,CIT,MAX,MAX1,STA,ZIP
  1.  Q
  1. SAFE(IEN) ; Safety Officer Screen
  1.  N VIEW,FORM,TYPE
  1.  S VIEW=1
  1.  S (TYPE,FORM)=$$GET1^DIQ(2260,IEN,52,"I"),FORM=$S(FORM=1:"CA1",FORM=2:"CA2",1:"")
  1.  ; Patch 8 - if ok to send to DOL cant edit
  1.  I $$GET1^DIQ(2260,IEN,67)'="" S VIEW=0
  1.  I $P($$EDSTA^OOPSUTL1(IEN,"E"),U,TYPE) S VIEW=0   ;Emp Signed
  1.  I $P($$EDSTA^OOPSUTL1(IEN,"S"),U,TYPE) S VIEW=0           ;Super Signed
  1.  I $$GET1^DIQ(2260,IEN,51,"I")'=0 S VIEW=0                 ;Case not open
  1.  Q VIEW
  1. SUP(DUZ,IEN) ; Supervisor Screen
  1.  N VIEW,FORM,SIGN,FORMS
  1.  S VIEW=1
  1.  S (FORMS,FORM)=$$GET1^DIQ(2260,IEN,52,"I"),FORM=$S(FORM=1:"CA1",FORM=2:"CA2",1:"")
  1.  I $P($$EDSTA^OOPSUTL1(IEN,"E"),U,FORMS) S VIEW=0 ; Employee Signed
  1.  I $P($$EDSTA^OOPSUTL1(IEN,"S"),U,FORMS) S VIEW=0 ; Super Signed
  1.  I $$GET1^DIQ(2260,IEN,51,"I")'=0 S VIEW=0 ; Case is not open
  1.  ; Patch 8 - if ok to send to DOL cant edit
  1.  I $$GET1^DIQ(2260,IEN,67)'="" S VIEW=0
  1.  I $$GET1^DIQ(2260,IEN,53,"I")'=DUZ,$$GET1^DIQ(2260,IEN,53.1,"I")'=DUZ S VIEW=0 ; Not Supervisor for case
  1.  Q VIEW
  1. SIGN(FORM) ; Sign/validate Document
  1.  N EMP,INC,VALID
  1.  S VALID=0,SIGN=""
  1.  S INC=$$GET1^DIQ(2260,IEN,52,"I")
  1.  W ! D VALIDATE^OOPSUTL4(IEN,FORM,"E",.VALID)
  1.  I 'VALID Q
  1.  I CALLER="E" D
  1.  . I $$GET1^DIQ(200,DUZ,20.4)="" D
  1.  .. W !!,"Please enter a Signature Code.",!
  1.  .. D ^XUSESIG
  1.  . S SIGN=$$SIG^OOPSESIG(DUZ,IEN)
  1.  Q
  1. BOR ; patch 10 - does employee understand Bill of Rights
  1.  N DIE,DA,DR
  1.  S DA=IEN,DIE="^OOPS(2260,",DR=""
  1.  W !
  1.  S DR(1,2260,1)="71I have read and understood the Employee Bill of Rights:"
  1.  D ^DIE I $D(Y) S OUT=1
  1.  Q