Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: OOPSVAL1

OOPSVAL1.m

Go to the documentation of this file. 
  1. OOPSVAL1 ;HINES/WAA,GTD-Validate and Sign data Routines ;3/25/98
  1.  ;;2.0;ASISTS;;Jun 03, 2002
  1.  ;;
  1.  ;  Note:  At EMP+18 added check to see if code being executed from
  1.  ;         the broker.  ASISTS V2.0
  1.  ;
  1. EN1(CALLER) ;  Main Entry Point
  1.  ;INPUT:
  1.  ;     CALLER = "E" FOR EMPLOYEE
  1.  ;            = "S" FOR SUPERVISOR
  1.  ;            = "O" FOR SAFETY OFFICER
  1.  ;            = "W" FOR WORKER'S COMP
  1.  ;
  1.  N SSN,IEN,SIGN,EDIT,FORM,GRP,SUP,I,CIT,HSA,STA,ZIP
  1.  S IEN=0
  1.  Q:DUZ<1
  1.  Q:$G(^VA(200,DUZ,1))=""
  1.  I CALLER="E" S SSN=$P(^VA(200,DUZ,1),U,9) Q:$D(^OOPS(2260,"SSN",SSN))<1
  1.  D  Q:IEN<1
  1.  .N DIC,X
  1.  .S DIC="^OOPS(2260,"
  1.  .I CALLER="E" S DIC("S")="I $$EMPSCR^OOPSVAL1(Y)"
  1.  .I CALLER="S" S DIC("S")="I $$SUPSCR^OOPSVAL1(Y)"
  1.  .I CALLER="O" S DIC("S")="I $$SAFSCR^OOPSVAL1(Y)"
  1.  .I CALLER="W" S DIC("S")="I $$WCSCR^OOPSVAL1(Y)"
  1.  .S DIC("S")=DIC("S")_",'$$GET1^DIQ(2260,Y,51,""I"")"
  1.  .S DIC(0)="AEMNZ",DIC("A")="   Select Case: "
  1.  .D ^DIC
  1.  .Q:Y<1
  1.  .Q:$D(DTOUT)!($D(DUOUT))
  1.  .S IEN=$P(Y,U)
  1.  .Q
  1.  I CALLER="O" D
  1.  .S FORM="2162"
  1.  .D FORM
  1.  .Q
  1.  I CALLER="E" D
  1.  .S FORM=$$GET1^DIQ(2260,IEN,52,"I")
  1.  .S FORM=$S(FORM=1:"CA1",FORM=2:"CA2",1:"")
  1.  .I FORM'="" D FORM
  1.  .Q
  1.  I CALLER="S" D
  1.  .N CNT,PAUSE,OUT,FORM,EDIT
  1.  .S (PAUSE,OUT)=0
  1.  .; Do block below needed so that for loop below only runs for "S"
  1.  .D
  1.  ..N INC,STAT,ESTAT
  1.  ..S INC=$$GET1^DIQ(2260,IEN,52,"I")
  1.  ..S STAT=$$EDSTA^OOPSUTL1(IEN,"S")
  1.  ..; added check for employee having signed CA1
  1.  ..S ESTAT=$$EDSTA^OOPSUTL1(IEN,"E")
  1.  ..; if employee signed ok to let super select if no forms signed
  1.  ..I $P(ESTAT,U,INC) D
  1.  ...I '$P(STAT,U,INC),'$P(STAT,U,3) D SELECT^OOPSSUP1 Q
  1.  ...S EDIT=$S('$P(STAT,U,3):2162,'$P(STAT,U,INC):$P("CA1^CA2",U,INC),1:"")
  1.  ..I '$P(ESTAT,U,INC) D  ;  Employee has not signed CA1/CA2
  1.  ...I '$P(STAT,U,3) S EDIT=2162 Q
  1.  ...S EDIT=""
  1.  .I EDIT="" Q
  1.  .F CNT=1:1 S FORM=$P(EDIT,U,CNT) Q:FORM=""  D:PAUSE END Q:OUT  D
  1.  ..D FORM S PAUSE=1
  1.  ..Q
  1.  .Q
  1.  I CALLER="W" D
  1.  .S FORM=$$GET1^DIQ(2260,IEN,52,"I")
  1.  .S FORM=$S(FORM=1:"CA1",FORM=2:"CA2",1:"")
  1.  . N DIR,Y
  1.  . S WOK=1
  1.  . W !
  1.  . S DIR("A")="OK to transmit to DOL"
  1.  . S DIR(0)="SBM^Y:Yes;N:No"
  1.  . D ^DIR
  1.  . I Y="Y",FORM'="" D FORM
  1.  .Q
  1. EXIT ;
  1.  K SUP,WOK                      ; left over from ^OOPSDIS
  1.  Q
  1. EMPSCR(IEN) ;
  1.  N VIEW
  1.  S VIEW=1
  1.  I '$$EMP^OOPSUTL1(IEN,SSN) S VIEW=0
  1.  E  D
  1.  .N INC
  1.  .S INC=$$GET1^DIQ(2260,IEN,52,"I")
  1.  .I $P($$EDSTA^OOPSUTL1(IEN,"E"),U,INC) S VIEW=0
  1.  .Q
  1.  Q VIEW
  1. SUPSCR(IEN) ;
  1.  N VIEW
  1.  S VIEW=1
  1.  I '$$SUPSCR^OOPSUTL2(DUZ,IEN) S VIEW=0
  1.  E  D
  1.  .N INC,STAT,ESTAT,CAT
  1.  .S CAT=$$GET1^DIQ(2260,IEN,2,"I")              ; Personnel status
  1.  .S INC=$$GET1^DIQ(2260,IEN,52,"I")             ; Injury/Illness
  1.  .S STAT=$$EDSTA^OOPSUTL1(IEN,"S")              ; sup signed forms
  1.  .S ESTAT=$$EDSTA^OOPSUTL1(IEN,"E")             ; emp signed forms
  1.  .; Added Non-PAID employee to check, not emp, 2162 signed
  1.  .; Patch 5 - logic changed for new Personnel Categories
  1.  .I '$$ISEMP^OOPSUTL4(IEN),$P(STAT,U,3) S VIEW=0 Q
  1.  .; super signed 2162 and CA1/CA2
  1.  .I $P(STAT,U,INC),$P(STAT,U,3) S VIEW=0 Q
  1.  .; emp not signed CA1/CA2, super signed 2162, not signed CA1/CA2 - no
  1.  .I '$P(ESTAT,U,INC),$P(STAT,U,3),'$P(STAT,U,INC) S VIEW=0 Q
  1.  .Q
  1.  Q VIEW
  1. WCSCR(IEN) ; Patch 8 - Worker's Comp Screen
  1.  N INC,VIEW,ESTAT,STAT
  1.  S VIEW=1
  1.  S INC=$$GET1^DIQ(2260,IEN,52,"I")
  1.  S ESTAT=$$EDSTA^OOPSUTL1(IEN,"E")             ;really defensive code
  1.  I '$P(ESTAT,U,INC) S VIEW=0                   ;should never be needed
  1.  S STAT=$$EDSTA^OOPSUTL1(IEN,"S")              ;super must have signed
  1.  I '$P(STAT,U,INC) S VIEW=0
  1.  I $$GET1^DIQ(2260,IEN,66)'="" S VIEW=0        ;Case sent to DOL
  1.  I $$GET1^DIQ(2260,IEN,67)'="" S VIEW=0        ;WC already signed
  1.  I $$GET1^DIQ(2260,IEN,51,"I")'=0 S VIEW=0     ;Case is not open
  1.  I '$$ISEMP^OOPSUTL4(IEN) S VIEW=0             ;not employee
  1.  Q VIEW
  1. SAFSCR(IEN) ;
  1.  N VIEW
  1.  S VIEW=1
  1.  I '$$SAFETY^OOPSUTL2(IEN) S VIEW=0
  1.  I $$EDSTA^OOPSUTL1(IEN,"O") S VIEW=0
  1.  Q VIEW
  1. END ;End of Form pause
  1.  N DIR
  1.  W !
  1.  S DIR(0)="E" D ^DIR
  1.  S:$D(DIRUT) OUT=1 Q
  1.  Q
  1. FORM ;Select Form
  1.  D:'$G(PAUSE,0) ^OOPSDIS
  1.  N OUT
  1.  I CALLER="E" D  Q:$G(OUT)
  1.  . I $$GET1^DIQ(2260,IEN,71,"I")'="Y" D BOR^OOPSEMP1
  1.  . I $$GET1^DIQ(2260,IEN,71,"I")'="Y" D  Q
  1.  .. W !?5,"Claim cannot be signed until the Bill of Rights Statement is understood."
  1.  .. D WCPBOR^OOPSMBUL(IEN)
  1.  .. S OUT=1
  1.  I '$G(OUT) D SIGN(FORM) Q:(+SIGN=0)
  1.  I CALLER="E",($$GET1^DIQ(2260,IEN,71,"I")="Y") D EMP
  1.  I CALLER="S" D SUP
  1.  I CALLER="O" D SAF
  1.  I CALLER="W" D WCP
  1.  Q
  1. SIGN(FORM) ; Sign/validate Document
  1.  N EMP,INC,VALID,OUT
  1.  S VALID=0,SIGN=""
  1.  S INC=$$GET1^DIQ(2260,IEN,52,"I")
  1.  D VALIDATE^OOPSUTL4(IEN,FORM,CALLER,.VALID)
  1.  I 'VALID D END Q
  1.  S SIGN=$$SIG^OOPSESIG(DUZ,IEN)
  1.  Q
  1. EMP ; Employee Sign off
  1.  N RECORD,UNIREP,X,X1,X2
  1.  S UNIREP=""
  1.  S RECORD=$G(^OOPS(2260,IEN,"CA"))
  1.  S X=$P($G(^VA(200,DUZ,20)),U,2)
  1.  S X1=DUZ
  1.  I FORM="CA1" D
  1.  . I '$$BROKER^XWBLIB S $P(^OOPS(2260,IEN,"CA1ES"),U,1,3)=SIGN
  1.  . S X2=$$CA1SUM^OOPSUTL6()
  1.  I FORM="CA2" D
  1.  . I '$$BROKER^XWBLIB S $P(^OOPS(2260,IEN,"CA2ES"),U,1,3)=SIGN
  1.  . S X2=$$CA2SUM^OOPSUTL6()
  1.  D EN^XUSHSHP
  1.  S $P(RECORD,U,9)=1
  1.  S $P(RECORD,U,7)=X
  1.  S ^OOPS(2260,IEN,"CA")=RECORD
  1.  D EMP^OOPSMBUL(IEN)
  1.  ; patch 10 - bill of rights enhancement
  1.  I (CALLER="E")&('$$BROKER^XWBLIB) D
  1.  . D CONSENT
  1.  . I $$GET1^DIQ(2260,IEN,72,"I")="Y" D UNION
  1.  . I UNIREP D CONSENT^OOPSMBUL(IEN,UNIREP)
  1.  Q
  1. SUP ;Supervisor Sign off
  1.  I FORM="CA1" S $P(^OOPS(2260,IEN,"CA1ES"),U,4,6)=SIGN
  1.  I FORM="CA2" S $P(^OOPS(2260,IEN,"CA2ES"),U,4,6)=SIGN
  1.  I FORM="2162" S $P(^OOPS(2260,IEN,"2162ES"),U,1,3)=SIGN D SAFETY^OOPSMBUL(IEN)
  1.  ; Patch 8
  1.  I FORM'="2162" D SUPS^OOPSMBUL(IEN),UNION^OOPSMBUL(IEN)
  1.  Q
  1. WCP ; Patch 8
  1.  I FORM="CA1" S $P(^OOPS(2260,IEN,"WCES"),U,1,3)=SIGN
  1.  I FORM="CA2" S $P(^OOPS(2260,IEN,"WCES"),U,1,3)=SIGN
  1.  N DA,DR,DIE
  1.  I $P(SIGN,U) D
  1.  . S DR="",DIE="^OOPS(2260,",DA=IEN
  1.  . S DR(1,2260,1)="67////^S X=$P(SIGN,U)"
  1.  . S DR(1,2260,5)="68////^S X=$P(SIGN,U,2)"
  1.  . S DR(1,2260,10)="69////^S X=$P(SIGN,U,3)"
  1.  . D ^DIE
  1.  D WCP^OOPSMBUL(IEN,"S")
  1.  Q
  1. SAF ; Safety Officer Sign off
  1.  I FORM="2162" S $P(^OOPS(2260,IEN,"2162ES"),U,4,6)=SIGN
  1.  Q
  1.  N DIC,DIE,DA,DR,OOPS
  1.  S DA=IEN,DIC="^OOPS(2260,",OUT=""
  1.  K DIQ S DIQ(0)="IE"
  1.  S DIQ="OOPS",DR=".01;2;3;4;7;13;14;16;17;18;52;53;53.1" D EN^DIQ1
  1.  S DR=""
  1.  W !!,"My consent is given for the release of case number "_OOPS(2260,IEN,.01,"E")
  1.  W !,"information for review by local bargaining units for accident and"
  1.  W !,"illness tracking purposes only.  Name, address, social security "
  1.  W !,"number, date of birth, and telephone number will not be included"
  1.  W !,"in the information provided to the bargaining units."
  1.  W !!,"With your consent, the following information will be provided"
  1.  W !,"to the local bargaining unit for your review."
  1.  W !!,"Dt/Tme Occurrence: ",OOPS(2260,IEN,4,"E")
  1.  W ?40,"   Inj/Ill: ",OOPS(2260,IEN,52,"E")
  1.  W !," Personnel Status: ",OOPS(2260,IEN,2,"E")
  1.  W ?40,"       Sex: ",OOPS(2260,IEN,7,"E")
  1.  W !,"   Station Number: ",OOPS(2260,IEN,13,"I")
  1.  W ?40," Education: ",$E(OOPS(2260,IEN,18,"E"),1,26)
  1.  W !,"  Cost Center/Org: ",OOPS(2260,IEN,14,"E")
  1.  W ?40," Grade/Stp: ",OOPS(2260,IEN,16,"E")_"/"_OOPS(2260,IEN,17,"E")
  1.  W !,"       Supervisor: ",$E(OOPS(2260,IEN,53,"E"),1,19)
  1.  W ?40,"Type Incid: ",$E(OOPS(2260,IEN,3,"E"),1,26)
  1.  W !,"  Secondary Super: ",$E(OOPS(2260,IEN,53.1,"E"),1,20),!
  1.  S DR(1,2260,1)="72Consent Given://^S X=""N"""
  1.  W !!?5,"If you give consent, you will be prompted to select the"
  1.  W !?5,"Union to send the bulletin to.  The bulletin will be sent"
  1.  W !?5,"immediately after the Union has been selected.",!
  1.  S DIE="^OOPS(2260,"
  1.  D ^DIE I $D(Y) S OUT=1
  1.  Q
  1. UNION ; Get the Union Representative's DUZ
  1.  N DIC,DA,Y
  1.  S DIC="^OOPS(2263.7,",DIC(0)="AEQZ"
  1.  S DIC("A")="Select UNION to send bulletin to: "
  1.  D ^DIC
  1.  I +Y S UNIREP=$$GET1^DIQ(2263.7,+Y,2,"I")
  1.  I 'UNIREP D
  1.  . W !!?3,"Cannot sent a bulletin to Union, No Union Representative name was selected"
  1.  . W !?3,"or one is not on file.  Contact your Workers' Compensation Specialist."
  1.  Q