Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSOCPIBF

PSOCPIBF.m

Go to the documentation of this file. 
  1. PSOCPIBF ;BIR/EJW-Clean up to bill unbilled CMOP copays ;01/14/02
  1.  ;;7.0;OUTPATIENT PHARMACY;**93**;DEC 1997
  1.  ;External reference to ^XUSEC supported by DBIA 10076
  1.  ;External reference to ^XPD(9.7, supported by DBIA 2197
  1.  S ZTDTH=""
  1.  I $D(ZTQUEUED) S ZTDTH=$H
  1.  I ZTDTH="" D
  1.  .W !,"The background job to clean up unbilled, released CMOP prescription fills must"
  1.  .W !,"be queued to run and complete before 02/01/2002 when tracking for the "
  1.  .W !,"annual copay cap begins."
  1.  .W !!,"If no start date/time is entered when prompted, the background job will be "
  1.  .W !,"queued to run NOW."
  1.  .W !
  1.  .D PATCHDT
  1.  .D CHKSITE
  1.  .D GETDATE
  1.  .D BMES^XPDUTL("Queuing background job to reprocess unbilled copay CMOP Prescription fills...")
  1.  S ZTRTN="EN^PSOCPIBF",ZTIO="",ZTDESC="Background job to bill CMOP unbilled copays" D ^%ZTLOAD K ZTDTH,ZTRTN,ZTIO,ZTDESC
  1.  W:$D(ZTSK)&('$D(ZTQUEUED)) !!,"Task Queued !",!
  1.  Q
  1. EN ;
  1.  N PSODATE,RXP,PSOTEXT,YY,PSOCNT,PSOSTART,PSOEND,PSOSTOP
  1.  S PSOCNT=0
  1.  S PSOSTOP=0
  1.  D NOW^%DTC S Y=% D DD^%DT S PSOSTART=Y
  1.  I '$G(DT) S DT=$$DT^XLFDT
  1.  I DT>3020201 S PSOSTOP=1 D MAIL Q  ; TOO LATE TO RUN CLEAN-UP
  1.  S PSOINST=$O(^XPD(9.7,"B","PSX*2.0*35","")) I PSOINST'="" S PSODATE=$P($G(^XPD(9.7,PSOINST,1)),"^",3)
  1.  I $G(PSODATE)'="" S PSODATE=PSODATE-1
  1.  I $G(PSODATE)="" S PSODATE=3011011 ; DAY BEFORE PSX*2*35 WAS INSTALLED ANYWHERE
  1.  F  S PSODATE=$O(^PSRX("AR",PSODATE)) Q:'PSODATE  S RXP="" F  S RXP=$O(^PSRX("AR",PSODATE,RXP)) Q:'RXP  S YY="" F  S YY=$O(^PSRX("AR",PSODATE,RXP,YY)) Q:YY=""  Q:PSOSTOP  D
  1.  .S PSOIB=+$P($G(^PSRX(RXP,"IB")),"^") I 'PSOIB Q  ; NOT MARKED AS A COPAY RX
  1.  . ; IF NO IB NUMBER FOR THIS FILL, SET UP VARIABLES AND CALL CP^PSOCP.  IF THERE IS AN IB NUMBER AFTER THIS CALL, COUNT IT FOR SUMMARY MAIL MSG
  1.  .I 'YY D  Q
  1.  ..I $P(^PSRX(RXP,"IB"),"^",2)'="" Q
  1.  ..D NOW^%DTC I %>3020201 S PSOSTOP=1 Q  ; STOP IF REACH DATE OF COPAY RATE CHANGE
  1.  ..D SITE
  1.  ..I PSODATE>3011231 D CP^PSOCP
  1.  ..I PSODATE<3020101 D CP^PSOCPIBC ; BEFORE NEW EXEMPTION CHECKS WENT INTO EFFECT
  1.  ..I $P(^PSRX(RXP,"IB"),"^",2)'="" S PSOCNT=PSOCNT+1
  1.  .I $P($G(^PSRX(RXP,1,YY,"IB")),"^",1)="" D
  1.  ..D NOW^%DTC I %>3020201 S PSOSTOP=1 Q  ; STOP IF REACH DATE OF COPAY RATE CHANGE
  1.  ..D SITE
  1.  ..I PSODATE>3011231 D CP^PSOCP
  1.  ..I PSODATE<3020101 D CP^PSOCPIBC ; BEFORE NEW EXEMPTION CHECKS WENT INTO EFFECT
  1.  ..I $P($G(^PSRX(RXP,1,YY,"IB")),"^",1)'="" S PSOCNT=PSOCNT+1
  1. MAIL ;
  1.  D NOW^%DTC S Y=% D DD^%DT S PSOEND=Y
  1.  I $G(DUZ) S XMY(DUZ)=""
  1.  S XMDUZ="Outpatient Pharmacy",XMSUB="Outpatient Pharmacy Copay Clean-up"
  1.  F PSOCXPDA=0:0 S PSOCXPDA=$O(^XUSEC("PSO COPAY",PSOCXPDA)) Q:'PSOCXPDA  S XMY(PSOCXPDA)=""
  1.  I $O(XMY(""))="" Q  ; no recipients for mail message
  1.  S PSOTEXT(1)="The Rx copay clean up job for the Outpatient Pharmacy patch (PSO*7*93)"
  1.  S PSOTEXT(2)="started "_PSOSTART_" and completed "_PSOEND_"."
  1.  I PSOCNT>0 S PSOTEXT(3)="Released unbilled copay Rxs have now been reprocessed."
  1.  I PSOCNT>0 S PSOTEXT(4)="There were "_PSOCNT_" Rx fills successfully billed."
  1.  I PSOCNT=0 S PSOTEXT(3)="No released unbilled copay Rxs were found to reprocess."
  1.  I PSOSTOP D
  1.  .S PSOTEXT(5)=""
  1.  .S PSOTEXT(6)="PROCESSING CANNOT CONTINUE BEYOND JAN. 31,2002 BECAUSE OF COPAY RATE CHANGE."
  1.  .I $G(PSODATE)'="" S Y=PSODATE D DD^%DT S PSOTEXT(7)="AT TIME JOB TERMINATED, RELEASE DATE BEING PROCESSED WAS "_Y
  1.  S XMTEXT="PSOTEXT(" N DIFROM D ^XMD K XMDUZ,XMTEXT,XMSUB
  1.  S:$D(ZTQUEUED) ZTREQ="@"
  1.  Q
  1.  ;
  1. GETDATE ; GET DATE/TIME OF WHEN BACKGROUND JOB SHOULD BE RUN
  1.  S ZTDTH=""
  1.  S NOW=0
  1.  D NOW^%DTC S (Y,TODAY)=% D DD^%DT 
  1.  W !!,"Background job must be queued to start by "_$S(Y<3020131:"Jan 30, 2002 or before.",1:"Jan 31, 2002.")
  1.  I Y>3020131 S ZTDTH=Y Q  ; LET JOB RUN IF IT'S FEB 1,2002 OR LATER.  THE MAILMAN MESSAGE WILL SHOW THAT NO CLEAN UP WAS DONE
  1.  W !!,"At the following prompt, enter a starting date/time after ",Y,!,"and before "_$S(Y<3020131:"Jan 31, 2002",1:"Feb 1, 2002")," or enter NOW to queue the job immediately."
  1.  W !,"If this prompting is during patch installation, you will not see what you type."
  1.  W ! K %DT D NOW^%DTC S %DT="RAEX",%DT(0)=%,%DT("A")="Queue copay clean-up Job to run Date/Time: "
  1.  D ^%DT K %DT I $D(DTOUT)!(Y<0) W "Task will be queued to run NOW" S ZTDTH=$H,NOW=1
  1.  I 'NOW I Y>0,$P(Y,".")>3020130 I TODAY<3020131 W !!,"Must queue background job to start on Jan. 30 or before." G GETDATE
  1.  I 'NOW,Y>0 D
  1.  .S SAVEY=Y
  1.  .D DD^%DT
  1.  .S X=Y
  1.  .S Y=SAVEY
  1. ASK W !!,"Task will be queued to run "_$S(NOW:"NOW",1:X)_" Is that correct?  :"
  1.  R XX:300 S:'$T XX="Y" I XX'="Y",XX'="y",XX'="N",XX'="n" W " Enter Y or N" G ASK
  1.  I XX'="Y",XX'="y" G GETDATE
  1.  I Y>0,ZTDTH="" S ZTDTH=Y
  1.  I ZTDTH="" S ZTDTH=$H
  1.  Q
  1.  ;
  1. SITE ; SET UP VARIABLES NEEDED BY BILLING
  1.  S PSOSITE=$S(YY=0:$P(^PSRX(RXP,2),"^",9),1:$P($G(^PSRX(RXP,1,YY,0)),"^",9))
  1.  I PSOSITE="" Q
  1.  S PSOPAR=$G(^PS(59,PSOSITE,1))
  1.  S PSOSITE7=$P($G(^PS(59,PSOSITE,"IB")),"^")
  1.  Q
  1.  ;
  1. PATCHDT ; SHOW USER WHEN CMOP PATCH WAS FIRST INSTALLED
  1.  S PSOFIRST="Oct 12, 2001" ; DEFAULT FOR WHEN FIRST SITE INSTALLED THE PATCH
  1.  S PSOINST=$O(^XPD(9.7,"B","PSX*2.0*35","")) I PSOINST'="" S Y=$P($G(^XPD(9.7,PSOINST,1)),"^",3) D DD^%DT S PSOFIRST=Y
  1.  W !,"CMOP patch PSX*2*35 was first installed at your facility on ",PSOFIRST
  1.  Q
  1.  ;
  1. CHKSITE ; SEE IF ANY DIVISIONS HAD THE PROBLEM
  1.  S PROBTEXT="'BARCODES ON ACTION PROFILES'"
  1.  N SITE,PROB
  1.  S PROB=0
  1.  S SITE="" F  S SITE=$O(^PS(59,SITE)) Q:SITE=""  I '$P($G(^PS(59,SITE,1)),"^",1) D  S PROB=1 Q
  1.  .W !!,"The Outpatient Site (File #59) parameter, "_PROBTEXT
  1.  .W !,"for one or more outpatient sites is either not defined or set to 'No'."
  1.  .W !,"All copay eligible, released CMOP prescription fills from those outpatient"
  1.  .W !,"sites would not have been billed since the installation of PSX*2*35."
  1.  .W !!,"NOTE:  If the estimated number of CMOP prescriptions involved is high based"
  1.  .W !,"on when the patch was first installed and the number of outpatient sites "
  1.  .W !,"involved, you may want to disable journaling for Integrated Billing and"
  1.  .W !,"Accounts Receivable globals ^IB and ^PRCA while the clean up job"
  1.  .W !,"is running."
  1.  W !!,"When the background job is complete, a MailMan message will be sent to the"
  1.  W !,"installer indicating how many copay eligible CMOP prescription fills were "
  1.  W !,"successfully billed."
  1.  I PROB Q
  1.  W !!,"All "_PROBTEXT_" are set to 'YES' for all divisions."
  1.  W !,"The MailMan message at the end should indicate that no fills were found to"
  1.  W !,"reprocess.  (i.e. All released CMOP fills have already been billed.)"
  1.  Q
  1.  ;