PRCFDES2 ;WISC/LEM-ESIG MAINTENANCE ROUTINE ;1/19/93 1:05 PM
V ;;5.1;IFCAP;;Oct 20, 2000
;Per VHA Directive 10-93-142, this routine should not be modified.
;ROUTINE FOR MAINTAINING FIELD 62 (COMPLETED BY ELEC SIG), FILE 421.5
DECODE(LEVEL0) ;Extrinsic Function to return hashed electronic sig to readable form.
;returns "" if unsuccessful
NEW RECORD2,RECORD21,VERSION,PERSON,SIG,CHECKSUM
;get record and check version
S RECORD2=$G(^PRCF(421.5,LEVEL0,2)) I RECORD2="" QUIT ""
S RECORD21=$G(^PRCF(421.5,LEVEL0,2.1))
S VERSION=$P(RECORD21,"^",3)
S PERSON=+$P(RECORD2,"^",11)
I VERSION'="",VERSION'=1 Q ""
S SIG=$P(RECORD2,"^",13)
D1 ;decode e signature for version 1
S RECORD=$G(^PRCF(421.5,LEVEL0,0))
S RECORD1=$G(^PRCF(421.5,LEVEL0,1))
S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_$$STRING(RECORD,RECORD1))
QUIT $$DECODE^PRCUESIG(SIG,PERSON,CHECKSUM)
ENCODE(LEVEL0,USERNUM,Y) ;Encode e signature for version 1 only
;Parameter passing entry point
NEW SIGBLOCK,CHECKSUM,OLDUSER
NEW RECORD,RECORD1,RECORD2,RECORD21
;get record
S USERNUM=+USERNUM
I USERNUM=0 S Y=-3 QUIT ;-3 no user num available
S SIGBLOCK=$P($G(^VA(200,USERNUM,20)),"^",2)
I SIGBLOCK="" S Y=-2 QUIT ;-2 no sigblock in file 200
S RECORD=$G(^PRCF(421.5,LEVEL0,0))
S RECORD1=$G(^PRCF(421.5,LEVEL0,1))
S RECORD2=$G(^PRCF(421.5,LEVEL0,2))
S RECORD21=$G(^PRCF(421.5,LEVEL0,2.1))
I RECORD="" S Y=-1 QUIT ;-1 no transaction record
I $P(RECORD2,"^",13)'="" S Y=-4 QUIT ;-4 cannot re-sign record
S OLDUSER=+$P(RECORD2,"^",11)
I OLDUSER=0 S $P(RECORD2,"^",11)=USERNUM
I OLDUSER>0 S USERNUM=OLDUSER
S:$P(RECORD21,"^",6)="" $P(RECORD21,"^",6)=$$NOW^PRCUESIG
S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_$$STRING(RECORD,RECORD1))
S $P(RECORD2,"^",13)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
S $P(RECORD21,"^",3,4)="1^"_$$SUM^PRCUESIG(SIGBLOCK)
S ^PRCF(421.5,LEVEL0,2)=RECORD2
S ^PRCF(421.5,LEVEL0,2.1)=RECORD21
S Y=1 QUIT
REMOVE(LEVEL0) ;Entry point to remove e signature from record
;NOT an extrinsic function
NEW RECORD2,RECORD21,I
S RECORD2=$G(^PRCF(421.5,LEVEL0,2))
S RECORD21=$G(^PRCF(421.5,LEVEL0,2.1))
F I=11,13 S $P(RECORD2,"^",I)=""
F I=4,6 S $P(RECORD21,"^",I)=""
S ^PRCF(421.5,LEVEL0,2)=RECORD2
S ^PRCF(421.5,LEVEL0,2.1)=RECORD21
QUIT
VERIFY(LEVEL0) ;extrinsic function to verify version 1 signature. Returns 1 if valid, 0 if not valid
NEW RECORD21,VERSION,SIGBLOCK
;get record variables
S RECORD21=$G(^PRCF(421.5,LEVEL0,2.1))
S VERSION=$P(RECORD21,"^",3),SIGBLOCK=$P(RECORD21,"^",4)
I VERSION_SIGBLOCK="" QUIT 1
QUIT ($$SUM^PRCUESIG($$DECODE(LEVEL0))=SIGBLOCK)
STRING(X,X1) ;Build String of critical fields
NEW RECORD,RECORD1
Q $P(X,"^",1)_"^"_$P(X,"^",3)_"^"_$P(X,"^",4)_"^"_$P(X,"^",8)_"^"_$P(X,"^",15)_"^"_$P(X1,"^",3)
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HPRCFDES2 2813 printed Oct 16, 2024@18:03:46 Page 2
PRCFDES2 ;WISC/LEM-ESIG MAINTENANCE ROUTINE ;1/19/93 1:05 PM
V ;;5.1;IFCAP;;Oct 20, 2000
+1 ;Per VHA Directive 10-93-142, this routine should not be modified.
+2 ;ROUTINE FOR MAINTAINING FIELD 62 (COMPLETED BY ELEC SIG), FILE 421.5
DECODE(LEVEL0) ;Extrinsic Function to return hashed electronic sig to readable form.
+1 ;returns "" if unsuccessful
+2 NEW RECORD2,RECORD21,VERSION,PERSON,SIG,CHECKSUM
+3 ;get record and check version
+4 SET RECORD2=$GET(^PRCF(421.5,LEVEL0,2))
IF RECORD2=""
QUIT ""
+5 SET RECORD21=$GET(^PRCF(421.5,LEVEL0,2.1))
+6 SET VERSION=$PIECE(RECORD21,"^",3)
+7 SET PERSON=+$PIECE(RECORD2,"^",11)
+8 IF VERSION'=""
IF VERSION'=1
QUIT ""
+9 SET SIG=$PIECE(RECORD2,"^",13)
D1 ;decode e signature for version 1
+1 SET RECORD=$GET(^PRCF(421.5,LEVEL0,0))
+2 SET RECORD1=$GET(^PRCF(421.5,LEVEL0,1))
+3 SET CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_$$STRING(RECORD,RECORD1))
+4 QUIT $$DECODE^PRCUESIG(SIG,PERSON,CHECKSUM)
ENCODE(LEVEL0,USERNUM,Y) ;Encode e signature for version 1 only
+1 ;Parameter passing entry point
+2 NEW SIGBLOCK,CHECKSUM,OLDUSER
+3 NEW RECORD,RECORD1,RECORD2,RECORD21
+4 ;get record
+5 SET USERNUM=+USERNUM
+6 ;-3 no user num available
IF USERNUM=0
SET Y=-3
QUIT
+7 SET SIGBLOCK=$PIECE($GET(^VA(200,USERNUM,20)),"^",2)
+8 ;-2 no sigblock in file 200
IF SIGBLOCK=""
SET Y=-2
QUIT
+9 SET RECORD=$GET(^PRCF(421.5,LEVEL0,0))
+10 SET RECORD1=$GET(^PRCF(421.5,LEVEL0,1))
+11 SET RECORD2=$GET(^PRCF(421.5,LEVEL0,2))
+12 SET RECORD21=$GET(^PRCF(421.5,LEVEL0,2.1))
+13 ;-1 no transaction record
IF RECORD=""
SET Y=-1
QUIT
+14 ;-4 cannot re-sign record
IF $PIECE(RECORD2,"^",13)'=""
SET Y=-4
QUIT
+15 SET OLDUSER=+$PIECE(RECORD2,"^",11)
+16 IF OLDUSER=0
SET $PIECE(RECORD2,"^",11)=USERNUM
+17 IF OLDUSER>0
SET USERNUM=OLDUSER
+18 if $PIECE(RECORD21,"^",6)=""
SET $PIECE(RECORD21,"^",6)=$$NOW^PRCUESIG
+19 SET CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_$$STRING(RECORD,RECORD1))
+20 SET $PIECE(RECORD2,"^",13)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
+21 SET $PIECE(RECORD21,"^",3,4)="1^"_$$SUM^PRCUESIG(SIGBLOCK)
+22 SET ^PRCF(421.5,LEVEL0,2)=RECORD2
+23 SET ^PRCF(421.5,LEVEL0,2.1)=RECORD21
+24 SET Y=1
QUIT
REMOVE(LEVEL0) ;Entry point to remove e signature from record
+1 ;NOT an extrinsic function
+2 NEW RECORD2,RECORD21,I
+3 SET RECORD2=$GET(^PRCF(421.5,LEVEL0,2))
+4 SET RECORD21=$GET(^PRCF(421.5,LEVEL0,2.1))
+5 FOR I=11,13
SET $PIECE(RECORD2,"^",I)=""
+6 FOR I=4,6
SET $PIECE(RECORD21,"^",I)=""
+7 SET ^PRCF(421.5,LEVEL0,2)=RECORD2
+8 SET ^PRCF(421.5,LEVEL0,2.1)=RECORD21
+9 QUIT
VERIFY(LEVEL0) ;extrinsic function to verify version 1 signature. Returns 1 if valid, 0 if not valid
+1 NEW RECORD21,VERSION,SIGBLOCK
+2 ;get record variables
+3 SET RECORD21=$GET(^PRCF(421.5,LEVEL0,2.1))
+4 SET VERSION=$PIECE(RECORD21,"^",3)
SET SIGBLOCK=$PIECE(RECORD21,"^",4)
+5 IF VERSION_SIGBLOCK=""
QUIT 1
+6 QUIT ($$SUM^PRCUESIG($$DECODE(LEVEL0))=SIGBLOCK)
STRING(X,X1) ;Build String of critical fields
+1 NEW RECORD,RECORD1
+2 QUIT $PIECE(X,"^",1)_"^"_$PIECE(X,"^",3)_"^"_$PIECE(X,"^",4)_"^"_$PIECE(X,"^",8)_"^"_$PIECE(X,"^",15)_"^"_$PIECE(X1,"^",3)
