Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PRCHES1

PRCHES1.m

Go to the documentation of this file. 
  1. PRCHES1 ;WISC/RHD/AKS-ESIG MAINTENANCE ROUTINE ;3/18/93  11:42
  1. V ;;5.1;IFCAP;;Oct 20, 2000
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;ROUTINE FOR MAINTAINING SUBFIELD 7 (ELECTRONIC SIGNATURE)
  1.  ; FIELD .6 (PARTIAL), FILE 442
  1. DECODE(LEVEL0,LEVEL1) ;Extrinsic Function to return hashed esig in readable form.
  1.  ;returns "" if unsuccessful
  1.  NEW RECORD,RECORD1,VERSION,PERSON,SIG,CHECKSUM
  1.  ;get record and check version
  1.  S RECORD=$G(^PRC(442,LEVEL0,11,LEVEL1,0)) I RECORD="" Q ""
  1.  S RECORD1=$G(^PRC(442,LEVEL0,11,LEVEL1,1))
  1.  S VERSION=$P(RECORD1,"^",9)
  1.  S PERSON=+$P(RECORD,"^",7)
  1.  I VERSION'="",VERSION'=1 Q ""
  1.  S SIG=$P(RECORD,"^",8)
  1. D1 ;decode e signature for version 1
  1.  S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD))
  1.  Q $$DECODE^PRCUESIG(SIG,PERSON,CHECKSUM)
  1. ENCODE(LEVEL0,LEVEL1,USERNUM,Y) ;Encode esig for version 1 only
  1.  NEW RECORD,RECORD1,SIGBLOCK,CHECKSUM,OLDUSER
  1.  S USERNUM=+USERNUM
  1.  I USERNUM=0 S Y=-3 Q  ;-3 no user number
  1.  S SIGBLOCK=$P($G(^VA(200,USERNUM,20)),"^",2)
  1.  I SIGBLOCK="" S Y=-2 Q  ;-2 no signature block
  1.  S RECORD=$G(^PRC(442,LEVEL0,11,LEVEL1,0))
  1.  S RECORD1=$G(^PRC(442,LEVEL0,11,LEVEL1,1))
  1.  I RECORD="" S Y=-1 Q  ;-1 no 2237 record
  1.  I $P(RECORD,"^",8)'="" S Y=-4 Q  ;-4 cannot re-sign record
  1.  S OLDUSER=+$P(RECORD,"^",7)
  1.  I OLDUSER=0 S $P(RECORD,"^",7)=USERNUM
  1.  I OLDUSER>0 S USERNUM=OLDUSER
  1.  S:$P(RECORD,"^",11)="" $P(RECORD,"^",11)=$$NOW^PRCUESIG
  1.  S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD))
  1.  S $P(RECORD,"^",8)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
  1.  S $P(RECORD1,"^",9,10)="1^"_$$SUM^PRCUESIG(SIGBLOCK)
  1.  S ^PRC(442,LEVEL0,11,LEVEL1,0)=RECORD
  1.  S ^PRC(442,LEVEL0,11,LEVEL1,1)=RECORD1
  1.  S Y=1 Q
  1. RECODE(LEVEL0,LEVEL1,CHECKSUM,Y) ;Recode esig for version 1 only
  1.  NEW RECORD,RECORD1,SIGBLOCK,USERNUM
  1.  S RECORD=$G(^PRC(442,LEVEL0,11,LEVEL1,0))
  1.  S RECORD1=$G(^PRC(442,LEVEL0,11,LEVEL1,1))
  1.  I RECORD=""!(RECORD1="") S Y=-1 Q  ;-1 no record
  1.  S USERNUM=+$P(RECORD,"^",7)
  1.  I $P(RECORD,"^",8)=""!(USERNUM=0) S Y=-4 Q  ;-4 cannot recode record
  1.  ;S SIGBLOCK=$$DECODE^PRCUESIG($P(RECORD,"^",8),USERNUM,CHECKSUM)
  1.  S SIGBLOCK=$P($G(^VA(200,USERNUM,20)),"^",2)
  1.  S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD))
  1.  S $P(RECORD,"^",8)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
  1.  S $P(RECORD1,"^",10)=$$SUM^PRCUESIG(SIGBLOCK)
  1.  S ^PRC(442,LEVEL0,11,LEVEL1,0)=RECORD
  1.  S ^PRC(442,LEVEL0,11,LEVEL1,1)=RECORD1
  1.  S Y=1
  1.  Q
  1. REMOVE(LEVEL0,LEVEL1) ;Entry point to remove esig
  1.  NEW I,RECORD,RECORD1
  1.  S RECORD=$G(^PRC(442,LEVEL0,11,LEVEL1,0))
  1.  S RECORD1=$G(^PRC(442,LEVEL0,11,LEVEL1,1))
  1.  F I=7,8,11 S $P(RECORD,"^",I)=""
  1.  S $P(RECORD1,"^",10)=""
  1.  S ^PRC(442,LEVEL0,11,LEVEL1,0)=RECORD
  1.  S ^PRC(442,LEVEL0,11,LEVEL1,1)=RECORD1
  1.  Q
  1. VERIFY(LEVEL0,LEVEL1)      ;extrinsic function to verify esig  Returns 1 if valid, 0 if not valid
  1.  NEW RECORD,RECORD1,VERSION,SIGBLOCK
  1.  S RECORD=$G(^PRC(442,LEVEL0,11,LEVEL1,0))
  1.  S RECORD1=$G(^PRC(442,LEVEL0,11,LEVEL1,1))
  1.  S VERSION=$P(RECORD1,"^",9),SIGBLOCK=$P(RECORD1,"^",10)
  1.  I VERSION_SIGBLOCK="" Q 1
  1.  Q $$SUM^PRCUESIG($$DECODE(LEVEL0,LEVEL1))=SIGBLOCK
  1. STRING(X)          ;Build String of critical fields
  1.  Q $P(X,"^")_"^"_$P(X,"^",3)_"^"_$P(X,"^",5)_"^"_$P(X,"^",11)_"^"_$P(X,"^",12)_"^"_$P(X,"^",14)