PRCOACT ;WISC/DJM-"ACT" & "PRJ" TRANSACTIONS FROM AUSTIN ;7/21/96 21:45
V ;;5.1;IFCAP;**202**;Oct 20, 2000;Build 27
;Per VA Directive 6402, this routine should not be modified.
;
START ;THIS ROUTINE WILL SAVE THE INCOMMING "ACT" OR "PRJ" TRANSACTION
;IN THE "EDI STATUS" FILE (#443.75) WITHIN AN EXISTING RECORD. THIS
;ROUTINE WILL START UP WHEN AN "ACT" OR "PRJ" TRANSACTION ARRIVES
;FROM AUSTIN AND IS SAVED IN FILE 423.6. AFTER SAVING IN 423.6 THE
;SERVER WILL START UP A BACKGROUND TASK THAT CALLS THIS ROUTINE.
;
;THE BACKGROUND TASK WILL SET UP **PRCDA**, THE INTERNAL ENTRY
;NUMBER FROM FILE 423.6. THE RECORD AT **PRCDA** CONTAINS THE DATA
;FROM THE "ACT" OR "PRJ" TRANSACTION THAT 'ARRIVED' FROM AUSTIN.
;
N COUNT,COUNTER,I,LINE,MGP,PONO,PRC,PRCMG,PRCTC,PRCTT,PRCXM,RFQ,RECORD,ERRCNT
N RRC,SEGT,STATION,STCK,TEXT,VENDOR,X,X1,X2
;
;NOW LETS VERIFY THAT THE TRANSACTION BELONGS TO THIS SITE.
;
S LINE=$G(^PRCF(423.6,PRCDA,1,10000,0))
S MGP=$O(^PRCF(423.5,"B",$P(LINE,U)_"-"_$P(LINE,U,4),0))
I MGP="" S PRCXM(1)=$P($T(ERROR+8),";;",2)_$P(LINE,U)_"-"_$P(LINE,U,4)_"." G EXIT
S MGP=$G(^PRCF(423.5,MGP,0))
I MGP="" S PRCXM(1)=$P($T(ERROR+9),";;",2) G EXIT
I $P(MGP,U,2)="" S PRCXM(1)=$P($T(ERROR+10),";;",2) G EXIT
I $P(MGP,U,2)]"" S PRCMG=$P($G(^XMB(3.8,$P(MGP,U,2),0)),U)
I PRCMG="" S PRCXM(1)=$P($T(ERROR+11),";;",2) G EXIT
D I $D(PRCXM(1)) G EXIT
. I ",ACT,PRJ,"'[","_$P(LINE,U,4)_"," S PRCXM(1)=$P($T(ERROR+1),";;",2)_$P(LINE,U,4)_"." Q
. S STATION=$P(LINE,U,3) I STATION="" S PRCXM(1)=$P($T(ERROR+4),";;",2)_$G(PRCDA)_"." Q
. S STCK=$O(^PRC(411,"B",STATION,0)) I STCK'>0 S PRCXM(1)=$P($T(ERROR+2),";;",2)_$G(STATION)_"." Q
. Q
S PRCTC=$P(LINE,U,4)
;
;GATHER THE DATA FROM THE 'AT' SEGMENT OF THE TRANSACTION.
;
S LINE=$G(^PRCF(423.6,PRCDA,1,10001,0))
I $P(LINE,U,1)'="AT" S PRCXM(1)=$P($T(ERROR+3),";;",2)_$P($G(LINE),U)_"." G EXIT
S PRCTT=$P(LINE,U,2)
I PRCTT="" S PRCXM(1)=$P($T(ERROR+13),";;",2)_$G(PRCDA)_"." G EXIT
S COUNT=+$P(LINE,U,3)
;
;NOW GET THE DATA FROM EACH 'TR' OR 'RJ' SEGMENT.
;
S I=10001
S COUNTER=0,ERRCNT=1
K PRCXM
F S I=$O(^PRCF(423.6,PRCDA,1,I)) Q:I'>0 D D:$O(PRCXM(0)) PERROR^PRCOACT0 Q:LINE["$"
. K PRC
. S LINE=$G(^PRCF(423.6,PRCDA,1,I,0))
. Q:$E(LINE,1)="$"
. S SEGT=$P(LINE,U)
. Q:",TR,RJ,"'[","_SEGT_","
. S PRC(1,443.75,"?+1,",9)=PRCTC
. S PRC(1,443.75,"?+1,",21)=COUNT
. S PONO=$P(LINE,U,2)
. I PRCTT="PHA" D
. . F Q:$A(PONO,$L(PONO))'=32 S PONO=$E(PONO,1,$L(PONO)-1)
. . S PONO=$E(PONO,1,3)_"-"_$E(PONO,4,$L(PONO))
. . Q
. S X1=$E($P(LINE,U,5),1,4)-1700_"0101"
. S X2=$E($P(LINE,U,5),5,7)-1
. D C^%DTC
. S PRC(1,443.75,"?+1,",10)=X_"."_$P(LINE,U,6)
. S PRC(1,443.75,"?+1,",22)=$S(PRCTC="ACT":$P(LINE,U,7),1:$P(LINE,U,14))
. S VENDOR=$P(LINE,U,3)
. S:PRCTT="RFQ" RFQ=$S(PRCTC="ACT":$P(LINE,U,8),1:$P(LINE,U,16))
. S:PRCTT="TXT" TEXT=$P(LINE,U,4)
. I PONO="" S PRCXM(ERRCNT)=$P($T(ERROR+14),";;",2)_$G(PRCDA)_"." D ERRCNT Q
. I PRCTT'="PHA",VENDOR="" S PRCXM(ERRCNT)=$P($T(ERROR+15),";;",2)_$G(PRCDA)_"." D ERRCNT Q
. I PRCTT="RFQ",RFQ="" S PRCXM(ERRCNT)=$P($T(ERROR+16),";;",2)_$G(PRCDA)_"." D ERRCNT Q
. I PRCTT="TXT",TEXT="" S PRCXM(ERRCNT)=$P($T(ERROR+17),";;",2)_$G(PRCDA)_"." D ERRCNT Q
. S RECORD=""
. I PRCTT="PHA" D Q:$O(PRCXM(0))
. . I VENDOR]"" S RECORD=$O(^PRC(443.75,"AO",PRCTT,PONO,VENDOR,0))
. . I 'RECORD D I 'RECORD S PRCXM(ERRCNT)=$P($T(ERROR+19),";;",2)_$G(PRCDA)_"." D ERRCNT Q
. . . S RECORD=$O(^PRC(443.75,"AR",PONO,0))
. . Q:$O(PRCXM(0))
. . S VENDOR(1)=$P($G(^PRC(443.75,+$G(RECORD),0)),U,6)
. . I VENDOR]"",VENDOR(1)]""&(VENDOR'=VENDOR(1)) S PRCXM(ERRCNT)=$P($T(ERROR+20),";;",2)_$G(RECORD)_"." D ERRCNT Q
. S:PRCTT="RFQ" RECORD=$O(^PRC(443.75,"AC",PRCTT,PONO,VENDOR,RFQ,0))
. S:PRCTT="TXT" RECORD=$O(^PRC(443.75,"AF",PRCTT,PONO,VENDOR,TEXT,0))
. I $G(^PRC(443.75,+$G(RECORD),0))']"" S PRCXM(ERRCNT)=$P($T(ERROR+12),";;",2)_$G(PONO)_"." D ERRCNT Q
. L +^PRC(443.75,RECORD):180 E S PRCXM(ERRCNT)=$P($T(ERROR+18),";;",2)_$G(RECORD)_"." D ERRCNT Q
. ;
. I SEGT="RJ" D
. . S PRC(1,443.75,"?+1,",11)=$P(LINE,U,7)
. . S PRC(1,443.75,"?+1,",12)=$P(LINE,U,8)
. . S PRC(1,443.75,"?+1,",13)=$P(LINE,U,9)
. . S:$P(LINE,U,12)]"" PRC(1,443.75,"?+1,",17)=$P(LINE,U,12)
. . S:$P(LINE,U,13)]"" PRC(1,443.75,"?+1,",18)=$P(LINE,U,13)
. . S:$P(LINE,U,10)]"" PRC(1,443.75,"?+1,",14)=$P(LINE,U,10)
. . S RRC=$$EXTRL^PRCOACT0($P(LINE,U,15),1)
. . I RRC']"" S PRCXM(ERRCNT)=$P($T(ERROR+5),";;",2)_$G(PRCDA)_"." D ERRCNT
. . I RRC']"" S PRC(1,443.75,"?+1,",19)="E"
. . I RRC']"" S PRC(1,443.75,"?+1,",20)=$P($T(ERROR+5),";;",3) Q
. . S RRC=$O(^PRC(443.76,"B",RRC,0))
. . I RRC'>0 S PRCXM(ERRCNT)=$P($T(ERROR+6),";;",2)_$G(PRCDA)_" (Error Code is "_$$EXTRL^PRCOACT0($P(LINE,U,15),1)_")." D ERRCNT
. . I RRC'>0 S PRC(1,443.75,"?+1,",19)="E"
. . I RRC'>0 S PRC(1,443.75,"?+1,",20)=$P($T(ERROR+6),";;",3) Q
. . S PRC(1,443.75,"?+1,",15)=RRC
. . Q
. S PRC(1,443.75,"?+1,",.01)=+$P($G(^PRC(443.75,RECORD,0)),U)
. D UPDATE^DIE("","PRC(1)")
. S COUNTER=COUNTER+1
STOP . L:$G(RECORD) -^PRC(443.75,RECORD)
. Q
I $G(RECORD),COUNTER'=COUNT S PRCXM(ERRCNT)=$P($T(ERROR+7),";;",2)_$G(PRCDA)_"." D ERRCNT
;
EXIT I $O(PRCXM(0)) D PERROR^PRCOACT0 Q
D KILL^PRCOSRV3(PRCDA)
Q
ERRCNT ;increment counter for multiple errors within RJ,TR processing
S ERRCNT=ERRCNT+1
Q
;
ERROR ;HERE IS THE LIST OF ERROR MESSAGES
;;Expected an ACT or a PRJ transaction. Received a ;;A1
;;The STATION number sent from EDI can not be found. The number is ;;A2
;;The second segment is not the expected AT segment. It was a ;;A3
;;There is no STATION number sent from EDI. IEN for 423.6 is ;;A4
;;No REJECT REASON CODE from EDI. The record IEN in 423.6 is ;;A5
;;The ERROR CODE can not be found in the EDI ERROR CODES file. The record IEN in 423.6 is ;;A6
;;There is a difference in the number of TR or RJ segments expected and how many found. File 423.6 entry is ;;A7
;;There is no "B" cross-reference entry for this transaction in file 423.5. The entry is ;;A8
;;There is a "B" cross-reference entry for this transaction but no record.;;A9
;;There is a record for this transaction but no mail group pointer is listed.;;A10
;;The mail group entered in the record in file 423.5 can not be found in the mail group file.;;A11
;;The incoming record can't be found in file 443.75. The RFQ/PO# is ;;A12
;;Required field TYPE OF TRANSACTION is blank. IEN for file 423.6 is ;;A13
;;Required field REF NUMBER is blank. IEN for file 423.6 is ;;A14
;;Required field VENDOR ID NUMBER is blank. IEN for file 423.6 is ;;A15
;;Required field TYPE OF RFQ is blank. IEN for file 423.6 is ;;A16
;;Required field TXT MESSAGE NUMBER is blank. IEN for file 423.6 is ;;A17
;;Unable to access record in file 443.75. IEN is ;;A18
;;Unable to locate entry in file 443.75. IEN for file 423.6 is ;;A19
;;VENDOR ID on transmission does not match 443.75 entry. The IEN is ;;A20
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HPRCOACT 7105 printed Apr 09, 2024@21:10:20 Page 2
PRCOACT ;WISC/DJM-"ACT" & "PRJ" TRANSACTIONS FROM AUSTIN ;7/21/96 21:45
V ;;5.1;IFCAP;**202**;Oct 20, 2000;Build 27
+1 ;Per VA Directive 6402, this routine should not be modified.
+2 ;
START ;THIS ROUTINE WILL SAVE THE INCOMMING "ACT" OR "PRJ" TRANSACTION
+1 ;IN THE "EDI STATUS" FILE (#443.75) WITHIN AN EXISTING RECORD. THIS
+2 ;ROUTINE WILL START UP WHEN AN "ACT" OR "PRJ" TRANSACTION ARRIVES
+3 ;FROM AUSTIN AND IS SAVED IN FILE 423.6. AFTER SAVING IN 423.6 THE
+4 ;SERVER WILL START UP A BACKGROUND TASK THAT CALLS THIS ROUTINE.
+5 ;
+6 ;THE BACKGROUND TASK WILL SET UP **PRCDA**, THE INTERNAL ENTRY
+7 ;NUMBER FROM FILE 423.6. THE RECORD AT **PRCDA** CONTAINS THE DATA
+8 ;FROM THE "ACT" OR "PRJ" TRANSACTION THAT 'ARRIVED' FROM AUSTIN.
+9 ;
+10 NEW COUNT,COUNTER,I,LINE,MGP,PONO,PRC,PRCMG,PRCTC,PRCTT,PRCXM,RFQ,RECORD,ERRCNT
+11 NEW RRC,SEGT,STATION,STCK,TEXT,VENDOR,X,X1,X2
+12 ;
+13 ;NOW LETS VERIFY THAT THE TRANSACTION BELONGS TO THIS SITE.
+14 ;
+15 SET LINE=$GET(^PRCF(423.6,PRCDA,1,10000,0))
+16 SET MGP=$ORDER(^PRCF(423.5,"B",$PIECE(LINE,U)_"-"_$PIECE(LINE,U,4),0))
+17 IF MGP=""
SET PRCXM(1)=$PIECE($TEXT(ERROR+8),";;",2)_$PIECE(LINE,U)_"-"_$PIECE(LINE,U,4)_"."
GOTO EXIT
+18 SET MGP=$GET(^PRCF(423.5,MGP,0))
+19 IF MGP=""
SET PRCXM(1)=$PIECE($TEXT(ERROR+9),";;",2)
GOTO EXIT
+20 IF $PIECE(MGP,U,2)=""
SET PRCXM(1)=$PIECE($TEXT(ERROR+10),";;",2)
GOTO EXIT
+21 IF $PIECE(MGP,U,2)]""
SET PRCMG=$PIECE($GET(^XMB(3.8,$PIECE(MGP,U,2),0)),U)
+22 IF PRCMG=""
SET PRCXM(1)=$PIECE($TEXT(ERROR+11),";;",2)
GOTO EXIT
+23 Begin DoDot:1
+24 IF ",ACT,PRJ,"'[","_$PIECE(LINE,U,4)_","
SET PRCXM(1)=$PIECE($TEXT(ERROR+1),";;",2)_$PIECE(LINE,U,4)_"."
QUIT
+25 SET STATION=$PIECE(LINE,U,3)
IF STATION=""
SET PRCXM(1)=$PIECE($TEXT(ERROR+4),";;",2)_$GET(PRCDA)_"."
QUIT
+26 SET STCK=$ORDER(^PRC(411,"B",STATION,0))
IF STCK'>0
SET PRCXM(1)=$PIECE($TEXT(ERROR+2),";;",2)_$GET(STATION)_"."
QUIT
+27 QUIT
End DoDot:1
IF $DATA(PRCXM(1))
GOTO EXIT
+28 SET PRCTC=$PIECE(LINE,U,4)
+29 ;
+30 ;GATHER THE DATA FROM THE 'AT' SEGMENT OF THE TRANSACTION.
+31 ;
+32 SET LINE=$GET(^PRCF(423.6,PRCDA,1,10001,0))
+33 IF $PIECE(LINE,U,1)'="AT"
SET PRCXM(1)=$PIECE($TEXT(ERROR+3),";;",2)_$PIECE($GET(LINE),U)_"."
GOTO EXIT
+34 SET PRCTT=$PIECE(LINE,U,2)
+35 IF PRCTT=""
SET PRCXM(1)=$PIECE($TEXT(ERROR+13),";;",2)_$GET(PRCDA)_"."
GOTO EXIT
+36 SET COUNT=+$PIECE(LINE,U,3)
+37 ;
+38 ;NOW GET THE DATA FROM EACH 'TR' OR 'RJ' SEGMENT.
+39 ;
+40 SET I=10001
+41 SET COUNTER=0
SET ERRCNT=1
+42 KILL PRCXM
+43 FOR
SET I=$ORDER(^PRCF(423.6,PRCDA,1,I))
if I'>0
QUIT
Begin DoDot:1
+44 KILL PRC
+45 SET LINE=$GET(^PRCF(423.6,PRCDA,1,I,0))
+46 if $EXTRACT(LINE,1)="$"
QUIT
+47 SET SEGT=$PIECE(LINE,U)
+48 if ",TR,RJ,"'[","_SEGT_","
QUIT
+49 SET PRC(1,443.75,"?+1,",9)=PRCTC
+50 SET PRC(1,443.75,"?+1,",21)=COUNT
+51 SET PONO=$PIECE(LINE,U,2)
+52 IF PRCTT="PHA"
Begin DoDot:2
+53 FOR
if $ASCII(PONO,$LENGTH(PONO))'=32
QUIT
SET PONO=$EXTRACT(PONO,1,$LENGTH(PONO)-1)
+54 SET PONO=$EXTRACT(PONO,1,3)_"-"_$EXTRACT(PONO,4,$LENGTH(PONO))
+55 QUIT
End DoDot:2
+56 SET X1=$EXTRACT($PIECE(LINE,U,5),1,4)-1700_"0101"
+57 SET X2=$EXTRACT($PIECE(LINE,U,5),5,7)-1
+58 DO C^%DTC
+59 SET PRC(1,443.75,"?+1,",10)=X_"."_$PIECE(LINE,U,6)
+60 SET PRC(1,443.75,"?+1,",22)=$SELECT(PRCTC="ACT":$PIECE(LINE,U,7),1:$PIECE(LINE,U,14))
+61 SET VENDOR=$PIECE(LINE,U,3)
+62 if PRCTT="RFQ"
SET RFQ=$SELECT(PRCTC="ACT":$PIECE(LINE,U,8),1:$PIECE(LINE,U,16))
+63 if PRCTT="TXT"
SET TEXT=$PIECE(LINE,U,4)
+64 IF PONO=""
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+14),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
QUIT
+65 IF PRCTT'="PHA"
IF VENDOR=""
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+15),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
QUIT
+66 IF PRCTT="RFQ"
IF RFQ=""
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+16),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
QUIT
+67 IF PRCTT="TXT"
IF TEXT=""
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+17),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
QUIT
+68 SET RECORD=""
+69 IF PRCTT="PHA"
Begin DoDot:2
+70 IF VENDOR]""
SET RECORD=$ORDER(^PRC(443.75,"AO",PRCTT,PONO,VENDOR,0))
+71 IF 'RECORD
Begin DoDot:3
+72 SET RECORD=$ORDER(^PRC(443.75,"AR",PONO,0))
End DoDot:3
IF 'RECORD
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+19),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
QUIT
+73 if $ORDER(PRCXM(0))
QUIT
+74 SET VENDOR(1)=$PIECE($GET(^PRC(443.75,+$GET(RECORD),0)),U,6)
+75 IF VENDOR]""
IF VENDOR(1)]""&(VENDOR'=VENDOR(1))
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+20),";;",2)_$GET(RECORD)_"."
DO ERRCNT
QUIT
End DoDot:2
if $ORDER(PRCXM(0))
QUIT
+76 if PRCTT="RFQ"
SET RECORD=$ORDER(^PRC(443.75,"AC",PRCTT,PONO,VENDOR,RFQ,0))
+77 if PRCTT="TXT"
SET RECORD=$ORDER(^PRC(443.75,"AF",PRCTT,PONO,VENDOR,TEXT,0))
+78 IF $GET(^PRC(443.75,+$GET(RECORD),0))']""
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+12),";;",2)_$GET(PONO)_"."
DO ERRCNT
QUIT
+79 LOCK +^PRC(443.75,RECORD):180
IF '$TEST
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+18),";;",2)_$GET(RECORD)_"."
DO ERRCNT
QUIT
+80 ;
+81 IF SEGT="RJ"
Begin DoDot:2
+82 SET PRC(1,443.75,"?+1,",11)=$PIECE(LINE,U,7)
+83 SET PRC(1,443.75,"?+1,",12)=$PIECE(LINE,U,8)
+84 SET PRC(1,443.75,"?+1,",13)=$PIECE(LINE,U,9)
+85 if $PIECE(LINE,U,12)]""
SET PRC(1,443.75,"?+1,",17)=$PIECE(LINE,U,12)
+86 if $PIECE(LINE,U,13)]""
SET PRC(1,443.75,"?+1,",18)=$PIECE(LINE,U,13)
+87 if $PIECE(LINE,U,10)]""
SET PRC(1,443.75,"?+1,",14)=$PIECE(LINE,U,10)
+88 SET RRC=$$EXTRL^PRCOACT0($PIECE(LINE,U,15),1)
+89 IF RRC']""
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+5),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
+90 IF RRC']""
SET PRC(1,443.75,"?+1,",19)="E"
+91 IF RRC']""
SET PRC(1,443.75,"?+1,",20)=$PIECE($TEXT(ERROR+5),";;",3)
QUIT
+92 SET RRC=$ORDER(^PRC(443.76,"B",RRC,0))
+93 IF RRC'>0
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+6),";;",2)_$GET(PRCDA)_" (Error Code is "_$$EXTRL^PRCOACT0($PIECE(LINE,U,15),1)_")."
DO ERRCNT
+94 IF RRC'>0
SET PRC(1,443.75,"?+1,",19)="E"
+95 IF RRC'>0
SET PRC(1,443.75,"?+1,",20)=$PIECE($TEXT(ERROR+6),";;",3)
QUIT
+96 SET PRC(1,443.75,"?+1,",15)=RRC
+97 QUIT
End DoDot:2
+98 SET PRC(1,443.75,"?+1,",.01)=+$PIECE($GET(^PRC(443.75,RECORD,0)),U)
+99 DO UPDATE^DIE("","PRC(1)")
+100 SET COUNTER=COUNTER+1
STOP if $GET(RECORD)
LOCK -^PRC(443.75,RECORD)
+1 QUIT
End DoDot:1
if $ORDER(PRCXM(0))
DO PERROR^PRCOACT0
if LINE["$"
QUIT
+2 IF $GET(RECORD)
IF COUNTER'=COUNT
SET PRCXM(ERRCNT)=$PIECE($TEXT(ERROR+7),";;",2)_$GET(PRCDA)_"."
DO ERRCNT
+3 ;
EXIT IF $ORDER(PRCXM(0))
DO PERROR^PRCOACT0
QUIT
+1 DO KILL^PRCOSRV3(PRCDA)
+2 QUIT
ERRCNT ;increment counter for multiple errors within RJ,TR processing
+1 SET ERRCNT=ERRCNT+1
+2 QUIT
+3 ;
ERROR ;HERE IS THE LIST OF ERROR MESSAGES
+1 ;;Expected an ACT or a PRJ transaction. Received a ;;A1
+2 ;;The STATION number sent from EDI can not be found. The number is ;;A2
+3 ;;The second segment is not the expected AT segment. It was a ;;A3
+4 ;;There is no STATION number sent from EDI. IEN for 423.6 is ;;A4
+5 ;;No REJECT REASON CODE from EDI. The record IEN in 423.6 is ;;A5
+6 ;;The ERROR CODE can not be found in the EDI ERROR CODES file. The record IEN in 423.6 is ;;A6
+7 ;;There is a difference in the number of TR or RJ segments expected and how many found. File 423.6 entry is ;;A7
+8 ;;There is no "B" cross-reference entry for this transaction in file 423.5. The entry is ;;A8
+9 ;;There is a "B" cross-reference entry for this transaction but no record.;;A9
+10 ;;There is a record for this transaction but no mail group pointer is listed.;;A10
+11 ;;The mail group entered in the record in file 423.5 can not be found in the mail group file.;;A11
+12 ;;The incoming record can't be found in file 443.75. The RFQ/PO# is ;;A12
+13 ;;Required field TYPE OF TRANSACTION is blank. IEN for file 423.6 is ;;A13
+14 ;;Required field REF NUMBER is blank. IEN for file 423.6 is ;;A14
+15 ;;Required field VENDOR ID NUMBER is blank. IEN for file 423.6 is ;;A15
+16 ;;Required field TYPE OF RFQ is blank. IEN for file 423.6 is ;;A16
+17 ;;Required field TXT MESSAGE NUMBER is blank. IEN for file 423.6 is ;;A17
+18 ;;Unable to access record in file 443.75. IEN is ;;A18
+19 ;;Unable to locate entry in file 443.75. IEN for file 423.6 is ;;A19
+20 ;;VENDOR ID on transmission does not match 443.75 entry. The IEN is ;;A20
