Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSO293PI

PSO293PI.m

Go to the documentation of this file. 
  1. PSO293PI ;BIR/MFR-EXPIRATION DATE CLEAN UP ;05/03/07
  1.  ;;7.0;OUTPATIENT PHARMACY;**293**;DEC 1997;Build 22
  1.  ;External references ^DPT supported by DBIA 10035
  1.  ;External reference to STATUS^ORQOR2 is supported by DBIA 3458
  1.  ;External reference to ^PS(59.7 is supported by DBIA 694
  1.  N NMSP,JOBSTS,DIR,DIRUT,DIROUT,DTOUT,DUOUT,X,Y,ACTION,EXPJOBDT,PSODUZ
  1.  S NMSP="PSO293PI"
  1.  ;
  1.  S JOBSTS=$$JOBSTS^PSO293P1()
  1.  ;
  1.  W !?5,"Expiration Date clean up job for Outpatient Pharamcy prescriptions"
  1.  W !?5,"=================================================================="
  1.  W !?5,"Current status: "
  1.  W:JOBSTS="N" "NEVER RUN"
  1.  W:JOBSTS="S" "STOPPED ON "_$$FMTE^XLFDT($G(^XTMP(NMSP,"STOPPED")))
  1.  W:JOBSTS="R" "RUNNING"
  1.  W:JOBSTS="C" "COMPLETED ON "_$$FMTE^XLFDT($G(^XTMP(NMSP,"COMPLETED")))
  1.  W:JOBSTS="U" "UNKNOWN"
  1.  W:$G(^XTMP(NMSP,"LASTRX")) " (Last Rx IEN: "_+$G(^XTMP(NMSP,"LASTRX"))_")"
  1.  ;
  1.  S DIR(0)="SO^",DIR("A")=""
  1.  I JOBSTS="N" D
  1.  .S DIR(0)=DIR(0)_"ST:START CLEAN UP JOB;",DIR("A")=DIR("A")_"(ST)Start,",DIR("B")="START"
  1.  I JOBSTS="S" D
  1.  . S DIR(0)=DIR(0)_"RE:RESUME CLEAN UP JOB;",DIR("A")=DIR("A")_"(RE)Resume,"
  1.  I JOBSTS="R" D
  1.  . S DIR(0)=DIR(0)_"SP:STOP CLEAN UP JOB;",DIR("A")=DIR("A")_"(SP)Stop,"
  1.  I JOBSTS="C" D
  1.  . S DIR(0)=DIR(0)_"RR:RE-RUN CLEAN UP JOB;",DIR("A")=DIR("A")_"(RR)Re-run,"
  1.  S DIR(0)=DIR(0)_"VW:VIEW "_$S(JOBSTS'="C":"PARTIAL ",1:"")_"CLEAN UP JOB RESULTS;"
  1.  S DIR("A")=DIR("A")_"(VW)View,",DIR("B")="VIEW"
  1.  S DIR(0)=DIR(0)_"QT:QUIT",DIR("A")=DIR("A")_"(QT)Quit"
  1.  D ^DIR I $D(DIRUT)!$D(DIROUT)!$D(DTOUT)!$D(DUOUT) G QUIT
  1.  S ACTION=Y
  1.  ;
  1.  I ACTION="SP" W !!,"This may take a few minutes, please wait..." D  G QUIT
  1.  . N TIME,UNABLE
  1.  . S ^XTMP(NMSP,"STOP")=1,(TIME,UNABLE)=0
  1.  . F  Q:$D(^XTMP(NMSP,"STOPPED"))  D  Q:UNABLE
  1.  . . H 1 S TIME=TIME+1
  1.  . . I '$D(^XTMP(NMSP,"STOPPED")) D
  1.  . . . I $D(^XTMP(NMSP,"COMPLETED"))!($$JOBSTS^PSO293P1()'="R")!(TIME>600) S UNABLE=1
  1.  ;
  1.  I ACTION="QT" G QUIT
  1.  I ACTION="VW" D DISPLAY^PSO293P1 G QUIT
  1.  ;
  1.  D JOB^PSO293P1()
  1.  Q
  1.  ;
  1. PI ; Post-Install entry point
  1.  N EXPJOBDT,NMSP
  1.  S NMSP="PSO293PI"
  1.  D LOG^PSO293P1("PATCH INSTALLATION")
  1.  S EXPJOBDT=$$GET1^DIQ(59.7,1,49.95,"I")
  1.  I 'EXPJOBDT D
  1.  . S EXPJOBDT=$$FMADD^XLFDT($$DT^XLFDT(),-2)
  1.  . S $P(^PS(59.7,1,49.99),"^",8)=EXPJOBDT
  1.  . D LOG^PSO293P1("DATE AUTO-EXPIRE set: "_$$FMTE^XLFDT(EXPJOBDT,2))
  1.  S ^XTMP(NMSP,"EXPJOBDT")=EXPJOBDT
  1.  ;
  1.  D JOB^PSO293P1($$NOW^XLFDT())
  1.  Q
  1.  ;
  1. EN ;
  1.  N NMSP,PSOINST,CUTOFF,PSOACT,RXP,STOP,PSOINACT,PATIENT,COUNTER,RXP,DRUG,STATUS
  1.  N ISSUEDT,EXPIRDT,BADRXCNT,DAYSSUP,NUMREFS,PSOPROD,LASTCNT,I
  1.  ;
  1.  S NMSP="PSO293PI" I '$G(PSODUZ) S PSODUZ=+$G(DUZ)
  1.  ;
  1.  ; - If can't get Lock, then already running.
  1.  L +^XTMP(NMSP):5 I '$T D LOG^PSO293P1("UNSUCCESSFUL (LOCKED)") G QUIT
  1.  ;
  1.  D SETXTMP
  1.  ;
  1.  I '$G(DT) S DT=$$DT^XLFDT
  1.  S PSOPROD=$$PROD^XUPROD()
  1.  ;
  1.  S PSOINST=$P($$SITE^VASITE(),"^",2)_" ("_+$$SITE^VASITE()_")"
  1.  S CUTOFF=$$GET1^DIQ(59.7,1,49.95,"I") I 'CUTOFF S CUTOFF=$$FMADD^XLFDT(DT,-2)
  1.  S PSOINACT=",11,12,13,14,15,"
  1.  S RXP=+$G(^XTMP(NMSP,"LASTRX"))
  1.  I $G(ACTION)="RE" D
  1.  . F I=2:1:12,14 S BADRXCNT(14)=+$G(^XTMP(NMSP,I))
  1.  S LASTCNT=+$G(BADRXCNT(14)),STOP=0
  1.  F COUNTER=LASTCNT:1 S RXP=$O(^PSRX(RXP)) Q:'RXP  D  Q:STOP
  1.  . S:'(COUNTER#10000) DT=$$DT^XLFDT()
  1.  . S PATIENT=$P($G(^PSRX(RXP,0)),"^",2)
  1.  . S DRUG=$P($G(^PSRX(RXP,0)),"^",6)
  1.  . S STATUS=$P($G(^PSRX(RXP,"STA")),"^")
  1.  . S ISSUEDT=$P($G(^PSRX(RXP,0)),"^",13)
  1.  . S DAYSSUP=$P($G(^PSRX(RXP,0)),"^",8)
  1.  . S NUMREFS=$P($G(^PSRX(RXP,0)),"^",9)
  1.  . S EXPIRDT=$P($G(^PSRX(RXP,2)),"^",6)
  1.  . S BADRXCNT(14)=$G(BADRXCNT(14))+1
  1.  . S BADRXCNT("LASTRX")=RXP_"^"_COUNTER
  1.  . ;--- SKIP bad Rx's
  1.  . I ('PATIENT!'DRUG) Q
  1.  . I '$D(^DPT(PATIENT))!('$D(^PSDRUG(DRUG))) Q
  1.  . I 'ISSUEDT Q
  1.  . ;--- 
  1.  . D SET
  1.  . ;---
  1.  . I '(COUNTER#5000) D
  1.  . . M ^XTMP(NMSP)=BADRXCNT
  1.  . . I $G(^XTMP(NMSP,"STOP")) S STOP=1
  1.  ;
  1.  I STOP D STOP G QUIT
  1.  ;
  1.  M ^XTMP(NMSP)=BADRXCNT
  1.  S ^XTMP(NMSP,"COMPLETED")=$$NOW^XLFDT()
  1.  K ^XTMP(NMSP,"LASTRX")
  1.  D LOG^PSO293P1("COMPLETED")
  1.  D MAIL^PSO293P1
  1.  ;
  1. QUIT ;
  1.  L -^XTMP(NMSP)
  1.  Q
  1.  ;
  1. STOP ;
  1.  K ^XTMP(NMSP,"STOP")
  1.  S ^XTMP(NMSP,"STOPPED")=$$NOW^XLFDT()
  1.  D LOG^PSO293P1("STOPPED")
  1.  D MAIL^PSO293P1
  1.  Q
  1.  ;
  1. SET ;
  1.  N CPRSDC,CPRSTA,NEWEXPDT,DA,DIE,ORN,DR
  1.  S CPRSDC=",1,7,12,13,"
  1.  ;
  1.  ; --- No expiration date on PRESCRIPTION file (#52)
  1.  I EXPIRDT="" D  Q
  1.  . S ORN=$$CPRSNUM(RXP),CPRSTA=$P(ORN,"^",2),ORN=+ORN
  1.  . D SETEXP^PSO293P1 I '$G(EXPIRDT) Q
  1.  . I EXPIRDT>CUTOFF D  Q                 ; Expiration Date past Cutoff (will be exp. by auto exp. job), Quit
  1.  . . S BADRXCNT(2)=$G(BADRXCNT(2))+1,^XTMP(NMSP,2,RXP)=""
  1.  . . D SENDHDR
  1.  . I PSOINACT'[(","_STATUS_",") D        ; Foce expiration of Rx (Past Exp. Date)
  1.  . . S DA=RXP,DIE=52,DR="100///11",STATUS=11
  1.  . . D ^DIE K DIE,DR
  1.  . . D RXACT^PSOBPSU2(RXP,0,"Rx status set to EXPIRED by PSO*7*293","E",PSODUZ)
  1.  . I ORN D  Q                            ; Rx is expired in CPRS (Update HDR with Exp. Date), Quit 
  1.  . . I CPRSDC'[(","_CPRSTA_","),'$D(^PS(52.41,"AQ",RXP)) D  Q
  1.  . . . S BADRXCNT(3)=$G(BADRXCNT(3))+1,^XTMP(NMSP,3,RXP)=""
  1.  . . . D SENDCPRS()
  1.  . . S BADRXCNT(4)=$G(BADRXCNT(4))+1,^XTMP(NMSP,4,RXP)=""
  1.  . . D SENDHDR
  1.  . I 'ORN D                              ; No CPRS Order # (Update HDR with Exp. Date)
  1.  . . S BADRXCNT(5)=$G(BADRXCNT(5))+1,^XTMP(NMSP,5,RXP)=""
  1.  . . D SENDHDR
  1.  ;
  1.  ; --- Rx is expired. Update CPRS and HDR if necessary
  1.  I STATUS=11 D  Q
  1.  . S ORN=$$CPRSNUM(RXP),CPRSTA=$P(ORN,"^",2),ORN=+ORN
  1.  . S NEWEXPDT=0
  1.  . I $$FMDIFF^XLFDT(EXPIRDT,ISSUEDT,1)>366 D  ; Expiration Date is > 366, Recalculate new Date
  1.  . . S NEWEXPDT=1 D SETEXP^PSO293P1
  1.  . I ORN,CPRSDC'[(","_CPRSTA_","),'$D(^PS(52.41,"AQ",RXP)) D  ; Rx is not expired in CPRS (Update CPRS/HDR with Exp. Date), Quit
  1.  . . I 'NEWEXPDT S BADRXCNT(6)=$G(BADRXCNT(6))+1,^XTMP(NMSP,6,RXP)=""
  1.  . . I NEWEXPDT S BADRXCNT(7)=$G(BADRXCNT(7))+1,^XTMP(NMSP,7,RXP)=""
  1.  . . D SENDCPRS()
  1.  . I 'NEWEXPDT Q                              ; Expiration Date was not recalculated, don't send to HDR
  1.  . S BADRXCNT(8)=$G(BADRXCNT(8))+1,^XTMP(NMSP,8,RXP)=""
  1.  . D SENDHDR
  1.  ;
  1.  I EXPIRDT<CUTOFF,(PSOINACT'[(","_STATUS_",")) D  ; Rx is past exp. date but is still on a non-Expired/DC'd status
  1.  . S DA=RXP                                       ; Note: Rx's expiring on or after the CUTOFF will be picked up
  1.  . S DIE=52,DR="100///11",STATUS=11               ;       by the Auto Expiration Job.
  1.  . D ^DIE K DIE,DR
  1.  . D RXACT^PSOBPSU2(RXP,0,"Rx status set to EXPIRED by PSO*7*293","E",PSODUZ)
  1.  . S ORN=$$CPRSNUM(RXP),CPRSTA=$P(ORN,"^",2),ORN=+ORN
  1.  . I ORN,CPRSDC'[(","_CPRSTA_",") D  Q            ; Update CPRS if necessary, this will also call HDR
  1.  . . S BADRXCNT(9)=$G(BADRXCNT(9))+1,^XTMP(NMSP,9,RXP)=""
  1.  . . D SENDCPRS()
  1.  . I ORN D  Q                                     ; If CPRS was not updated, call HDR if there is an Order #
  1.  . . S BADRXCNT(10)=$G(BADRXCNT(10))+1,^XTMP(NMSP,10,RXP)=""
  1.  . . D SENDHDR
  1.  . I 'ORN D                                       ; If no CPRS Order #, just report (no updates to CPRS/HDR)
  1.  . . S BADRXCNT(11)=$G(BADRXCNT(11))+1
  1.  . . S ^XTMP(NMSP,11,RXP)=""
  1.  ;
  1.  I STATUS=13 D  Q
  1.  . S ORN=+$$CPRSNUM(RXP)
  1.  . I 'ORN D
  1.  . . S BADRXCNT(12)=$G(BADRXCNT(12))+1,^XTMP(NMSP,12,RXP)=""
  1.  . . D SENDHDR
  1.  Q
  1.  ;
  1. CPRSNUM(RXP) ;
  1.  N ORN,STA
  1.  S ORN=$P($G(^PSRX(RXP,"OR1")),"^",2),STA=""
  1.  I ORN S STA=+$$STATUS^ORQOR2(ORN) I STA=0 S ORN=""
  1.  Q (ORN_"^"_STA)
  1.  ;
  1. SETXTMP ; - Initialize the XTMP global
  1.  I $D(^XTMP(NMSP,"STARTED")) D
  1.  . S ^XTMP(NMSP,"RE-STARTED")=$$NOW^XLFDT() D LOG^PSO293P1("RESUMED")
  1.  I '$D(^XTMP(NMSP,"STARTED")) D
  1.  . S ^XTMP(NMSP,"STARTED")=$$NOW^XLFDT() D LOG^PSO293P1("STARTED")
  1.  K ^XTMP(NMSP,"STOP"),^XTMP(NMSP,"STOPPED")
  1.  S ^XTMP(NMSP,0)=$$FMADD^XLFDT($$NOW^XLFDT(),730)_"^"_$$NOW^XLFDT()_"^PSO*7*293 - RX EXPIRATION DATE CLEAN UP"
  1.  Q
  1.  ;
  1. SENDCPRS(CPRSONLY) ; Update CPRS/HDR
  1.  N PSOSSMES,TYPE,STS,STSCOM
  1.  S:$G(CPRSONLY) PSOSSMES="CPRSUP"
  1.  ;
  1.  S TYPE="SC",STS="DC",STSCOM="Discontinued"
  1.  I STATUS=11 S $P(^PSRX(RXP,0),"^",19)=1,STS="ZE",STSCOM="Expired"
  1.  I STATUS=13 S TYPE="OC",STS="",STSCOM="Deleted"
  1.  I STATUS=14 S TYPE="OD",STS="RP",STSCOM="Discontinued/Edited"
  1.  D EN^PSOHLSN1(RXP,TYPE,STS,"Prescription is "_STSCOM_".")
  1.  Q
  1.  ;
  1. SENDHDR ; Update HDR only
  1.  D:$G(PSOPROD) EN^PSOHDR("PRES",RXP)
  1.  Q