Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: OOPSGUI0

OOPSGUI0.m

Go to the documentation of this file. 
  1. OOPSGUI0 ;WIOFO/LLH-RPC routines ;01/02/02
  1.  ;;2.0;ASISTS;**2,4,7,15**;Jun 03, 2002;Build 9
  1.  ;
  1. GETCASE(RESULTS,PERSON,CSTAT,PSTAT,CALL,OPT) ; Subroutine for Case Selection
  1.  ; Returns a list of cases that can be displayed for selection
  1.  ; RESULTS = return array containing, CASE#^IEN^NAME^DATE TIME OCCUR
  1.  ; PERSON  = 0^ if no person selected
  1.  ;           1^PERSON INVOLVED NAME
  1.  ;           2^SUPERVISOR DUZ
  1.  ;           3^USER SSN
  1.  ;           4^CASE NUMBER
  1.  ; CSTAT   = #^#^#^#  0^1^2^3 0=open, 1=closed, 2=deleted, 3=replaced
  1.  ;           99^ if all Case Status should be included
  1.  ;           CSTAT is only set programatically
  1.  ; PSTAT   = 0^  if all personnel status types should be included
  1.  ;           #^#^#^ for each personnel status selected
  1.  ; CALL    = Calling menu, used to assure proper access
  1.  ; OPT     = Option called from, used to assure proper access
  1.  ; 
  1.  K ^TMP("OOPSCASE",DUZ)
  1.  N ARR,CNUM,OOPSDA,PER,STA,SUP,VIEWSUP,VIEWEMP,VALSSN
  1.  I $G(PERSON)="" Q
  1.  I +PERSON=1 D GETPER,SORT G EXIT
  1.  I +PERSON=4 D  G EXIT
  1.  . S CNUM=$P($G(PERSON),U,2) I '$G(CNUM) Q
  1.  . S OOPSDA=$O(^OOPS(2260,"B",CNUM,"")) I '$G(OOPSDA) D  Q
  1.  .. S ^TMP("OOPSCASE",DUZ,1)="No Cases Selectable"
  1.  .. S RESULTS=$NA(^TMP("OOPSCASE",DUZ))
  1.  ..; S RESULTS(0)="No Cases Selectable"
  1.  . S STA=$$GET1^DIQ(2260,OOPSDA,51,"I")
  1.  . I +CSTAT'=99,(CSTAT'[STA_"^") Q  ;allow only selected case status
  1.  . I $$CALLER() S ARR(CNUM)=OOPSDA
  1.  . D SORT
  1.  S CNUM=0
  1.  F  S CNUM=$O(^OOPS(2260,"B",CNUM)) Q:CNUM=""  D
  1.  . S OOPSDA=""
  1.  . F  S OOPSDA=$O(^OOPS(2260,"B",CNUM,OOPSDA)) Q:OOPSDA=""  D
  1.  .. I +PERSON=3 D  Q:'VIEWEMP
  1.  ... S VIEWEMP=1,VALSSN=$P($G(PERSON),U,2)
  1.  ... I $$GET1^DIQ(2260,OOPSDA,5,"I")'=VALSSN  D
  1.  .... S VIEWEMP=0
  1.  .... S ^TMP("OOPSCASE",DUZ,1)="No Cases Selectable"
  1.  .... S RESULTS=$NA(^TMP("OOPSCASE",DUZ))
  1.  .. S STA=$$GET1^DIQ(2260,OOPSDA,51,"I")
  1.  .. I +CSTAT'=99,(CSTAT'[STA_"^") Q  ;allow only selected case status
  1.  .. S PER=$$GET1^DIQ(2260,OOPSDA,2,"I")
  1.  .. I (+PSTAT)&(PSTAT'[(PER_"^")) Q      ;allow only selected per status
  1.  .. I +PERSON=2 D  Q:'VIEWSUP
  1.  ... S VIEWSUP=1,SUP=$P(PERSON,U,2)
  1.  ... I $$GET1^DIQ(2260,OOPSDA,53,"I")'=SUP,($$GET1^DIQ(2260,OOPSDA,53.1,"I")'=SUP) D  Q
  1.  ....; S RESULTS(0)="No Cases Selectable",VIEWSUP=0
  1.  .... S ^TMP("OOPSCASE",DUZ,1)="No Cases Selectable",VIEWSUP=0
  1.  .... S RESULTS=$NA(^TMP("OOPSCASE",DUZ))
  1.  .. I $$CALLER() S CNUM=$$GET1^DIQ(2260,OOPSDA,.01),ARR(CNUM)=OOPSDA
  1.  D SORT
  1. EXIT ; quit the routine
  1.  Q
  1. GETPER ; Person Name passed in, match
  1.  ; See above for documentation
  1.  N NM
  1.  S OOPSDA="",NM=$P(PERSON,U,2)
  1.  F  S OOPSDA=$O(^OOPS(2260,"C",NM,OOPSDA)) Q:OOPSDA=""  D
  1.  . S STA=$$GET1^DIQ(2260,OOPSDA,51,"I")
  1.  . I +CSTAT'=99,(CSTAT'[STA_"^") Q  ;allow only selected case status
  1.  . S PER=$$GET1^DIQ(2260,OOPSDA,2,"I")
  1.  . I (+PSTAT)&(PSTAT'[(PER_"^")) Q      ;allow only selected per status
  1.  . I $$CALLER() S CNUM=$$GET1^DIQ(2260,OOPSDA,.01),ARR(CNUM)=OOPSDA
  1.  Q
  1. CALLER() ; Check to make sure case should be included
  1.  N EES,ESTAT,FLD,INC,SIG,SSN,VIEWC
  1.  S VIEWC=1
  1.  S INC=$$GET1^DIQ(2260,OOPSDA,52,"I")
  1.  ; get users SSN 
  1.  S SSN=$$GET1^DIQ(200,DUZ,9)
  1.  ; make sure user cannot access claim from any menu but Employee
  1.  I CALL'="E",($$GET1^DIQ(2260,OOPSDA,5,"I")=SSN) S VIEWC=0 Q VIEWC
  1.  ; Claim already sent to DOL, can't edit, Caller / Option doesnt matter
  1.  ; unless the Option = "CHGCASE"
  1.  ; Patch 4 llh - should also be able to create amendment.  NOTE: Case
  1.  ;               status should always = open
  1.  ; patch 7 llh - allow access if also opt=iocome
  1.  I ($$GET1^DIQ(2260,OOPSDA,66)'=""),(OPT'="CHGCASE"),(OPT'="PRINTCA"),(OPT'=2162),(OPT'="CRAMEND"),(OPT'="IOCOME") S VIEWC=0 Q VIEWC
  1.  ; for any option from the supervisor menu
  1.  I CALL="S" D  I 'VIEWC Q VIEWC
  1.  . I $$GET1^DIQ(2260,OOPSDA,53,"I")'=DUZ,($$GET1^DIQ(2260,OOPSDA,53.1,"I")'=DUZ) S VIEWC=0 Q
  1.  ; if opt = 2162
  1.  I OPT=2162 D  Q VIEWC
  1.  . I $$GET1^DIQ(2260,OOPSDA,51,"I")=1 S VIEWC=0  ; closed, can't edit
  1.  . ; signed SO, coming from Supervisor menu, cant access
  1.  . I (CALL="S"),+$$EDSTA^OOPSUTL1(OOPSDA,"O") S VIEWC=0
  1.  . I CALL="H" D
  1.  .. I $P($$EDSTA^OOPSUTL1(OOPSDA,"S"),U,3)!(+$$EDSTA^OOPSUTL1(OOPSDA,"O")) S VIEWC=0
  1.  . I CALL="W" D
  1.  .. I +$$EDSTA^OOPSUTL1(OOPSDA,"O") S VIEWC=0   ;safety signed cant see
  1.  ; if opt = CA1 only return/allow CA1's, caller doesnt matter
  1.  I OPT="CA1",INC'=1 S VIEWC=0 Q VIEWC
  1.  ; if opt = CA2 only return/allow CA2's, caller doesnt matter
  1.  I OPT="CA2",INC'=2 S VIEWC=0 Q VIEWC
  1.  I CALL="E" D  Q VIEWC
  1.  . I '$$ISEMP^OOPSUTL4(OOPSDA) S VIEWC=0 Q
  1.  . I '$G(SSN) S VIEWC=0 Q
  1.  . I $D(^OOPS(2260,"SSN",SSN))<1 S VIEWC=0 Q
  1.  . ; user SSN must = case IEN from Employee menu
  1.  . I $$GET1^DIQ(2260,OOPSDA,5,"I")'=SSN S VIEWC=0 Q
  1.  . S SIG=$$EDSTA^OOPSUTL1(OOPSDA,"S")
  1.  . I (OPT'="PRINTCA"),$P(SIG,U,INC) S VIEWC=0 Q
  1.  I CALL="S" D  Q VIEWC
  1.  . ; not Super or Sec Super, can't access form, regardless of form type
  1.  . I $$GET1^DIQ(2260,OOPSDA,53,"I")'=DUZ&($$GET1^DIQ(2260,OOPSDA,53.1,"I")'=DUZ) S VIEWC=0 Q
  1.  . ; Supervisor cannot complete their own form.
  1.  . I $$GET1^DIQ(2260,OOPSDA,5,"I")=SSN S VIEWC=0 Q
  1.  . I OPT="CA1"!(OPT="CA2") D  Q
  1.  .. ; if form CA, must be employee to complete
  1.  .. I '$$ISEMP^OOPSUTL4(OOPSDA) S VIEWC=0 Q
  1.  .. ; commented out next 2 lines, ? whether wanted by TAG 11/1/01 llh
  1.  .. ; Employee hasn't signed, super can't get to
  1.  .. ; I '$P($$EDSTA^OOPSUTL1(OOPSDA,"E"),U,INC) S VIEWC=0 Q
  1.  .. ; Supervisor has signed, can't re-edit
  1.  .. I $P($$EDSTA^OOPSUTL1(OOPSDA,"S"),U,INC) S VIEWC=0 Q
  1.  I CALL="O"!(CALL="W")!(CALL="H") D  Q VIEWC
  1.  . I OPT="CA1"!(OPT="CA2") D  Q
  1.  .. I '$$ISEMP^OOPSUTL4(OOPSDA) S VIEWC=0 Q
  1.  . I OPT="WCSIGN" D  Q
  1.  .. S ESTAT=$$EDSTA^OOPSUTL1(OOPSDA,"E")
  1.  .. I '$$ISEMP^OOPSUTL4(OOPSDA) S VIEWC=0 Q
  1.  .. I CALL'="W",$P(ESTAT,U,INC) S VIEWC=0 Q
  1.  .. I CALL="W" D
  1.  ... S FLD=$S(INC=1:119,INC=2:221,1:"") I 'FLD S VIEWC=0 Q
  1.  ... S EES=$$GET1^DIQ(2260,OOPSDA,FLD,"I")
  1.  ... ; employee hasn't signed, ok for WC to sign
  1.  ... I 'EES Q
  1.  ... ; employee signed, not signed by person accessing claim, no access
  1.  ... I EES'=DUZ S VIEWC=0 Q
  1.  ... I $P($$EDSTA^OOPSUTL1(OOPSDA,"S"),U,INC) S VIEWC=0 ;Sup Sign, no acc
  1.  . I OPT="WCEMPSIGN" D  Q
  1.  .. N CALLER,SVIEW
  1.  .. S CALLER=CALL
  1.  .. I $$GET1^DIQ(2260,OOPSDA,51,"I") S VIEWC=0 Q    ; claim must be open
  1.  .. ;V2_P15 02/13/08 llh - remove requirement Safety or Occ Health must sign first
  1.  .. ;I $$GET1^DIQ(2260,OOPSDA,77)="" S VIEWC=0 Q
  1.  .. ;I $$GET1^DIQ(2260,OOPSDA,80)="" S VIEWC=0 Q
  1.  .. S SVIEW=$$SCR^OOPSWCSE(OOPSDA) I 'SVIEW S VIEWC=0 Q
  1.  I CALL="U" D  Q VIEWC
  1.  . I '+$$EDSTA^OOPSUTL1(OOPSDA,"O") S VIEWC=0 Q
  1.  . I '$P($$EDSTA^OOPSUTL1(OOPSDA,"S"),U,3) S VIEWC=0 Q
  1.  Q VIEWC
  1. SORT ; put cases in reverse number order
  1.  N CN,CNUM,OOPSDA,SSN,DOI
  1.  S ^TMP("OOPSCASE",DUZ,0)="",CNUM="",CN=1
  1.  I '$D(ARR) S RESULTS(0)="No Cases Selectable"  D
  1.  . S ^TMP("OOPSCASE",DUZ,1)="No Cases Selectable",VIEWSUP=0
  1.  . S RESULTS=$NA(^TMP("OOPSCASE",DUZ))
  1.  F  S CNUM=$O(ARR(CNUM),-1) Q:CNUM=""  D
  1.  . S OOPSDA=ARR(CNUM)
  1.  . S NM=$$GET1^DIQ(2260,OOPSDA,1)
  1.  . S DOI=$$GET1^DIQ(2260,OOPSDA,4)
  1.  . S SSN=$$GET1^DIQ(2260,OOPSDA,5)
  1.  . I CALL="U" S (NM,DOI,SSN)=""
  1.  . S ^TMP("OOPSCASE",DUZ,CN)=CNUM_U_DOI_U_NM_U_OOPSDA_U_SSN_$C(10),CN=CN+1
  1.  S RESULTS=$NA(^TMP("OOPSCASE",DUZ))
  1.  Q