Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORAMY

ORAMY.m

Go to the documentation of this file. 
  1. ORAMY ; ISL/JER - Anticoagulation Management Installation ;12/16/09  15:31
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**307**;Dec 17, 1997;Build 60
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified
  1.  Q
  1. POST ; Post-install routine
  1.  D ATTRPT
  1.  D REGRPCS
  1.  D PARAM
  1.  Q
  1. ATTRPT ; Set Anticoagulation Flowsheet Report as item in ORRPW REPORT CATEGORIES
  1.  N ORRIEN,ORRNM,ORERRF,ORFDA,ORAFIEN,ORAFNM,ORLNE
  1.  N ORMSG,ORTXT
  1.  K ORMSG
  1.  D BMES^XPDUTL(" Attaching Anticoagulation Flowsheet to ORRPW REPORT CATEGORIES...")
  1.  S ORRNM="ORRPW REPORT CATEGORIES"
  1.  S ORRIEN=$$FIND1^DIC(101.24,"","X",ORRNM,"","","")
  1.  ;If ORRPW REPORT CATEGORIES not found, error
  1.  I ORRIEN'>0 D  I 1
  1.  . S ORMSG(1)="**"
  1.  . S ORMSG(2)="** "_ORRNM_" not found **"
  1.  . S ORMSG(3)="**"
  1.  . D MES^XPDUTL(.ORMSG) K ORMSG
  1.  . S ORERRF=1
  1.  ELSE  D
  1.  . S ORAFNM="ORAM ANTICOAG REPORT"
  1.  . S ORAFIEN=$$FIND1^DIC(101.24,"","X",ORAFNM,"","","")
  1.  . ;If ORAM ANTICOAG REPORT not found, error
  1.  . I ORAFIEN'>0 D  Q
  1.  . . S ORMSG(1)="**"
  1.  . . S ORMSG(2)="** "_ORAFNM_" not found **"
  1.  . . S ORMSG(3)="**"
  1.  . . D MES^XPDUTL(.ORMSG) K ORMSG
  1.  . . S ORERRF=1
  1.  . ;Attach ORAM ANTICOAG REPORT to ORRPW REPORT CATEGORIES
  1.  . N ORFDA,ORIEN,ORMSG
  1.  . S ORFDA(101.241,"?+10,"_ORRIEN_",",.01)=ORAFIEN
  1.  . D UPDATE^DIE("","ORFDA","ORIEN","ORMSG")
  1.  . ;Check for error
  1.  . I $D(ORMSG("DIERR")) D  Q
  1.  . . S ORMSG(1)="**"
  1.  . . S ORMSG(2)="** Unable to attach "_ORAFNM_" to "_ORRNM_" **"
  1.  . . S ORMSG(3)="**"
  1.  . . D MES^XPDUTL(.ORMSG) K ORMSG
  1.  . . S ORERRF=1
  1.  . S ORMSG(1)=" "
  1.  . S ORMSG(2)=" ... "_ORAFNM_$S($G(ORIEN(10,0))="?":" already",1:"")_" attached to "_ORRNM_" ..."
  1.  . D MES^XPDUTL(.ORMSG) K ORMSG
  1.  ;Check for error
  1.  I $G(ORERRF) D
  1.  . S ORMSG(1)="** Post-installation interrupted"
  1.  . S ORMSG(2)="** Please contact Enterprise VistA Support"
  1.  . D MES^XPDUTL(.ORMSG) K ORMSG
  1.  Q
  1.  ;
  1. REGRPCS ; Register RPCS
  1.  D BMES^XPDUTL(" Registering RPCs with Context Menu ORAM ANTICOAGULATION CONTEXT...")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","ORWPCE SCDIS")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","ORWPCE SCSEL")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","ORWTPP GETCOS")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","ORWTPP GETDCOS")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","TIU SIGN RECORD")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","TIU CREATE RECORD")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","TIU DELETE RECORD")
  1.  D REGISTER("ORAM ANTICOAGULATION CONTEXT","TIU REQUIRES COSIGNATURE")
  1.  Q
  1.  ;
  1. REGISTER(OPTION,RPC) ; Call FM Updater to register each RPC
  1.  ; Input  -- OPTION   Option file (#19) Name field (#.01)
  1.  ;           RPC      RPC sub-file (#19.05) RPC field (#.01)
  1.  ; Output -- None
  1.  N FDA,FDAIEN,ERR,DIERR
  1.  S FDA(19,"?1,",.01)=OPTION
  1.  S FDA(19.05,"?+2,?1,",.01)=RPC
  1.  D UPDATE^DIE("E","FDA","FDAIEN","ERR")
  1.  Q
  1. PARAM ; main (initial) parameter transport routine
  1.  N ORENT,IDX,ROOT,REF,ORVAL,I
  1.  D BMES^XPDUTL(" Installing List of Indications for Care...")
  1.  S ROOT=$NAME(^TMP("ORAMY",$J)) K @ROOT
  1.  D LOAD(ROOT)
  1.  S IDX=0,ORENT="PKG.ORDER ENTRY/RESULTS REPORTING"
  1.  F  S IDX=$O(@ROOT@(IDX)) Q:'IDX  D
  1.  . N ORPAR,ORINST,ORIVAL,OREVAL,ORERR
  1.  . S ORPAR=$P(@ROOT@(IDX,"KEY"),U),ORINST=$P(^("KEY"),U,2)
  1.  . S ORIVAL=$P(@ROOT@(IDX,"VAL"),U),OREVAL=$P(^("VAL"),U,2)
  1.  . D BMES^XPDUTL(" Installing "_ORINST_" = "_OREVAL)
  1.  . D EN^XPAR(ORENT,ORPAR,ORINST,ORIVAL,.ORERR)
  1.  . I +$G(ORERR)>0 D BMES^XPDUTL(" Error Occurred for "_ORINST_" = "_OREVAL_": "_$P(ORERR,U,2))
  1.  K @ROOT
  1.  Q
  1. LOAD(ROOT) ; load data into ^TMP (expects ROOT to be defined)
  1.  N I,REF
  1.  S I=1,ROOT=$E(ROOT,1,$L(ROOT)-1)_","
  1.  F  S REF=$P($T(DATA+I),";",3,999) Q:REF=""  D
  1.  . N ORVAL
  1.  . S ORVAL=$P($T(DATA+I+1),";",3,999)
  1.  . S @(ROOT_REF)=ORVAL,I=I+2
  1.  Q
  1. DATA ; parameter data
  1.  ;;14701,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^A Fib
  1.  ;;14701,"VAL")
  1.  ;;`2557^427.31
  1.  ;;14702,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^A Flutter
  1.  ;;14702,"VAL")
  1.  ;;`2558^427.32
  1.  ;;14703,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^CVA
  1.  ;;14703,"VAL")
  1.  ;;`9069^436.
  1.  ;;14704,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^DVT
  1.  ;;14704,"VAL")
  1.  ;;`15011^453.89
  1.  ;;14705,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^Hypercoag State
  1.  ;;14705,"VAL")
  1.  ;;`13798^289.81
  1.  ;;14706,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^PE
  1.  ;;14706,"VAL")
  1.  ;;`13157^415.19
  1.  ;;14707,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^TIA
  1.  ;;14707,"VAL")
  1.  ;;`2591^435.9
  1.  ;;14708,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^Valve-Tissue
  1.  ;;14708,"VAL")
  1.  ;;`11516^V42.2
  1.  ;;14709,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^Valve-Mech
  1.  ;;14709,"VAL")
  1.  ;;`11527^V43.3
  1.  ;;14710,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^L/T (Current) Anticoag Use
  1.  ;;14710,"VAL")
  1.  ;;`13194^V58.61
  1.  ;;14711,"KEY")
  1.  ;;ORAM INDICATIONS FOR CARE^Enctr for Tx Drug Monitoring
  1.  ;;14711,"VAL")
  1.  ;;`13529^V58.83