Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORKLR

ORKLR.m

Go to the documentation of this file. 
  1. ORKLR ;slc/CLA - Order checking support procedure for lab orders ;May 17, 2019@17:00
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**6,32,51,92,105,243,331,510**;Dec 17, 1997;Build 11
  1.  ;
  1.  Q
  1. DUP(ORKLR,OI,ORDFN,NEWORDT,SPECIMEN) ; return duplicate lab order info
  1.  N ORL,DDT,ODT,ORN,ORNC,LRID,DGIEN,ORPANEL,ORDIFF
  1.  ;get lab id from orderable item (OI):
  1.  S LRID=$P(^ORD(101.43,OI,0),U,2) S:$L($G(LRID)) ORL(LRID_";"_SPECIMEN)=""
  1.  ;expand into child-level lab identifiers if children exist for this OI:
  1.  ;if children found, set panel flag to '1':
  1.  S LRID="" F  S LRID=$O(^ORD(101.43,OI,10,"AID",LRID)) Q:LRID=""  S ORL(LRID_";"_SPECIMEN)="",ORPANEL=1
  1.  ;get duplicate date range-beginning date/time for this OI:
  1.  S DDT=$P($$DUPRANGE^ORQOR2(OI,"LR",NEWORDT,ORDFN),U)
  1.  Q:DDT=0  ;if dup range for this OI = zero, don't process dup order oc
  1.  ;
  1.  ;get all signed/not canceled lab orders since dup beg d/t:
  1.  S DGIEN=0,DGIEN=$O(^ORD(100.98,"B","LAB",DGIEN))
  1.  ;expand the search range to look for future orders
  1.  S ORDIFF=$$FMDIFF^XLFDT(NEWORDT,DDT,2)
  1.  S NEWORDT=$$FMADD^XLFDT(NEWORDT,"","","",ORDIFF)
  1.  ;start DDT at one minute previous so that search begins correctly
  1.  S DDT=$$FMADD^XLFDT(DDT,"","","",-60)
  1.  K ^TMP("ORR",$J)
  1.  D EN^ORQ1(ORDFN_";DPT(",DGIEN,1,"",DDT,NEWORDT+.2359,1,0,"AW")
  1.  N J,HOR,SEQ,X S J=1,HOR=0,SEQ=0
  1.  S HOR=$O(^TMP("ORR",$J,HOR)) Q:+HOR<1
  1.  F  S SEQ=$O(^TMP("ORR",$J,HOR,SEQ)) Q:+SEQ<1  D
  1.  .S X=^TMP("ORR",$J,HOR,SEQ),ORN=+$P(X,U),ODT=$P(X,U,4)
  1.  .I $G(ORREN)=1 Q:+$G(ORN)=+$G(ORIFN)  ;quit current order # = dup order # ;DJE-VM *331 on renewed orders only
  1.  .;break into child orders if they exist:
  1.  .I $D(^OR(100,ORN,2,0)) D  ;child orders exist
  1.  ..S ORNC=0 F  S ORNC=$O(^OR(100,ORN,2,ORNC)) Q:ORNC=""  D
  1.  ...I $G(ORREN)=1 Q:+$G(ORNC)=+$G(ORIFN)  ;quit current order # = dup order # ;DJE-VM *331 on renewed orders only
  1.  ...D DUP2(.ORKLR,ORNC,ODT,.ORL,$G(ORPANEL))
  1.  .I '$D(^OR(100,ORN,2,0)) D DUP2(.ORKLR,ORN,ODT,.ORL,$G(ORPANEL))
  1.  K ^TMP("ORR",$J)
  1.  Q
  1.  ;
  1. DUP2(ORKLR,ORN,ODT,ORL,ORPANEL) ;second part of dup lab order check
  1.  N ORS,ORST,ORSI,ORSP,OROI,LRID,LRIDX,LRIDXC,EXDT,INVDT,RCNT,ORY,ORX,ORQ,ORXI
  1.  S ORS=$$STATUS^ORQOR2(ORN),ORSI=$P(ORS,U),ORST=$P(ORS,U,2)
  1.  ;quit if order status is canceled/discontinued/expired/lapsed/changed/delayed:
  1.  I (ORSI=13)!(ORSI=1)!(ORSI=7)!(ORSI=14)!(ORSI=12)!(ORSI=10) Q
  1.  ;
  1.  ;get specimen for this order:
  1.  S ORSP=$$VALUE^ORCSAVE2(ORN,"SPECIMEN")
  1.  Q:'$L($G(ORSP))  ;quit if no specimen found
  1.  ;get orderable item for this order:
  1.  S OROI=$$OI^ORQOR2(ORN)
  1.  Q:'$L($G(OROI))  ;quit if no orderable item found
  1.  ;get lab id and check against ordered array ORL
  1.  S:$L($G(^ORD(101.43,OROI,0))) LRIDX=$P(^ORD(101.43,OROI,0),U,2)_";"_ORSP I $L($G(LRIDX)) D
  1.  .S LRID="" F  S LRID=$O(ORL(LRID)) Q:LRID=""  I LRID=LRIDX D  ;dup!
  1.  ..;
  1.  ..;quit if order results entered in lab as "cancelled":
  1.  ..D ORDER^ORQQLR(.ORY,ORDFN,ORN)
  1.  ..S ORX=0 F  S ORX=$O(ORY(ORX)) Q:+$G(ORX)<1  D
  1.  ...I ($P(LRID,";")=$P(ORY(ORX),U)),($P(ORY(ORX),U,3)["canc") S ORQ=1
  1.  ..Q:+$G(ORQ)=1  ;quit if lab test cancelled in lab
  1.  ..;
  1.  ..S EXDT=$$FMTE^XLFDT(ODT,"2P"),INVDT=9999999-ODT
  1.  ..;if previous orders have same date/time, do not overlay
  1.  ..F ORXI=0:0 Q:'$D(ORKLR(INVDT))  S INVDT=INVDT+.000001
  1.  ..;get most recent lab results:
  1.  ..S RCNT=$$LOCLFORM^ORQQLR1(ORDFN,+LRID,ORSP)
  1.  ..;
  1.  ..S ORKLR(INVDT)=ORN_U_$P($$TEXT^ORKOR(ORN,60),U,2)_" "_$G(EXDT)_" ["_$S(ORST="ACTIVE":"COLLECTED",ORST="PENDING":"UNCOLLECTED",1:ORST)_"]"
  1.  ..I +RCNT>0 S ORKLR(INVDT)=ORKLR(INVDT)_"  *Most recent result: "_$P(RCNT,U,2)_"*"
  1.  ;get children lab ids and check against ordered array  ORL
  1.  S LRIDX="" F  S LRIDX=$O(^ORD(101.43,OROI,10,"AID",LRIDX)) Q:LRIDX=""  D
  1.  .S LRIDXC=LRIDX_";"_ORSP
  1.  .S LRID="" F  S LRID=$O(ORL(LRID)) Q:LRID=""  I LRID=LRIDXC D  ;dup!
  1.  ..;
  1.  ..D ORDER^ORQQLR(.ORY,ORDFN,ORN)
  1.  ..S ORX=0 F  S ORX=$O(ORY(ORX)) Q:+$G(ORX)<1  D
  1.  ...I ($P(LRID,";")=$P(ORY(ORX),U)),($P(ORY(ORX),U,3)["canc") S ORQ=1
  1.  ..Q:+$G(ORQ)=1  ;quit if lab test cancelled in lab
  1.  ..;
  1.  ..S EXDT=$$FMTE^XLFDT(ODT,"2P"),INVDT=9999999-ODT
  1.  ..;if previous orders have same date/time, do not overlay
  1.  ..F ORXI=0:0 Q:'$D(ORKLR(INVDT))  S INVDT=INVDT+.000001
  1.  ..;
  1.  ..;get most recent lab results:
  1.  ..S RCNT=$S($G(ORPANEL)=1:"",1:$$LOCLFORM^ORQQLR1(ORDFN,+LRID,ORSP))
  1.  ..;
  1.  ..S ORKLR(INVDT)=ORN_U_$P($$TEXT^ORKOR(ORN,60),U,2)_" "_$G(EXDT)_" ["_$S(ORST="ACTIVE":"COLLECTED",ORST="PENDING":"UNCOLLECTED",1:ORST)_"]"
  1.  ..I +RCNT>0 S ORKLR(INVDT)=ORKLR(INVDT)_"  *Most recent result: "_$P(RCNT,U,2)_"*"
  1.  Q
  1. RECNTWBC(ORDFN,ORDAYS) ;extrinsic function to return most recent WBC within <ORDAYS> in format:
  1.  ;test id^result units flag ref range collection d/t
  1.  N BDT,CDT,ORY,ORX,ORZ,X,TEST,ORI,ORJ,WBCRSLT,LABFILE,SPECFILE
  1.  Q:'$L($G(ORDFN)) "0^"
  1.  D NOW^%DTC
  1.  I $L($G(ORDAYS)) S BDT=$$FMADD^XLFDT(%,"-"_ORDAYS,"","","")
  1.  K %
  1.  S:'$L($G(BDT)) BDT=1  ;if no ORDAYS, set BDT to '1' to search all days
  1.  S LABFILE=$$TERMLKUP^ORB31(.ORY,"WBC")
  1.  Q:'$D(ORY) "0^"  ;quit if no link between WBC and local lab test
  1.  Q:$G(LABFILE)'=60 "0^"
  1.  S SPECFILE=$$TERMLKUP^ORB31(.ORX,"BLOOD SPECIMEN")
  1.  Q:'$D(ORX) "0^" ;quit if no link between BLOOD SPECIMEN and local spec
  1.  Q:$G(SPECFILE)'=61 "0^"
  1.  F ORI=1:1:ORY I +$G(WBCRSLT)<1 D
  1.  .S TEST=$P(ORY(ORI),U)
  1.  .Q:+$G(TEST)<1
  1.  .F ORJ=1:1:ORX I +$G(WBCRSLT)<1 D
  1.  ..S SPECIMEN=$P(ORX(ORJ),U)
  1.  ..Q:+$G(SPECIMEN)<1
  1.  ..S ORZ=$$LOCL^ORQQLR1(ORDFN,TEST,SPECIMEN)
  1.  ..Q:'$L($G(ORZ))
  1.  ..S CDT=$P(ORZ,U,7)
  1.  ..I CDT'<BDT S WBCRSLT=1
  1.  Q:+$G(WBCRSLT)<1 "0^"
  1.  Q $P(ORZ,U,3)_U_$P(ORZ,U,3)_" "_$P(ORZ,U,4)_" "_$P(ORZ,U,5)_" ("_$P(ORZ,U,6)_")  "_$$FMTE^XLFDT(CDT,"2P")
  1.  ;
  1. CLOZLABS(ORDFN,ORDAYS,ORCLOZ) ;extrinsic function rtns "1" if clozapine ordered and WBC labs results within past ORDAYS, "0" if not
  1.  ;result format: clozapine/mapped labs flag^recent WBC flag;recent WBC
  1.  ; result^recent ANC flag;recent ANC result^formatted WBC and ANC results
  1.  ;
  1.  N BDT,WBC,WBCSPEC,WBCRSLT,WBCCDT,WBCF,ANC,ANCSPEC,ANCRSLT,ANCCDT,ANCF
  1.  Q:'$L($G(ORDFN)) "0^"
  1.  I $L($G(ORDAYS)) S BDT=$$FMADD^XLFDT($$NOW^XLFDT,"-"_ORDAYS,"","","")
  1.  S:'$L($G(BDT)) BDT=1  ;if no ORDAYS, set BDT to '1' to search all days
  1.  ;
  1.  K LAB
  1.  D EN^PSODRG(ORCLOZ)  ;pharmacy api rtns Lab file ptrs for WBC, ANC
  1.  Q:$G(LAB("NOT"))=0 "0^"  ;medication is not clozapine
  1.  ;Q:$G(LAB("BAD TEST"))=0 "0^"  ;one or both lab tests aren't mapped
  1.  ;S WBC=$G(LAB("WBC")),WBCSPEC=$P(WBC,U,2),WBC=$P(WBC,U)
  1.  ;S ANC=$G(LAB("ANC")),ANCSPEC=$P(ANC,U,2),ANC=$P(ANC,U)
  1.  ;
  1.  K ^TMP($J,"PSO")
  1.  D CL1^YSCLTST2(ORDFN,ORDAYS)
  1.  I $D(^TMP($J,"PSO")) D
  1.  .N INVDT
  1.  .S INVDT=$O(^TMP($J,"PSO",0))
  1.  .Q:'INVDT
  1.  .S WBC=$P($G(^TMP($J,"PSO",INVDT)),U)/1000
  1.  .S ANC=$P($G(^TMP($J,"PSO",INVDT)),U,2)/1000
  1.  .I WBC S WBCF=1
  1.  .I ANC S ANCF=1
  1.  .I $L(WBC)=1 S WBC=WBC_".0"
  1.  .I $L(ANC)=1 S ANC=ANC_".0"
  1.  .S WBCRSLT="WBC "_WBC_" ["_$$FMTE^XLFDT(9999999-INVDT,"""2P""")_"]"
  1.  .S ANCRSLT="ANC "_ANC_" ["_$$FMTE^XLFDT(9999999-INVDT,"""2P""")_"]"
  1.  ;
  1.  K LAB
  1.  Q "1^"_$G(WBCF,0)_";"_$G(WBC)_"^"_$G(ANCF,0)_";"_$G(ANC)_"^"_$G(WBCRSLT)_"  "_$G(ANCRSLT)