Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSODEAMA

PSODEAMA.m

Go to the documentation of this file. 
  1. PSODEAMA ;DAL/JCH - Manually Entered DEA Report ;08/16/2021
  1.  ;;7.0;OUTPATIENT PHARMACY;**545,731**;DEC 1997;Build 18
  1.  ;External reference to DEA NUMBERS file (#8991.9) is supported by DBIA 7002
  1.  ;External reference to XUEPCS DATA file (#8991.6) is supported by DBIA 7015
  1.  ;
  1.  Q
  1.  ;
  1. ENTRY ; Entry Point
  1.  ;
  1.  N PSODONE,PSOHEAD,PSORTYPE
  1.  S PSODONE=0,PSOHEAD="Manually Entered DEA Report"
  1.  D MESSAGE
  1.  D ASK(.PSORTYPE,.PSODONE) Q:$G(PSODONE)
  1.  D DEVICE(.PSODONE) Q:PSODONE  ; Print to device
  1.  D PROCESS
  1.  Q
  1.  ;
  1. PROCESS  ; Process and Print Report Data
  1.  D RUN
  1.  D OUT
  1.  D CLOSE
  1.  D EXIT
  1.  Q
  1.  ;
  1. MESSAGE ; Option informatoin
  1.  ;
  1.  W !!,"This option lists DEA numbers that were added/edited via the Manual DEA Number"
  1.  W !,"Entry [PSO EPCS DEA MANUAL ENTRY] option and were not subsequently updated"
  1.  W !,"using the Add New Providers [PSO PROVIDER ADD] option or the Edit Provider"
  1.  W !,"[PSO PROVIDER EDIT] option while the PSO DOJ/DEA WEB SERVICE was running."
  1.  W !!,"Manually entered DEA numbers are removed from this list after they are edited"
  1.  W !,"using the Add New Providers [PSO PROVIDER ADD] option or the Edit Provider"
  1.  W !,"[PSO PROVIDER EDIT] option while the PSO DOJ/DEA WEB SERVICE is running."
  1.  Q
  1.  ;
  1. ASK(PSORTYPE,PSODONE)  ; Ask user's report options
  1.  ; Summary or Detailed Report
  1.  N DIR,X,Y
  1.  S DIR(0)="S^S:Summary;D:Detailed",DIR("A")="Report Type" D ^DIR K DIR I $D(DIRUT) S PSODONE=1 Q
  1.  S PSORTYPE=Y,PSOHEAD=PSOHEAD_$S(Y="S":"(Summary)",1:"(Detailed)")
  1.  Q
  1.  ;
  1. RUN  ; Run Report
  1.  N DEATXT,PSOLINE,WSDWN
  1.  S PSOLINE=1,WSDWN=0
  1.  D GATHER
  1.  S DEATXT="" F  S DEATXT=$O(^TMP($J,"PSODEAMA","DEA",DEATXT)) Q:DEATXT=""  D
  1.  .N IEN,IENS,WSAR,MANAR
  1.  .S IEN=+$G(^TMP($J,"PSODEAMA","DEA",DEATXT)),IENS=IEN_","
  1.  .D GETMAN(IENS,.MANAR)
  1.  .I DEATXT'="" D GETWS(DEATXT,.WSAR,.WSDWN)
  1.  .D COMPILE(.MANAR,.WSAR,.PSOLINE,PSORTYPE)
  1.  Q PSODONE
  1.  ;
  1. GATHER ; Identify Manually entered DEA #'s
  1.  N DEAIEN,DEATXT,PSODONE S PSODONE=0
  1.  K ^TMP($J,"PSODEAMA")
  1.  S DEAIEN=0 F  S DEAIEN=$O(^XTV(8991.9,DEAIEN)) Q:'DEAIEN!$G(PSODONE)  D
  1.  .N RETURN,ERROR,FIELDS,DOJUPDT,IENS,MANAR,WSAR,DEATXT,WSDWN
  1.  .S IENS=DEAIEN_","
  1.  .Q:$$GET1^DIQ(8991.9,IENS,10.3,"I")  ; Quit if Last Updated by PSO DOJ/DEA WEB SERVICE
  1.  .S DEATXT=$$GET1^DIQ(8991.9,IENS,.01,"E")
  1.  .S ^TMP($J,"PSODEAMA","DEA",DEATXT)=DEAIEN
  1.  Q
  1.  ;
  1. GETMAN(IENS,MANAR) ; Get one manually entered DEA number from DEA NUMBERS file (#8991.9)
  1.  N TMPAR
  1.  ;S FIELDS=".01;.02;.03;.04;.05;.06;.07;1.1;1.2;1.3;1.4;1.5;1.6;1.7;2.1;2.2;2.3;2.4;2.5;2.6;10.1;10.2;10.3" ;P731 detox/x-waiver removal
  1.  S FIELDS=".01;.02;.04;.05;.06;.07;1.1;1.2;1.3;1.4;1.5;1.6;1.7;2.1;2.2;2.3;2.4;2.5;2.6;10.1;10.2;10.3"
  1.  D GETS^DIQ(8991.9,IENS,FIELDS,,"MANAR","ERROR")
  1.  M TMPAR=MANAR(8991.9,IENS) K MANAR M MANAR=TMPAR
  1.  Q
  1.  ;
  1. GETWS(DEATXT,WSAR,WSDWN) ; Get one DEA#'s information from Web Service
  1.  N RETURN,NOMORE,FLD,TXTLN
  1.  S NOMORE=0
  1.  I '$G(WSDWN) S RETURN=$$WSGET^PSODEAUT(.WSAR,DEATXT)
  1.  S RETURN=$G(RETURN)
  1.  I $P(RETURN,U,3)=6059 S WSDWN=1   ; Web Service Down
  1.  I (RETURN["DEA NUMBER NOT FOUND")!$G(WSDWN) D  Q
  1.  .F TXTLN=1:1:999 Q:NOMORE  S FLD=$P($T(JSONFLDS+TXTLN),";",2) D
  1.  ..I FLD="***" S NOMORE=1 Q
  1.  ..I FLD="deaNumber" S WSAR(FLD)=$S($G(WSDWN):"Unable to Connect",1:"Not Found") Q
  1.  ..S WSAR(FLD)="**"
  1.  Q
  1.  ;
  1. COMPILE(MANAR,WSAR,PSOLINE,PSORTYPE) ; Print results
  1.  N DS,DSII,DSIIN,DSIII,DSIIIN,DSIV,DSV,COL1IN,COL2IN,PSEXPDTE,PSDTRSLT,BAC,PSDTXDOJ,PSTYPE
  1.  N PRNAM,PRNO,PRNOCONTXT,XIP
  1.  S COL1IN=20,COL2IN=21
  1.  ;
  1.  S ^TMP($J,"PSODEAMA","OUT",PSOLINE)="",PSOLINE=PSOLINE+1
  1.  S PRNOCONTXT="Unable to Connect"
  1.  ;
  1.  S PRNO=$$ASSIGNED(MANAR(.01))
  1.  S ^TMP($J,"PSODEAMA","OUT",PSOLINE)="DEA Number "_MANAR(.01)_$S(PRNO:" assigned to "_$P(PRNO,U,2)_" (IEN: "_+PRNO_")",1:" not assigned to any providers.")
  1.  S PSOLINE=PSOLINE+1
  1.  ;
  1.  Q:$G(PSORTYPE)="S"
  1.  ;
  1.  S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("FIELD NAME",COL1IN)_$$LJ^XLFSTR("DOJ VALUE",COL2IN)_"LOCAL VISTA VALUE (Manual)"
  1.  S PSOLINE=PSOLINE+1
  1.  S $P(^TMP($J,"PSODEAMA","OUT",PSOLINE),"-",75)="-"
  1.  S PSOLINE=PSOLINE+1
  1.  S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("DEA NUMBER: ",COL1IN)_$$LJ^XLFSTR(WSAR("deaNumber"),COL2IN)_MANAR(.01)
  1.  S PSOLINE=PSOLINE+1
  1.  I WSAR("name")'=MANAR(1.1) D
  1.  .I $G(WSDWN) S WSAR("name")=PRNOCONTXT Q
  1.  . S:$E(WSAR("name"),$L(WSAR("name")))'="*" WSAR("name")=WSAR("name")_"**"
  1.  S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("NAME: ",COL1IN)_$$LJ^XLFSTR(WSAR("name"),COL2IN)_MANAR(1.1)
  1.  S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(WSAR("address1"),MANAR(1.2)) D
  1.  . I WSAR("address1")'=MANAR(1.2) D
  1.  .. I $G(WSDWN) S WSAR("address1")=PRNOCONTXT Q
  1.  .. S:WSAR("address1")'="**" WSAR("address1")=WSAR("address1")_"**"
  1.  . S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("ADDRESS 1:",COL1IN)_$$LJ^XLFSTR(WSAR("address1"),COL2IN)_MANAR(1.2)
  1.  . S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(WSAR("address2"),MANAR(1.3)) D
  1.  .I WSAR("address2")'=MANAR(1.3) D
  1.  .. I $G(WSDWN) S WSAR("address2")=PRNOCONTXT Q
  1.  .. S:WSAR("address2")'="**" WSAR("address2")=WSAR("address2")_"**"
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("ADDRESS 2:",COL1IN)_$$LJ^XLFSTR(WSAR("address2"),COL2IN)_MANAR(1.3)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;;
  1.  ;I $$NULLCHK(WSAR("address3"),MANAR(1.4)) D
  1.  ;.I WSAR("address3")'=MANAR(1.4) S:WSAR("address3")'="**" WSAR("address3")=WSAR("address3")_"**"
  1.  ;.S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("ADDRESS 3:",COL1IN)_$$LJ^XLFSTR(WSAR("address3"),COL2IN)_MANAR(1.4)
  1.  ;.S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(WSAR("city"),MANAR(1.5)) D
  1.  . I WSAR("city")'=MANAR(1.5) D
  1.  .. I $G(WSDWN) S WSAR("city")=PRNOCONTXT Q
  1.  .. S:WSAR("city")'="**" WSAR("city")=WSAR("city")_"**"
  1.  . S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("CITY:",COL1IN)_$$LJ^XLFSTR(WSAR("city"),COL2IN)_MANAR(1.5)
  1.  . S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(WSAR("state"),MANAR(1.6)) D
  1.  . D POSTAL^XIPUTIL($G(WSAR("zipCode")),.XIP) S XSTATE=$G(XIP("STATE"))
  1.  . I XSTATE'=MANAR(1.6) D
  1.  .. I $G(WSDWN) S XSTATE=PRNOCONTXT Q
  1.  .. S:XSTATE'="**" XSTATE=XSTATE_"**"
  1.  . S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("STATE:",COL1IN)_$$LJ^XLFSTR(XSTATE,COL2IN)_MANAR(1.6)
  1.  . S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(WSAR("zipCode"),MANAR(1.7)) D
  1.  . I WSAR("zipCode")'=MANAR(1.7) D
  1.  .. I $G(WSDWN) S WSAR("zipCode")=PRNOCONTXT Q
  1.  .. S:WSAR("zipCode")'="**" WSAR("zipCode")=WSAR("zipCode")_"**"
  1.  . S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("ZIP:",COL1IN)_$$LJ^XLFSTR(WSAR("zipCode"),COL2IN)_MANAR(1.7)
  1.  . S PSOLINE=PSOLINE+1
  1.  ;
  1.  S BAC=$S($G(WSAR("businessActivityCode"))="**":"",1:$G(WSAR("businessActivityCode")))_$S($G(WSAR("businessActivitySubcode"))="**":"",1:$G(WSAR("businessActivitySubcode")))
  1.  S DEA=WSAR("deaNumber"),PSDTXDOJ=""
  1.  I BAC?1U S BAC=BAC_0
  1.  I BAC'=MANAR(.02) D
  1.  . I $G(WSDWN) S BAC=PRNOCONTXT Q
  1.  . S:BAC'="**" BAC=BAC_"**"
  1.  I $$NULLCHK(BAC,MANAR(.02)) D
  1.  . S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("ACTIVITY CODE:",COL1IN)_$$LJ^XLFSTR(BAC,COL2IN)_MANAR(.02)
  1.  . S PSOLINE=PSOLINE+1
  1.  ;
  1.  S PSTYPE=BAC I $TR(PSTYPE,"*")'="" S PSTYPE=$P($$PROVTYPE^PSODEAUT(PSTYPE),"^",2)
  1.  I $$NULLCHK(WSAR("businessActivityCode"),MANAR(.07)) D
  1.  . I $G(WSDWN) S PSTYPE=PRNOCONTXT
  1.  . I '$G(WSDWN),(PSTYPE'=MANAR(.07)) S:$E(PSTYPE,$L(PSTYPE))'="*" PSTYPE=PSTYPE_"**"
  1.  . S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("TYPE:",COL1IN)_$$LJ^XLFSTR(PSTYPE,COL2IN)_MANAR(.07)
  1.  . S PSOLINE=PSOLINE+1
  1.  ;
  1.  ;P731 detox/x-waiver removal
  1.  ;S BAC=$G(WSAR("businessActivityCode"))_WSAR("businessActivitySubcode")
  1.  ;I $$NULLCHK(BAC,DEA) S PSDTXDOJ=$S($$DETOXCHK^PSODEAUT(BAC):"X"_$E(MANAR(.01),2,9),1:"")
  1.  ;I $$NULLCHK(PSDTXDOJ,MANAR(.03)) D
  1.  ;. I $G(WSDWN) S PSDTXDOJ=PRNOCONTXT
  1.  ;. I '$G(WSDWN),(PSDTXDOJ'=MANAR(.03)) S:$E(PSDTXDOJ,$L(PSDTXDOJ))'="*" PSDTXDOJ=PSDTXDOJ_"**"
  1.  ;. S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("DETOX NUMBER:",COL1IN)_$$LJ^XLFSTR(PSDTXDOJ,COL2IN)_MANAR(.03)
  1.  ;. S PSOLINE=PSOLINE+1
  1.  ;
  1.  S (PSDTRSLT,PSDTRSLT(0))=""
  1.  I $$NULLCHK(WSAR("expirationDate"),MANAR(.04)) D DT^DILF("E",$G(WSAR("expirationDate")),.PSDTRSLT)
  1.  I $G(WSDWN) S PSDTRSLT(0)=PRNOCONTXT
  1.  I '$G(WSDWN),(PSDTRSLT(0)'=MANAR(.04)) S:PSDTRSLT(0)'="**" PSDTRSLT(0)=PSDTRSLT(0)_"**"
  1.  S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("EXPIRATION DATE:",COL1IN)_$$LJ^XLFSTR($G(PSDTRSLT(0)),COL2IN)_MANAR(.04)
  1.  S PSOLINE=PSOLINE+1
  1.  ;
  1.  S DS=WSAR("drugSchedule")
  1.  ;
  1.  I $$NULLCHK(DS,MANAR(2.1)) D
  1.  .I $G(WSDWN) S DSII=PRNOCONTXT
  1.  .I '$G(WSDWN) D
  1.  .. S DSII=$S(DS["22N":"YES",(DS["2"&(DS'["2N")):"YES",DS="**":"",1:"NO")
  1.  .. S DSII=$G(DSII)_$S($G(DSII)'=$G(MANAR(2.1)):"**",1:"")
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("SCH II NARC:",COL1IN)_$$LJ^XLFSTR(DSII,COL2IN)_MANAR(2.1)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(DS,MANAR(2.2)) D
  1.  .I $G(WSDWN) S DSIIN=PRNOCONTXT
  1.  .I '$G(WSDWN) D
  1.  .. S DSIIN=$S(DS["2N":"YES",DS="**":"",1:"NO")
  1.  .. S DSIIN=DSIIN_$S(DSIIN'=$G(MANAR(2.2)):"**",1:"")
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("SCH II NON-NARC:",COL1IN)_$$LJ^XLFSTR(DSIIN,COL2IN)_MANAR(2.2)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(DS,MANAR(2.3)) D
  1.  .I $G(WSDWN) S DSIII=PRNOCONTXT
  1.  .I '$G(WSDWN) D
  1.  .. S DSIII=$S(DS="**":"",DS["33N":"YES",DS["3"&(DS'["3N"):"YES",1:"NO")
  1.  .. S DSIII=DSIII_$S(DSIII'=$G(MANAR(2.3)):"**",1:"")
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("SCH III NARC:",COL1IN)_$$LJ^XLFSTR(DSIII,COL2IN)_MANAR(2.3)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(DS,MANAR(2.4)) D
  1.  .I $G(WSDWN) S DSIIIN=PRNOCONTXT
  1.  .I '$G(WSDWN) D
  1.  .. S DSIIIN=$S(DS="**":"",DS["3N":"YES",1:"NO")
  1.  .. S DSIIIN=DSIIIN_$S(DSIIIN'=$G(MANAR(2.4)):"**",1:"")
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("SCH III NON-NARC:",COL1IN)_$$LJ^XLFSTR(DSIIIN,COL2IN)_MANAR(2.4)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(DS,MANAR(2.5)) D
  1.  .I $G(WSDWN) S DSIV=PRNOCONTXT
  1.  .I '$G(WSDWN) D
  1.  .. S DSIV=$S(DS="**":"",DS["4":"YES",1:"NO")
  1.  .. S DSIV=DSIV_$S(DSIV'=$G(MANAR(2.5)):"**",1:"")
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("SCH IV:",COL1IN)_$$LJ^XLFSTR(DSIV,COL2IN)_MANAR(2.5)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;
  1.  I $$NULLCHK(DS,MANAR(2.6)) D
  1.  .I $G(WSDWN) S DSV=PRNOCONTXT
  1.  .I '$G(WSDWN) D
  1.  .. S DSV=$S(DS="**":"",DS["5":"YES",1:"NO") ; SCHEDULE V
  1.  .. S DSV=DSV_$S(DSV'=$G(MANAR(2.6)):"**",1:"")
  1.  .S ^TMP($J,"PSODEAMA","OUT",PSOLINE)=$$LJ^XLFSTR("SCH V:",COL1IN)_$$LJ^XLFSTR(DSV,COL2IN)_MANAR(2.6)
  1.  .S PSOLINE=PSOLINE+1
  1.  ;
  1.  Q
  1.  ;
  1. OUT   ; Write Output
  1.  N PSOLINE,PSOPAGE,DIR,Y,PSODONE,PSOQ
  1.  S PSOLINE=0,PSOPAGE=1
  1.  I $D(IO("Q")) D CLEAR^VALM1
  1.  U IO
  1.  F  S PSOLINE=$O(^TMP($J,"PSODEAMA","OUT",PSOLINE)) Q:'PSOLINE!$G(PSODONE)  D
  1.  . I PSOLINE>1 D
  1.  .. I ($G(PSORTYPE)'="S") I ^TMP($J,"PSODEAMA","OUT",PSOLINE)="" D  Q:$G(PSODONE)
  1.  ... S PSODONE=$$CHKP(.PSOPAGE,PSOHEAD,PSORTYPE) Q:$G(PSODONE)
  1.  .. I $G(PSORTYPE)="S" S PSODONE=$$CHKP(.PSOPAGE,PSOHEAD,PSORTYPE) Q:$G(PSODONE)
  1.  . I PSOLINE=1 D HDR(.PSOPAGE,PSOHEAD,PSORTYPE)
  1.  . W !,^TMP($J,"PSODEAMA","OUT",PSOLINE)
  1.  I '$G(PSODONE) S PSODONE=$$CHKP(0)
  1.  Q
  1.  ;
  1. DEVICE(PSODONE)  ; Request Device Information
  1.  N %ZIS,IOP,ZTSK,ZTRTN,ZTIO,ZTDESC,ZTSAVE,POP,RTN,VAR
  1.  K IO("Q")
  1.  S %ZIS="QM"
  1.  W ! D ^%ZIS I POP S PSODONE=1 Q
  1.  I $D(IO("Q")) D
  1.  . S RTN=$P($T(+1)," ",1)
  1.  . S ZTRTN="PROCESS^PSODEAMA"
  1.  . S ZTIO=ION
  1.  . S ZTSAVE("PS*")=""
  1.  . S ZTDESC="MANUAL DEA ENTRY REPORT"
  1.  . D ^%ZTLOAD W !,$S($D(ZTSK):"Report is Queued to print (Task "_ZTSK_")",1:"REQUEST CANCELLED") K ZTSK
  1.  . S PSODONE=1
  1.  Q
  1.  ;
  1. NULLCHK(DOJVAL,VISTAVAL) ; Check for null value, filter out askterisks
  1.  I $TR(DOJVAL,"*")]"" Q 1
  1.  I VISTAVAL'="" Q 1
  1.  Q 0
  1.  ;
  1. ASSIGNED(DEA) ; Is the DEA number assigned to a provider?
  1.  N PRNO,PRNAM
  1.  Q:'$$VALN1DEA^XUSER3(DEA) 0
  1.  S PRNO="" S PRNO=$O(^VA(200,"PS4",DEA,PRNO))
  1.  S PRNAM=$$GET1^DIQ(200,PRNO,.01)
  1.  Q PRNO_U_PRNAM
  1.  ;
  1. CHKP(PSOPAGE,PSOHEAD,PSORTYPE) ; Check for End Of Page
  1.  N PSOSCPAD S PSOSCPAD=$S($G(PSORTYPE)="D":15,1:6)
  1.  I $G(PSOPAGE) Q:'($Y>(IOSL-PSOSCPAD)) 0
  1.  S PSOQ=0
  1.  W !
  1.  I $E(IOST)="C" D  Q:$G(PSOQ) PSOQ
  1.  . N X,Y,DTOUT,DUOUT,DIRUT,DIR
  1.  . U IO(0) S DIR(0)="E" D ^DIR K DIR S:$D(DIRUT) PSOQ=1
  1.  . U IO
  1.  I $G(PSOPAGE) D HDR(.PSOPAGE,PSOHEAD,PSORTYPE)
  1.  Q PSOQ
  1.  ;
  1. HDR(PSOPAGE,PSOHEAD,PSORTYPE) ; Print Header
  1.  N X
  1.  W @IOF,PSOHEAD,?40,"Run Date: ",$$FMTE^XLFDT(DT,"5DZ"),$$RJ^XLFSTR("Page "_PSOPAGE,12)
  1.  S X="",$P(X,"=",79)="" W !,X
  1.  I $G(PSORTYPE)="D" D
  1.  . W !,"Asterisks ""**"" indicate the local value does not match the DOJ value."
  1.  S PSOPAGE=$G(PSOPAGE)+1
  1.  Q
  1.  ;
  1. EXIT ; Clean up
  1.  K ^TMP($J)
  1.  D CLOSE
  1.  Q
  1.  ;
  1. CLOSE D ^%ZISC S:$D(ZTQUEUED) ZTREQ="@"
  1.  Q
  1.  ;
  1. JSONFLDS ; JSON fields returned by web service
  1.  ;address1
  1.  ;address2
  1.  ;address3
  1.  ;businessActivityCode
  1.  ;businessActivitySubcode
  1.  ;city
  1.  ;deaNumber
  1.  ;drugSchedule
  1.  ;expirationDate
  1.  ;name
  1.  ;processedDate
  1.  ;state
  1.  ;type
  1.  ;zipCode
  1.  ;***