Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSJHLV

PSJHLV.m

Go to the documentation of this file. 
  1. PSJHLV ;BIR/CML3-VERIFY (MAKE ACTIVE) ORDERS ;4/8/99  08:16
  1.  ;;5.0;INPATIENT MEDICATIONS;**39,42,78,92,127,133,268,257**;16 DEC 97;Build 105
  1.  ;
  1.  ; Reference to ^PS(50.7 is supported by DBIA# 2180.
  1.  ; Reference to ^PS(55 is supported by DBIA# 2191.
  1.  ; Reference to ^PSDRUG is supported by DBIA# 2192.
  1.  ; Reference to ^PSSLOCK is supported by DBIA# 2789.
  1.  ;
  1. EN(PSJHLDFN,PSGORD) ;
  1. VFY ; change status, move to 55, and change label record
  1.  N PSJPWD,VAIP,DFN,PSGP,PSGORDP S (DFN,PSGP)=PSJHLDFN D IN5^VADPT S:VAIP(5)]"" PSJPWD=+VAIP(5) G:VAIP(5)']"" DONE
  1.  I $P($G(^PS(53.1,+PSGORD,0)),U,4)'="U" D IV Q
  1.  N PSJSYSP S PSJSYSP=+NURSEACK
  1.  N PSGDT D NOW^%DTC S PSGDT=%
  1.  S CHK=0 D DDCHK G:CHK DONE
  1.  D CHK($G(^PS(53.1,+PSGORD,0)),$G(^(.2)),$G(^(2)))
  1.  G:CHK DONE
  1.  S PSGORDP=PSGORD
  1.  ;
  1.  N PSJRPND0 S PSJRPND0=^PS(53.1,+PSGORD,0) I $P(PSJRPND0,U,24)="R" D
  1.  .N PSGORDR,PSJPRIO,PSJSCHED,FILE55N0
  1.  .S PSGORDR=$P(PSJRPND0,U,25)
  1.  .Q:'$$LS^PSSLOCK(PSGP,PSGORDR)
  1.  .N OEORD,OOEORD,FILE55,FILE55N0,FILE55N2 S FILE55="^PS(55,"_PSJHLDFN_$S($P(PSJRPND0,U,4)="U":",5,",1:",""IV"","),FILE55N0=FILE55_+PSGORDR_",0)",FILE55N2=FILE55_+PSGORDR_",2)"
  1.  .S OEORD=$P(PSJRPND0,U,21) I PSGORDR S OOEORD=$P(@FILE55N0,"^",21) I OEORD'=OOEORD N PSGSD S PSGSD=$P(@FILE55N2,"^",2) D
  1.  ..D EXPOE^PSGOER(PSJHLDFN,PSGORD,+$$LASTREN^PSJLMPRI(PSJHLDFN,PSGORD))
  1.  .K DA,DR,DIE S PSGORDP=PSGORD,DIE="^PS(53.1,",DA=+PSGORD,DR="28////A;104////@" W "." D ^DIE
  1.  .D START^PSGOTR(PSGORD,+PSGORDR) I OEORD D
  1.  ..K DA,DR,DIE S DA(1)=PSJHLDFN,DA=+PSGORDR,DIE=FILE55,DR=$S(DIE["IV":110,1:66)_"////"_+OEORD D ^DIE S DIE=FILE55_+PSGORDR_",0)",$P(@DIE,U,21)=OEORD
  1.  ..D EN1^PSJHL2(PSJHLDFN,"SC",PSGORDR),UNL^PSSLOCK(PSGP,PSGORDR)
  1.  ..S PSGORD=PSGORDR
  1.  ;
  1.  S DIE="^PS(53.1,",DA=+PSGORD,DR="28////A" D ^DIE I $P(PSJRPND0,U,24)'="R" D ^PSGOT
  1.  D CIMOU^PSJIMO1(PSJHLDFN,+PSGORD,"",PSGORDP)
  1.  S DA=+PSGORD,DA(1)=PSJHLDFN,PSGAL("C")=22010
  1.  D ^PSGAL5 S VND4=$G(^PS(55,PSJHLDFN,5,DA,4)) I $P(PSJRPND0,U,24)="R",$P(VND4,U,4) D
  1.  .K DA,DIE,DR I $P(VND4,U,4)<$$LASTREN^PSJLMPRI(PSJHLDFN,PSGORDP) S DIE="^PS(55,"_PSJHLDFN_",5,",DA(1)=PSJHLDFN,DA=+PSGORD,DR="18////@;19////@" D ^DIE
  1.  .S $P(VND4,U,3,4)=""
  1.  S $P(VND4,"^",10)=1
  1.  S:$P(VND4,"^",15)&'$P(VND4,"^",16) $P(VND4,"^",15)="" S:$P(VND4,"^",18)&'$P(VND4,"^",19) $P(VND4,"^",18)="" S:$P(VND4,"^",22)&'$P(VND4,"^",23) $P(VND4,"^",22)="" S $P(VND4,"^",1,2)=+NURSEACK_"^"_PSGDT,^PS(55,PSJHLDFN,5,+PSGORD,4)=VND4
  1.  I '$P(VND4,U,9) S ^PS(55,"APV",PSJHLDFN,+PSGORD)=""
  1.  I '$P(VND4,U,10) S ^PS(55,"ANV",PSJHLDFN,+PSGORD)=""
  1.  I $P(VND4,U,10) K ^PS(55,"ANV",PSJHLDFN,+PSGORD)
  1.  D:$D(PSGORDP) ACTLOG^PSGOEV(PSGORDP,PSJHLDFN,PSGORD)
  1.  D EN1^PSJHL2(PSJHLDFN,"SC",+PSGORD_"U")
  1.  ; ** This is where the Automated Dispensing Machine hook is called. Do NOT DELETE or change this location **
  1.  D NEWJ^PSJADM
  1.  ; ** END of Inferface Hook **
  1.  Q
  1.  ;
  1. IV ;
  1.  NEW DRG,DRGI,DRGN,DRGT,FIL,ON,ON55,P,PSJORD,VADM,VAIN
  1.  S ON=PSGORD,PSIVCHG=0,PSJSYSU=1
  1.  D INP^VADPT
  1.  D GT531^PSIVORFA(PSJHLDFN,PSGORD),ACTIVE^PSIVORC2
  1.  K PSIVCHG,PSJIVORF,PSJORF,PSJORIFN,PSJORL,PSJORNP,PSJPINIT,PSJSYSL,PSJSYSU,PSJSYSW,PSJSYSW0
  1.  Q
  1. DONE ;
  1.  K CHK,DA,DIE,DRGF,DP,DR,ND,PSGAL,PSGODA,PSGPD,VND4 Q
  1.  ;
  1. CHK(ND,DRG,ND2) ; checks for data in required fields
  1.  ; Input: ND  - ^(PS(53.1,PSGORD,0)
  1.  ;        DRG - ^(.2)
  1.  ;        ND2 - ^(2)
  1.  S CHK="" I DRG,$D(^PS(50.7,+DRG,0))
  1.  E  S CHK=1
  1.  I ND="" S CHK=CHK_23
  1.  E  S CHK=CHK_$S($P(ND,"^",3):"",1:2)_$S($P(ND,"^",7)]"":"",1:3)
  1.  ;The naked reference on the line below refers to the variable ND
  1.  ;which is ^PS(53.1,PSGORD,0).
  1.  I ND2="" S CHK=CHK_$S('$D(^(0)):4,$P(^(0),"^",7)="OC":"",1:4)_56
  1.  E  S CHK=CHK_$S($P(ND2,"^")]"":"",ND="":4,$P(ND,"^",7)="OC":"",1:4)_$S($P(ND2,"^",2):"",1:5)_$S($P(ND2,"^",4):"",1:6)
  1.  I $$CHECK^PSGOE8(PSJSYSP),$P(DRG,U,2)="" S CHK=CHK_8
  1.  K PSGDFLG,PSGPFLG S PSGDI=0
  1.  S:'$$OIOK^PSGOE2(+DRG) PSGPFLG=1
  1.  Q
  1.  ;
  1. DDCHK ; dispense drug check
  1.  S DRGF="^PS("_$S(PSGORD["P":"53.1,"_+PSGORD,1:"55,"_PSJHLDFN_",5,"_+PSGORD)_",",CHK=$S('$O(@(DRGF_"1,0)")):7,1:0)
  1.  S PSGPD=$G(@(DRGF_".2)"))
  1.  S CHK=$S('$$DDOK(DRGF_"1,",PSGPD):7,1:0)
  1.  Q
  1.  ;
  1. DDOK(PSJF,OI) ;Check to be sure all dispense drugs that are active in the
  1.   ;order are valid.
  1.   ; Input: PSJF - File root of the order including all but the IEN of 
  1.   ;               the drug. (EX "^PS(53.1,X,1,")
  1.   ;        OI   - IEN of the order's orderable item
  1.   ; Output: 1 - all active DD's in the order are valid
  1.   ;         0 - no DD's active DD's or at least one active is invalid
  1.   N DDCNT,ND,PSJ,X S (X,DDCNT)=0
  1.   I '$O(@(PSJF_"0)")) Q 1
  1.   F PSJ=0:0 S PSJ=$O(@(PSJF_PSJ_")")) Q:'PSJ!X  S ND=$G(@(PSJF_PSJ_",0)"))  D
  1.   .I $P(ND,U,3),($P(ND,U,3)'>PSGDT) Q
  1.   .S DDCNT=DDCNT+1
  1.   .S X=$S('$D(^PSDRUG(+ND,0)):1,$P($G(^(2)),U,3)'["U":1,+$G(^(2))'=+OI:1,$G(^("I"))="":0,1:^("I")'>PSGDT)
  1.   Q $S('DDCNT:0,X=1:0,1:1)
  1.   ;