Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWTPO

ORWTPO.m

Go to the documentation of this file.
  1. ORWTPO ; SLC/STAFF Personal Preference - Order Checks ;5/1/01 12:27 [11/29/04 11:19am]
  1. ;;3.0;ORDER ENTRY/RESULTS REPORTING;**85,195**;Dec 17, 1997
  1. ;
  1. GETOTHER(INFO,USER) ; from ORWTPP
  1. ; get user's other parameter settings
  1. S INFO=$$GET^XPAR("ALL^USR.`"_USER,"ORCH INITIAL TAB")
  1. S INFO=INFO_U_$$GET^XPAR("ALL^USR.`"_USER,"ORCH USE LAST TAB")
  1. S INFO=INFO_U_$$GET^XPAR("ALL^USR.`"_USER,"ORWOR AUTOSAVE NOTE")
  1. S INFO=INFO_U_$$GET^XPAR("ALL^USR.`"_USER,"ORWOR VERIFY NOTE TITLE")
  1. Q
  1. ;
  1. SETOTHER(OK,INFO,USER) ; from ORWTPP
  1. ; save user's other parameter settings
  1. N AUTO,LAST,TAB,VER
  1. S OK=1
  1. S TAB=$P(INFO,U),LAST=$P(INFO,U,2),AUTO=$P(INFO,U,3),VER=$P(INFO,U,4)
  1. I $L(TAB) D EN^XPAR(USER_";VA(200,","ORCH INITIAL TAB",1,TAB)
  1. I $L(LAST) D EN^XPAR(USER_";VA(200,","ORCH USE LAST TAB",1,$S(LAST:"YES",1:"NO"))
  1. I $L(AUTO) D EN^XPAR(USER_";VA(200,","ORWOR AUTOSAVE NOTE",1,AUTO)
  1. I $L(VER) D EN^XPAR(USER_";VA(200,","ORWOR VERIFY NOTE TITLE",1,$S(VER:"YES",1:"NO"))
  1. Q
  1. ;
  1. GETTABS(VALUES) ; RPC
  1. ; get tab names for patient chart
  1. K VALUES
  1. D PDSET^ORWTPUP("ORCH INITIAL TAB",.VALUES)
  1. Q
  1. ;
  1. CSLABD(INFO) ; RPC
  1. ; get lab defaults
  1. N RNG
  1. S INFO=""
  1. F RNG="INPT","OUTPT" D
  1. .S INFO=INFO_$$GET^XPAR("DIV^SYS^PKG","ORQQLR DATE RANGE "_RNG,1,"I")_U
  1. Q
  1. ;
  1. CSLAB(VAL,USER) ; from ORWTPP
  1. ; get user's lab date range defaults
  1. N RNG
  1. S VAL=""
  1. F RNG="INPT","OUTPT" D
  1. .S VAL=VAL_$$GET^XPAR("USR.`"_USER_"^DIV^SYS^PKG","ORQQLR DATE RANGE "_RNG,1,"I")_U
  1. Q
  1. ;
  1. CSARNGD(INFO) ; RPC
  1. ; get start, stop defaults
  1. S INFO=$$GET^XPAR("DIV^SYS^PKG","ORQQCSDR CS RANGE START",1,"I")_U
  1. S INFO=INFO_$$GET^XPAR("DIV^SYS^PKG","ORQQCSDR CS RANGE STOP",1,"I")
  1. Q
  1. ;
  1. CSARNG(VAL,USER) ; from ORWTPP
  1. ; get user's appt date range defaults
  1. N ORSRV
  1. S ORSRV=$G(^VA(200,DUZ,5)) I +ORSRV>0 S ORSRV=$P(ORSRV,U) ; Get S/S.
  1. S VAL=$$GET^XPAR("USR.`"_USER_"^SRV.`"_+$G(ORSRV)_"^DIV^SYS^PKG","ORQQCSDR CS RANGE START",1,"I")_U
  1. S VAL=VAL_$$GET^XPAR("USR.`"_USER_"^SRV.`"_+$G(ORSRV)_"^DIV^SYS^PKG","ORQQCSDR CS RANGE STOP",1,"I")
  1. Q
  1. ;
  1. SAVECS(OK,INFO,USER) ; from ORWTPP
  1. ; save user's date range defaults
  1. N INPT,OUTPT,START,STOP
  1. S OK=1
  1. S START=+$P(INFO,U,3) S START=$S(START=0:"T",START<0:"T"_START,1:"T+"_START)
  1. S STOP=+$P(INFO,U,4) S STOP=$S(STOP=0:"T",STOP<0:"T"_STOP,1:"T+"_STOP)
  1. S INPT=+$P(INFO,U,1),INPT=$S('INPT:"@",1:INPT)
  1. S OUTPT=+$P(INFO,U,2),OUTPT=$S('OUTPT:"@",1:OUTPT)
  1. D EN^XPAR(USER_";VA(200,","ORQQCSDR CS RANGE START",1,START)
  1. D EN^XPAR(USER_";VA(200,","ORQQCSDR CS RANGE STOP",1,STOP)
  1. D EN^XPAR(USER_";VA(200,","ORQQLR DATE RANGE INPT",1,INPT)
  1. D EN^XPAR(USER_";VA(200,","ORQQLR DATE RANGE OUTPT",1,OUTPT)
  1. Q
  1. GETIMGD(INFO) ; RPC
  1. S INFO=$$GET^XPAR("SRV.`"_+$G(ORSRV)_"^DIV^SYS^PKG","ORCH CONTEXT REPORTS")
  1. Q
  1. ;
  1. GETIMG(INFO,USER) ; from ORWTPP
  1. ; get user's image report defaults
  1. S INFO=$$GET^XPAR("USR.`"_USER_"^SRV.`"_+$G(ORSRV)_"^DIV^SYS^PKG","ORCH CONTEXT REPORTS")
  1. Q
  1. ;
  1. SETIMG(OK,MAX,START,STOP,USER) ; from ORWTPP
  1. ; save user's image report defaults
  1. N VALUE S OK=0
  1. I MAX'>0 Q
  1. S START=$S(START=0:"T",START<0:"T"_START,1:"T+"_START)
  1. S STOP=$S(STOP=0:"T",STOP<0:"T"_STOP,1:"T+"_STOP)
  1. S VALUE=START_";"_STOP_";;;"_MAX
  1. S OK=1
  1. D EN^XPAR(USER_";VA(200,","ORCH CONTEXT REPORTS",1,VALUE)
  1. Q