PRCHES7 ;WISC/RHD/AKS-ESIG MAINT ;8/25/94 14:40
V ;;5.1;IFCAP;;Oct 20, 2000
;Per VHA Directive 10-93-142, this routine should not be modified.
;ROUTINE FOR MAINTAINING SUBFIELD 11 (ELECTRONIC SIGNATURE)
; FIELD 50 (AMENDMENT) FILE 442
DECODE(LEVEL0,LEVEL1) ;return esig to readable form
;returns "" if unsuccessful
NEW RECORD,RECORD1,VERSION,PERSON,SIG,CHECKSUM
S RECORD=$G(^PRC(442,LEVEL0,6,LEVEL1,0)) I RECORD="" Q ""
S RECORD1=$G(^PRC(442,LEVEL0,6,LEVEL1,1))
S VERSION=$P(RECORD,"^",11)
S PERSON=+$P(RECORD1,"^",5)
I VERSION'="",VERSION'=1 Q ""
S SIG=$P(RECORD1,"^",6)
D1 ;esig for ver 1
S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD,RECORD1))
Q $$DECODE^PRCUESIG(SIG,PERSON,CHECKSUM)
ENCODE(LEVEL0,LEVEL1,USERNUM,Y) ;Encode esig for version 1 only
NEW RECORD,RECORD1,SIGBLOCK,CHECKSUM,OLDUSER
S USERNUM=+USERNUM
I USERNUM=0 S Y=-3 Q ;-3 no user number
S SIGBLOCK=$P($G(^VA(200,USERNUM,20)),"^",2)
I SIGBLOCK="" S Y=-2 Q ;-2 no signature block
S RECORD=$G(^PRC(442,LEVEL0,6,LEVEL1,0))
S RECORD1=$G(^PRC(442,LEVEL0,6,LEVEL1,1))
I RECORD="" S Y=-1 Q ;-1 no record
I $P(RECORD1,"^",6)'="" S Y=-4 Q ;-4 cannot re-sign record
S OLDUSER=+$P(RECORD1,"^",5)
I OLDUSER=0 S $P(RECORD1,"^",5)=USERNUM
I OLDUSER>0 S USERNUM=OLDUSER
S:$P(RECORD1,"^",8)="" $P(RECORD1,"^",8)=$$NOW^PRCUESIG
S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD,RECORD1))
S $P(RECORD1,"^",6)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
S $P(RECORD,"^",11)="1",$P(RECORD1,"^",7)=$$SUM^PRCUESIG(SIGBLOCK)
S ^PRC(442,LEVEL0,6,LEVEL1,0)=RECORD
S ^PRC(442,LEVEL0,6,LEVEL1,1)=RECORD1
S Y=1 Q
RECODE(LEVEL0,LEVEL1,Y) ;Recode ESIG for version 1 only
N RECORD,RECORD1,SIGBLOCK,CHECKSUM,USERNUM
S RECORD=$G(^PRC(442,LEVEL0,6,LEVEL1,0))
S RECORD1=$G(^PRC(442,LEVEL0,6,LEVEL1,1))
I RECORD=""!(RECORD1="") S Y=-1 Q ;-1 no record
S USERNUM=$P(RECORD1,"^",5)
I $P(RECORD1,"^",6)=""!(USERNUM=0) S Y=-4 Q ;-4 cannot recode record
S SIGBLOCK=$P($G(^VA(200,USERNUM,20)),"^",2)
S CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD,RECORD1))
S $P(RECORD1,"^",6)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
S $P(RECORD,"^",11)="1",$P(RECORD1,"^",7)=$$SUM^PRCUESIG(SIGBLOCK)
S ^PRC(442,LEVEL0,6,LEVEL1,0)=RECORD
S ^PRC(442,LEVEL0,6,LEVEL1,1)=RECORD1
S Y=1 ;1 record recoded properly
Q
REMOVE(LEVEL0,LEVEL1) ;Entry point to remove esig from record
NEW RECORD
S RECORD=$G(^PRC(442,LEVEL0,6,LEVEL1,0)) Q:RECORD=""
S $P(^PRC(442,LEVEL0,6,LEVEL1,1),"^",5,8)="^^^"
Q
VERIFY(LEVEL0,LEVEL1) ;verify version 1 signature. Returns 1 if valid
NEW RECORD,RECORD1,VERSION,SIGBLOCK
S RECORD=$G(^PRC(442,LEVEL0,6,LEVEL1,0))
S RECORD1=$G(^PRC(442,LEVEL0,6,LEVEL1,1))
S VERSION=$P(RECORD,"^",11),SIGBLOCK=$P(RECORD1,"^",7)
I VERSION_SIGBLOCK="" Q 1
Q ($$SUM^PRCUESIG($$DECODE(LEVEL0,LEVEL1))=SIGBLOCK)
STRING(X,X1) ;Build String of critical fields
Q $P(X,"^")_"^"_$P(X,"^",2)_"^"_$P(X,"^",3)_"^"_$P(X1,"^",4)_"^"_$P(X1,"^",8)
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HPRCHES7 3042 printed Dec 13, 2024@02:07:24 Page 2
PRCHES7 ;WISC/RHD/AKS-ESIG MAINT ;8/25/94 14:40
V ;;5.1;IFCAP;;Oct 20, 2000
+1 ;Per VHA Directive 10-93-142, this routine should not be modified.
+2 ;ROUTINE FOR MAINTAINING SUBFIELD 11 (ELECTRONIC SIGNATURE)
+3 ; FIELD 50 (AMENDMENT) FILE 442
DECODE(LEVEL0,LEVEL1) ;return esig to readable form
+1 ;returns "" if unsuccessful
+2 NEW RECORD,RECORD1,VERSION,PERSON,SIG,CHECKSUM
+3 SET RECORD=$GET(^PRC(442,LEVEL0,6,LEVEL1,0))
IF RECORD=""
QUIT ""
+4 SET RECORD1=$GET(^PRC(442,LEVEL0,6,LEVEL1,1))
+5 SET VERSION=$PIECE(RECORD,"^",11)
+6 SET PERSON=+$PIECE(RECORD1,"^",5)
+7 IF VERSION'=""
IF VERSION'=1
QUIT ""
+8 SET SIG=$PIECE(RECORD1,"^",6)
D1 ;esig for ver 1
+1 SET CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD,RECORD1))
+2 QUIT $$DECODE^PRCUESIG(SIG,PERSON,CHECKSUM)
ENCODE(LEVEL0,LEVEL1,USERNUM,Y) ;Encode esig for version 1 only
+1 NEW RECORD,RECORD1,SIGBLOCK,CHECKSUM,OLDUSER
+2 SET USERNUM=+USERNUM
+3 ;-3 no user number
IF USERNUM=0
SET Y=-3
QUIT
+4 SET SIGBLOCK=$PIECE($GET(^VA(200,USERNUM,20)),"^",2)
+5 ;-2 no signature block
IF SIGBLOCK=""
SET Y=-2
QUIT
+6 SET RECORD=$GET(^PRC(442,LEVEL0,6,LEVEL1,0))
+7 SET RECORD1=$GET(^PRC(442,LEVEL0,6,LEVEL1,1))
+8 ;-1 no record
IF RECORD=""
SET Y=-1
QUIT
+9 ;-4 cannot re-sign record
IF $PIECE(RECORD1,"^",6)'=""
SET Y=-4
QUIT
+10 SET OLDUSER=+$PIECE(RECORD1,"^",5)
+11 IF OLDUSER=0
SET $PIECE(RECORD1,"^",5)=USERNUM
+12 IF OLDUSER>0
SET USERNUM=OLDUSER
+13 if $PIECE(RECORD1,"^",8)=""
SET $PIECE(RECORD1,"^",8)=$$NOW^PRCUESIG
+14 SET CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD,RECORD1))
+15 SET $PIECE(RECORD1,"^",6)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
+16 SET $PIECE(RECORD,"^",11)="1"
SET $PIECE(RECORD1,"^",7)=$$SUM^PRCUESIG(SIGBLOCK)
+17 SET ^PRC(442,LEVEL0,6,LEVEL1,0)=RECORD
+18 SET ^PRC(442,LEVEL0,6,LEVEL1,1)=RECORD1
+19 SET Y=1
QUIT
RECODE(LEVEL0,LEVEL1,Y) ;Recode ESIG for version 1 only
+1 NEW RECORD,RECORD1,SIGBLOCK,CHECKSUM,USERNUM
+2 SET RECORD=$GET(^PRC(442,LEVEL0,6,LEVEL1,0))
+3 SET RECORD1=$GET(^PRC(442,LEVEL0,6,LEVEL1,1))
+4 ;-1 no record
IF RECORD=""!(RECORD1="")
SET Y=-1
QUIT
+5 SET USERNUM=$PIECE(RECORD1,"^",5)
+6 ;-4 cannot recode record
IF $PIECE(RECORD1,"^",6)=""!(USERNUM=0)
SET Y=-4
QUIT
+7 SET SIGBLOCK=$PIECE($GET(^VA(200,USERNUM,20)),"^",2)
+8 SET CHECKSUM=$$SUM^PRCUESIG(LEVEL0_"^"_LEVEL1_"^"_$$STRING(RECORD,RECORD1))
+9 SET $PIECE(RECORD1,"^",6)=$$ENCODE^PRCUESIG(SIGBLOCK,USERNUM,CHECKSUM)
+10 SET $PIECE(RECORD,"^",11)="1"
SET $PIECE(RECORD1,"^",7)=$$SUM^PRCUESIG(SIGBLOCK)
+11 SET ^PRC(442,LEVEL0,6,LEVEL1,0)=RECORD
+12 SET ^PRC(442,LEVEL0,6,LEVEL1,1)=RECORD1
+13 ;1 record recoded properly
SET Y=1
+14 QUIT
REMOVE(LEVEL0,LEVEL1) ;Entry point to remove esig from record
+1 NEW RECORD
+2 SET RECORD=$GET(^PRC(442,LEVEL0,6,LEVEL1,0))
if RECORD=""
QUIT
+3 SET $PIECE(^PRC(442,LEVEL0,6,LEVEL1,1),"^",5,8)="^^^"
+4 QUIT
VERIFY(LEVEL0,LEVEL1) ;verify version 1 signature. Returns 1 if valid
+1 NEW RECORD,RECORD1,VERSION,SIGBLOCK
+2 SET RECORD=$GET(^PRC(442,LEVEL0,6,LEVEL1,0))
+3 SET RECORD1=$GET(^PRC(442,LEVEL0,6,LEVEL1,1))
+4 SET VERSION=$PIECE(RECORD,"^",11)
SET SIGBLOCK=$PIECE(RECORD1,"^",7)
+5 IF VERSION_SIGBLOCK=""
QUIT 1
+6 QUIT ($$SUM^PRCUESIG($$DECODE(LEVEL0,LEVEL1))=SIGBLOCK)
STRING(X,X1) ;Build String of critical fields
+1 QUIT $PIECE(X,"^")_"^"_$PIECE(X,"^",2)_"^"_$PIECE(X,"^",3)_"^"_$PIECE(X1,"^",4)_"^"_$PIECE(X1,"^",8)
