Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSUCSR0

PSUCSR0.m

Go to the documentation of this file. 
  1. PSUCSR0 ;BIR/DJM,DJE - Extract records for CS ;25 AUG 1998
  1.  ;;4.0;PHARMACY BENEFITS MANAGEMENT;;MARCH, 2005
  1.  ;
  1.  ; 3.2.11.34 Functional Requirement 34
  1.  ;-------------------------------------
  1.  ;
  1.  ; 3.2.11.35 Functional Requirement 35
  1.  ;-------------------------------------
  1.  ;DBIA(S)
  1.  ; Reference to file #4.3  supported by DBIA 2496
  1.  ; Reference to file #40.8 supported by DBIA 2438
  1.  ;
  1.  ; ----- SEE SPECS FOR DETAIL
  1.  ;
  1. EN(PSUMSG) ;Scan and process for Division(s)
  1.  ; PSUMSGT ("M")= # MESSAGES  ("L")= # LINES
  1.  ;
  1. TEST S Y=PSUSDT\1 X ^DD("DD") S PSUDTS=Y ;    start date
  1.  S Y=PSUEDT\1 X ^DD("DD") S PSUDTE=Y ;    end date
  1.  S PSUDUZ=$G(PSUDUZ,DUZ)
  1.  S PSUDIV=0,Z=0
  1.  S:'$D(PSUCSJB) PSUCSJB="PSUCS_"_PSUJOB
  1.  S PSUMC=0 ; No messages set yet
  1.  K ^XTMP(PSUCSJB,"MAIL")
  1.  K ^XTMP(PSUCSJB,"REPORT")
  1.  K ^XTMP(PSUCSJB,"CSFR-37")
  1.  S PSUXMY(DUZ)="" ; *** TESTING
  1.  I '$D(PSUXMY) S PSUXMY(PSUDUZ)="" ; THIS IS WHO WE MAIL TO
  1.  N Z ; Z used to pass back "CONFIRM" numbers
  1.  F  S PSUDIV=$O(^XTMP(PSUCSJB,"RECORDS",PSUDIV)) Q:PSUDIV=""  D
  1.  . S PSUMSEQ=0
  1.  . D DIV(.Z) ; Process a single divisions data extract
  1.  . D SUMMRY^PSUCSR1(.Z) ; Send the summary report(s)
  1.  ; PSUMC holding a variable
  1.  I PSUMC=0 D  ; No data to send messages
  1.  . S PSUMSEQ=0,PSUDIV=PSUSNDR
  1.  . D DIV(.Z)
  1.  . D SUMMRY^PSUCSR1(.Z)
  1.  D VARS("MAIL",1,PSUMC)
  1.  M ^XTMP("PSU_"_$G(PSUJOB,$J),"CONFIRM")=Z
  1.  Q
  1.  ; 3.2.11.36 Functional Requirement 36
  1.  ;-------------------------------------
  1.  ;
  1.  ; 3.2.11.37 Functional Requirement 37
  1.  ;-------------------------------------
  1.  ;
  1.  ;
  1. DIV(PSUMSG) ;EP returns PSUMSG("M")= # MESSAGES ("L")= # LINES
  1.  ; Scan TMP, split lines, transmit per MAX lines in Netmail
  1.  S PSUMAX=$$VAL^PSUTL(4.3,1,8.3)
  1.  S PSUMAX=$S(PSUMAX="":10000,PSUMAX>10000:10000,1:PSUMAX)
  1.  ;
  1.  ;   Split and store into ^XTMP(PSUCSJB,"MAIL",PSUMC,PSUMLC)
  1.  S PSUOMC=PSUMC,PSUMC=PSUMC+1,PSUMSEQ=PSUMSEQ+1,PSUMLC=0
  1.  K ^XTMP(PSUCSJB,"MAIL",PSUMC)
  1.  S PSUTIEN="",PSULC=0,PSUTLC=0
  1.  F  S PSUTIEN=$O(^XTMP(PSUCSJB,"RECORDS",PSUDIV,PSUTIEN)) Q:PSUTIEN=""  D
  1.  . S PSULC=PSULC+1
  1.  . S PSURC=$O(^XTMP(PSUCSJB,"RECORDS",PSUDIV,PSUTIEN,""))
  1.  . S X=$G(^XTMP(PSUCSJB,"RECORDS",PSUDIV,PSUTIEN,PSURC))
  1.  . D EN^PSUCSR1 ; Prepare data for next report (drug breakdown)
  1.  . Q:$G(PSUSMRY)  ; Only do a summary
  1.  . I $G(PSUMASF)!$G(PSUDUZ)!$G(PSUPBMG) D  ; Detail to Hines,self,group
  1.  .. S PSUMLC=PSUMLC+1,PSUTLC=PSUTLC+1
  1.  .. I PSUMLC>PSUMAX S PSUMC=PSUMC+1,PSUMLC=0,PSULC=PSULC+1 Q  ; +  message
  1.  .. I $L(X)<235 S ^XTMP(PSUCSJB,"MAIL",PSUMC,PSUMLC)=X Q
  1.  .. F I=235:-1:1 S Z=$E(X,I) Q:Z="^"
  1.  .. S ^XTMP(PSUCSJB,"MAIL",PSUMC,PSUMLC)=$E(X,1,I)
  1.  .. S PSUMLC=PSUMLC+1
  1.  .. S ^XTMP(PSUCSJB,"MAIL",PSUMC,PSUMLC)="*"_$E(X,I+1,999)
  1.  ; Go mail the message now
  1.  ;I '$G(PSUMASF) S PSUMC=PSUMC-1 Q  ; Do not update the master file, commented out to send detailed message to user DAM
  1.  I PSUMLC=0 D
  1.  . S PSUMLC=PSUMLC+1
  1.  . S ^XTMP(PSUCSJB,"MAIL",PSUMC,PSUMLC)="No data to report"
  1.  S ^XTMP(PSUCSJB,"MAIL",PSUMC)=PSUDIV
  1.  S ^XTMP(PSUCSJB,"DETAIL",PSUMC)=PSUMSEQ_"/"_(PSUMC-PSUOMC)
  1.  S PSUMSG(PSUDIV,6,"M")=$G(PSUMSG(PSUDIV,6,"M"))+(PSUMC-PSUOMC)
  1.  S PSUMSG(PSUDIV,6,"L")=$G(PSUMSG(PSUDIV,6,"L"))+PSUMLC
  1.  Q
  1.  ;
  1. VARS(PSUMMS,S,E) ; Setup variables for contents
  1.  S PSUMC=0,PSUTLC=0
  1.  S XMDUZ=PSUDUZ
  1.  F PSUM=S:1:E D
  1.  . Q:'$D(^XTMP(PSUCSJB,"MAIL",PSUM))
  1.  . S PSUMC=PSUMC+1
  1.  . S PSUMLC=$O(^XTMP(PSUCSJB,"MAIL",PSUM,""),-1),PSUTLC=PSUTLC+PSUMLC
  1.  . S PSUDIV=^XTMP(PSUCSJB,"MAIL",PSUM)
  1.  . I $D(^XTMP(PSUCSJB,"DETAIL",PSUM)) M XMY=PSUXMYH
  1.  . I $D(^XTMP(PSUCSJB,"SUMMARY 1",PSUM)) M XMY=PSUXMYS1
  1.  . I $D(^XTMP(PSUCSJB,"SUMMARY 2",PSUM)) M XMY=PSUXMYS2
  1.  . S X=PSUDIV,DIC=40.8,DIC(0)="X",D="C" D IX^DIC ;**1
  1.  . S X=+Y S PSUDIVNM=$$VAL^PSUTL(40.8,X,.01)
  1.  . S PSUMSEQ=$G(^XTMP(PSUCSJB,"DETAIL",PSUM)) ; Get the mail sequence data
  1.  . S PSUMSEQ=$S(PSUMSEQ="":" ",1:" "_PSUMSEQ_" ")
  1.  . S XMSUB="V. 4.0 PBMCS "_PSUMON_PSUMSEQ_PSUDIV_" "_PSUDIVNM
  1.  . S XMTEXT="^XTMP(PSUCSJB,PSUMMS,PSUM,"
  1.  . S XMCHAN=1
  1.  . D ^XMD
  1.  ;
  1.  Q