Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PRS8PP

PRS8PP.m

Go to the documentation of this file. 
  1. PRS8PP ;HISC/MRL,WIRMFO/MGD-DECOMP, PREMIUM PAYS ;05/10/07
  1.  ;;4.0;PAID;**22,40,75,92,96,112,117**;Sep 21, 1995;Build 32
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;
  1.  ;This routine is the entry point for determining certain premium
  1.  ;pays for an employee.  Included are overtime (OT), 
  1.  ;night differential (ND), unscheduled hours (UH), etc.
  1.  ;
  1.  ;Called by Routines:  PRS8ST
  1.  ;
  1.  S D=DAY(DAY,"W") ;                Daily activity string.
  1.  S W=$S(DAY<8:1,1:2) ;             Week.
  1.  I D?1"0"."0" Q  ;                 No activity this date.
  1.  S NDC=1,(HT,HTP,HTFFOT)=0 ;       Counter for hrs worked this 
  1.  ;                                 day (HT=Hours total).
  1.  N HYBRID ;                        HYBRID under P.L 107-135
  1.  S HYBRID=$$HYBRID^PRSAENT1($G(DFN))
  1.  D ^PRS8HR ;                       calculate Norm hrs first
  1.  F M=1:1:96 S VAL=$E(D,M) I VAL'=0 D  ;loop thru minutes of day
  1.  .S DH=DAY(DAY,"DH1")
  1.  .I TWO,M'<+$P(DAY(DAY,"TWO"),"^",2) S DH=DAY(DAY,"DH2") ;    Daily hrs.
  1.  .I NDC,"CWB"'[VAL D ND ;                                        Get ND.
  1.  .I TYP["B",+VAL Q  ;                  Baylor get no premium during tod.
  1.  .I "1234OosEe"'[VAL Q  ;                 Don't chk for non-work status.
  1.  .S X=$E(D,M,96) ;                                     Remainder of day.
  1.  .I X?1N.N,X'[4 Q  ;                      No hrs left other than normal.
  1.  .I "J123MLSWNARXYOFGD"'[VAL!(VAL="O"&($E(DAY(DAY,"HOL"),M)'=2)) S AV="OosEe" D CALC^PRS8HR
  1.  K AV,D,GO,M,NDC,X,X1,J1,J2 Q
  1.  ;
  1. ND ; --- compute ND
  1.  ; Process wagegrade
  1.  I TYP["W" D  Q
  1.  . ; process WG scheduled time
  1.  . I "J23LSARMXYUVFGDZq"[VAL!(VAL="O"&($E(DAY(DAY,"HOL"),M)=2)) D
  1.  . . N DAT,DAYN,FND,M1,NODE,SC,TS
  1.  . . ; find tour segment that contains the time and get it's special code
  1.  . . S FND=0,SC="" ; FND true if found in schedule, SC = special code 
  1.  . . ; look in schedule of current day for M and previous day for M+96
  1.  . . ; (in 2day tour, previous day's schedules >96 are Today's activity)
  1.  . . F DAYN=DAY,DAY-1 D  Q:FND
  1.  . . . S M1=$S(DAYN=DAY:M,1:M+96)
  1.  . . . ; loop thru both tours in day
  1.  . . . F NODE=1,4 S DAT=$G(^TMP($J,"PRS8",DAYN,NODE)) Q:DAT=""  D  Q:FND
  1.  . . . . ; loop thru tour segments in tour
  1.  . . . . F TS=1:1:7 Q:$P(DAT,U,(TS-1)*3+1)=""  D  Q:FND
  1.  . . . . . ; check if time contained in tour segment
  1.  . . . . . I M1'<$P(DAT,U,(TS-1)*3+1),M1'>$P(DAT,U,(TS-1)*3+2) S FND=1,SC=$P(DAT,U,(TS-1)*3+3)
  1.  . . ;
  1.  . . ; if time not found in any schedule, base SC on value of variable
  1.  . . ;   TOUR for Today (or previous day when no scheduled tour Today).
  1.  . . I 'FND S SC=$S($G(^TMP($J,"PRS8",DAY,1))=""&(DAY(DAY-1,"TOUR")>1):DAY(DAY-1,"TOUR")+4,1:TOUR+4)
  1.  . . Q:"^6^7^"'[(U_SC_U)  ; tour segment not coded for shift 2 or 3
  1.  . . S X=(SC-4)+8 ; determine where to store in WK array
  1.  . . I $E(ENT,X-4) D SET ; if employee entitled then store result
  1.  . ;
  1.  . ; process WG unscheduled time
  1.  . I VAL=4!(VAL="O") D
  1.  . . N T,SD
  1.  . . ; unscheduled regular tours for 'shift coverage' that are eligible
  1.  . . ;   for shift 2 or 3 differential were saved in "SD" by PRS8EX.
  1.  . . S SD=$G(^TMP($J,"PRS8",DAY,"SD"))
  1.  . . Q:SD=""
  1.  . . ; see if time belongs to a tour saved in "SD" and if so use the
  1.  . . ;   associated shift (2 or 3)
  1.  . . S SD(1)=0 ; init shift
  1.  . . F T=1:3 S SD(0)=$P(SD,U,T,T+2) Q:SD(0)=""!(SD(0)?1."^")  D  Q:SD(1)
  1.  . . . I M'<+SD(0),M'>$P(SD(0),"^",2) S SD(1)=$P(SD(0),"^",3)
  1.  . . I SD(1) S X=SD(1)+8 I $E(ENT,X-4) D SET
  1.  ;
  1.  ; Process Other Employees (non-Wage Grade)
  1.  ;
  1.  ; Not entitled to ND
  1.  I '$E(ENT,6) Q
  1.  ;
  1.  ; not entitled to ND if No Premium Pay tour
  1.  I $P(DAY(DAY,1),"^",3)=8 Q
  1.  ;
  1.  ; check if time segment could be eligible for ND
  1.  I $$NOTND(TYP,DAY,M) Q
  1.  ;
  1.  S AV="J1234ALSRMUEOosecbVXYFGDZq"
  1.  ;
  1.  ; Grant ND for time before 6a/after 6p or anytime when nurse/hybrid
  1.  ; works tour coverage
  1.  I M<25!(M>72)!($E(DAY(DAY,"P"),M)="N"&(TYP["N"!(TYP["H")!(HYBRID))),AV[VAL D
  1.  . ; The Hybrids defined in Public Law 107-135 will only receive Night
  1.  . ; Differential time for OT and CT worked between 6 p.m. and 6 a.m.
  1.  . Q:HYBRID!(PMP'=""&("^S^T^U^V^"[(U_PMP_U)))&(M'<25&(M'>72))
  1.  . ; Tour time between 6 p.m. and 6 a.m. counts toward ND
  1.  . N DAT,DAYN,FND,M1,NODE,SC,TS,TOT
  1.  . ; find tour segment that contains the time and get it's special code
  1.  . S FND=0,SC="" ; FND true if found in schedule, SC = special code 
  1.  . S TOT="" ; Type Of Time
  1.  . ; look in schedule of current day for M and previous day for M+96
  1.  . ; (in 2day tour, previous day's schedules >96 are Today's activity)
  1.  . F DAYN=DAY,DAY-1 D  Q:FND
  1.  . . S M1=$S(DAYN=DAY:M,1:M+96)
  1.  . . S DAT=$G(^TMP($J,"PRS8",DAYN,2)) D  Q:FND
  1.  . . . ; loop thru tour segments in exceptions
  1.  . . . F TS=1:1:7 Q:$P(DAT,U,(TS-1)*4+1)=""  D  Q:FND
  1.  . . . . ; check if time contained in exception segment
  1.  . . . . I M1'<$P(DAT,U,(TS-1)*4+1),M1'>$P(DAT,U,(TS-1)*4+2) D
  1.  . . . . . S TOT=$P(DAT,U,(TS-1)*4+3)
  1.  . . . . . ; On-Call and Recess are the only types of exceptions
  1.  . . . . . ; where OT, CT and RG can be posted for the same 15 minute
  1.  . . . . . ; segment of time, so don't stop searching if you find these.
  1.  . . . . . I TOT="ON"!(TOT="RS") S TOT="" Q
  1.  . . . . . S FND=1,SC=$P(DAT,U,(TS-1)*4+4)
  1.  . . . . . Q
  1.  . Q:TOT="OT"&("^11^12^17^"'[(U_SC_U))  ; Pre-Scheduled & Tour Coverage & OT/CT With Premiums
  1.  . Q:TOT="CT"&("^12^17^"'[(U_SC_U))     ; Tour Coverage & OT/CT With Premiums
  1.  . ; Code 17 - OT/CT with premiums only get ND for 6p-6a
  1.  . Q:TOT="OT"!(TOT="CT")!(TOT="RG")&(SC=17)&((M'<25)&(M'>72))
  1.  . Q:TOT="RG"&(SC'=7)&(SC'=17)          ; Shift Coverage & OT/CT With Premiums
  1.  . S X=10
  1.  . ; for 36/40 AWS, premium time resulting from their tour 
  1.  . ; will be mapped to Night Differential-AWS (ND/NU) and
  1.  . ; Paid at the AAC with the 1872 divisor for the hourly rate (36*52)
  1.  . I +NAWS=36,("OEc"'[VAL!(TOT="HW")) S X=51
  1.  . D SET
  1.  . ; keep leave count since it may need to be backed out by PRS8MSC0
  1.  . I "LSRUFGDZq"[VAL S WKL(WK)=WKL(WK)+1
  1.  ;
  1.  ; Nurse can get ND for 6a-6p time when part of tour with 4+ hrs in 6p-6a
  1.  ; check is made when M=24 (just before 6am) or M=73 (just after 6pm).
  1.  ; if tour eligible (4+ hours in 'night' time) then ND is granted for
  1.  ; the portion of the tour that falls within the 'day' time.
  1.  I TYP["N"!(TYP["H"),M=73!(M=24),AV_"m"[VAL D
  1.  . N C,J,Q,X,X1,X2,XD
  1.  . ;
  1.  . ; quit if 'day' time is for tour coverage since already counted
  1.  . I $E(DAY(DAY,"P"),$S(M=73:72,1:25))="N" Q
  1.  . ;
  1.  . ; first check if tour has at least 4 hours of 'night' (6pm-6am) time
  1.  . S XD=$S(M=24:-1,1:1) ; loop direction, [6am back, 6pm forward]
  1.  . S X1=M,X2=X1+(XD*15) ; start and stop of 4 hour range
  1.  . ; loop thru tour 'night' time - stop if tour ends or after 4 hours
  1.  . S C=1 ; init flag, false when tour has less than 4 hours of 'night'
  1.  . F J=X1:XD:X2 D  Q:'C
  1.  . . I AV_"m"'[$E(D,J) S C=0 Q  ; inappropriate type of time
  1.  . . I $$NOTND(TYP,DAY,J) S C=0 Q
  1.  . . ; scheduled TOD considered as separate from covered TOD
  1.  . . I $E(DAY(DAY,"P"),M)'=$E(DAY(DAY,"P"),J) S C=0 Q
  1.  . ;
  1.  . Q:'C  ; tour not eligible (less than 4 hours of 'night')
  1.  . ;
  1.  . ; loop thru day time (6am-6pm) portion of tour and grant ND
  1.  . ; don't pay ND for meal-time (m) but continue loop
  1.  . S XD=$S(M=24:1,1:-1) ; loop direction [6am forward, 6pm back]
  1.  . S X1=M+XD,X2=X1+(47*XD) ; start and stop for day time (12 hours)
  1.  . S Q=0 ; init flag, true when end of tour reached
  1.  . F J=X1:XD:X2 D  Q:Q
  1.  . . I AV_"m"'[$E(D,J) S Q=1 Q  ;    inappropriate time
  1.  . . I $$NOTND(TYP,DAY,J) S Q=1 Q
  1.  . . ; scheduled TOD considered as separate from covered TOD
  1.  . . I $E(DAY(DAY,"P"),M)'=$E(DAY(DAY,"P"),J) S Q=1 Q
  1.  . . ; grant ND (unless meal-time, etc.), keep count of leave since it
  1.  . . ;   may need to be backed out by PRS8MSC0
  1.  . . I AV[$E(D,J) D
  1.  . . . S X=10
  1.  . . . ; For 36/46 AWS nurses ND for Holiday Worked (HA/HL) and normal
  1.  . . . ; tour time will be reported as Night Differential-AWS (ND/NU)
  1.  . . . I +NAWS=36 D
  1.  . . . . I $E(DAY(DAY,"HOL"),J)=2 S X=51 Q  ; Holiday Worked
  1.  . . . . I "OEc"'[VAL S X=51 ; Tour time
  1.  . . . D SET
  1.  . . . S:"LSRUFGDZq"[$E(D,J) WKL(WK)=WKL(WK)+1
  1.  ;
  1.  Q
  1.  ;
  1. SETJ ; --- set week node (J variable defined)
  1.  Q:$E(D,J)="m"
  1.  ;
  1. SET ; --- actually set the piece
  1.  S $P(WK(WK),"^",X)=$P(WK(WK),"^",X)+1
  1.  Q
  1.  ;
  1. NOTND(PRSTY,PRSDY,PRSTM) ; Not Eligible Night Differential
  1.  ; in PRSTY  type of employee
  1.  ;    PRSDY  day (1-14)
  1.  ;    PRSTM  time segment (1-96)
  1.  ; returns 0 or 1 (True when not eligible for ND)
  1.  ;
  1.  N VAL
  1.  S VAL=$E(DAY(PRSDY,"W"),PRSTM)
  1.  ;
  1.  ; not entitled to ND
  1.  I ($E(DAY(PRSDY,"P"),PRSTM)=5) Q 1
  1.  ;
  1.  ; OT on non-premium T&L
  1.  I "EOosecb"[VAL,$E(DAY(PRSDY,"P"),PRSTM),VAL'="O"!(VAL="O"&($E(DAY(PRSDY,"HOL"),PRSTM)'=2)) Q 1
  1.  ;
  1.  ; Nurses do not get ND for OT that is not for ND Tour Coverage
  1.  I "Ecb"[VAL!(VAL="O"&'$E(DAY(PRSDY,"HOL"),PRSTM)),PRSTY["N"!(PRSTY["H")!(HYBRID)!("^S^T^U^V^"[(U_PMP_U)),$E(DAY(PRSDY,"P"),PRSTM)'="N" Q 1
  1.  ;
  1.  ; Baylor gets no ND for work time on regularly scheduled day
  1.  I TYP["B","^1^7^8^14^"[("^"_DAY_"^"),"1234ALSRMUNVXYFGDZq"[VAL Q 1
  1.  ;
  1.  ; GS Employees do not get ND for OT that is not Pre-Scheduled
  1.  I "Ecb"[VAL!(VAL="O"&'$E(DAY(PRSDY,"HOL"),PRSTM)),PRSTY'["N",PRSTY'["H",'HYBRID,("^S^T^U^V^"'[(U_PMP_U)),$E(DAY(PRSDY,"P"),PRSTM)'="n" Q 1
  1.  ;
  1.  ; Unsch Reg time needs to be Pre-scheduled to get ND
  1.  I VAL=4,PRSTY["P"!(PRSTY["I"&(PRSTY["N"!(PRSTY["H"))),"Nn"'[$E(DAY(PRSDY,"P"),PRSTM) Q 1
  1.  Q 0 ; did not fail any of the checks