Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRHS01

PXRHS01.m

Go to the documentation of this file. 
  1. PXRHS01 ;SLC/SBW - PCE Visit data extract main routine ;6/7/96
  1.  ;;1.0;PCE PATIENT CARE ENCOUNTER;**73,199**;Aug 12, 1996;Build 51
  1.  ; Extract returns visit data with associated ICD code, CPT, and
  1.  ; Provider data.
  1. VISIT(DFN,ENDDT,BEGDT,OCCLIM,CATCODE,EXTRCODE,TIMEORD) ; Control branching
  1.  ;INPUT  : DFN      - Pointer to PATIENT file (#2)
  1.  ;         ENDDT    - Ending date/time in internal FileMan format
  1.  ;                  - Defaults to today's date at 11:59 pm
  1.  ;         BEGDT    - Beginning date/time in internal FileMan format
  1.  ;                  - Defaults to one year prior to today's date
  1.  ;         OCCLIM   - Maximum number of visits returned
  1.  ;         CATCODE  - Pattern Match which controls visit data that is
  1.  ;                    returned (Can include multiple codes)
  1.  ;               A = AMBULATORY
  1.  ;               H = HOSPITALIZATION
  1.  ;               I = IN HOSPITAL
  1.  ;               C = CHART REVIEW
  1.  ;               T = TELECOMMUNICATIONS
  1.  ;               N = NOT FOUND
  1.  ;               S = DAY SURGERY
  1.  ;               O = OBSERVATION
  1.  ;               E = EVENT (HISTORICAL)
  1.  ;               R = NURSING HOME
  1.  ;               D = DAILY HOSPITALIZATION DATA
  1.  ;               X = ANCILLARY PACKAGE DAILY DATA
  1.  ;         EXTRCODE - Pattern Match indicating which optional
  1.  ;                    data is returned (Can be multiple)
  1.  ;               P = return PROVIDER data
  1.  ;               C = return CPT (procedure) data
  1.  ;               D = return ICD-9 (diagnosis) data
  1.  ;         TIMEORD  - Order visits on same day are indexed
  1.  ;                    Default is inverse chronological order
  1.  ;               1 = Time order in regular chronological order
  1.  ;
  1.  ;OUTPUT : 
  1.  ;  Data from VISIT (9000010) file except for hosp. loc. abbr.
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,0) = VISIT/ADMIT DATE&TIME [I;.01] 
  1.  ;        ^ TYPE [E;.03] ^ LOC. OF ENCOUNTER [E;.06]
  1.  ;        ^ SERVICE CATEGORY [E;.07] ^ CHECK OUT DATE&TIME [I;.18] 
  1.  ;        ^ HOSPITAL LOCATION [E;.22] ^ HOSP. LOC. ABBREVIATION [E;44;1]
  1.  ;        ^ OUTSIDE LOCATION [E;2101] ^ CLINIC [E;.08]
  1.  ;        ^ WALK IN/APPT [E;.16] ^ LEVEL OF SERVICE [E;.17]
  1.  ;        ^ ELIGIBILITY [E;.21]
  1.  ;  Data from V CPT (9000010.18) file
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,"C",X) = CPT [I;.01] 
  1.  ;        ^ PROVIDER NARRATIVE [E;.04]
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,"C",X,MODIFIER)="" [E;1/.01]
  1.  ;  Data from V POV (9000010.07) file
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,"D",X) = POV [I;.01]
  1.  ;        ^ MODIFIER [E;.06] ^ CAUSE OF DX [E;.07]
  1.  ;        ^ PLACE OF ACCIDENT [E;.11] ^ PRIMARY/SECONDARY [E;.12]
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,"D",X,"N") = PROVIDER NARRATIVE [E;.04]
  1.  ;  Data from V PROVIDER (9000010.06) file
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,"P",X) = PROVIDER [E;.01]
  1.  ;        ^ PRIMARY/SECONDARY [E;.04]
  1.  ;  Data from V HOSPITALIZATION (9000010.02) file (If Service Category
  1.  ;  is for hospitalization)
  1.  ;  ^TMP("PXHSV",$J,InvExDt,COUNT,"H",X) = DATE OF DISCHARGE [I;.01]
  1.  ;        ^ ADMITTING DX [E;.12]
  1.  ;
  1.  ;   [] = [I(nternal)/E(xternal); Optional file #; Record #]
  1.  ;   Subscripts:
  1.  ;     InvExDt - Inverse FileMan date of DATE OF visit [.01]
  1.  ;     Count   - # of entry
  1.  ;
  1.  Q:$G(DFN)']""!'$D(^AUPNVSIT("AA",DFN))
  1.  N PXCNT,PXIVD,PXVDF,PXBEG,IBEGDT,IENDDT,CHGIVD,PXSTOP,IHSDATE
  1.  S:+$G(OCCLIM)'>0 OCCLIM=999
  1.  S:+$G(BEGDT)'>0 BEGDT=DT-10000
  1.  S:+$G(ENDDT)'>0 ENDDT=DT_".235959"
  1.  ; Chg regular dt/time to inverted dt/time
  1.  S IBEGDT=9999999-ENDDT,IENDDT=9999999-BEGDT+.235959
  1.  K ^TMP("PXHSV",$J)
  1.  S PXBEG=9999999-$P(ENDDT,"."),PXSTOP=(9999999-$P(BEGDT,"."))_".235959",PXCNT=0,IHSDATE=9999999-$$HSDATE+.235959
  1.  F  S PXBEG=$O(^AUPNVSIT("AA",DFN,PXBEG)) Q:+PXBEG'>0!(PXBEG>PXSTOP)  Q:PXBEG>IHSDATE  D  Q:PXCNT'<OCCLIM
  1.  .; Gets all valid visits on one day in last to first order
  1.  .; X-ref is in visit inverse date order but not inverse time order
  1.  . S (PXIVD,PXBEG)=$P(PXBEG,".")_".999999"
  1.  . ;start with last visit on a dt and don't duplicate any visits
  1.  . F  S PXIVD=$O(^AUPNVSIT("AA",DFN,PXIVD),-1) Q:+PXIVD'>0!(PXIVD<$P(PXBEG,"."))  D  Q:PXCNT'<OCCLIM
  1.  . .;invert PXIVD to same format as IBEGDT and IENDDT. For Visit file
  1.  . .;date is inverted date/regular time. We want inverted date/time.
  1.  . . S CHGIVD=9999999-((9999999-$P(PXIVD,"."))_"."_$P(PXIVD,".",2))
  1.  . . Q:(CHGIVD<IBEGDT)!(CHGIVD>IENDDT)
  1.  . . S PXVDF=""
  1.  . . F  S PXVDF=$O(^AUPNVSIT("AA",DFN,PXIVD,PXVDF)) Q:+PXVDF'>0  D GETREC^PXRHS02(PXVDF,$G(CATCODE),$G(EXTRCODE),$S(+$G(TIMEORD):PXIVD,1:""),.PXCNT)  Q:PXCNT'<OCCLIM
  1.  Q
  1.  ;
  1. HSDATE() ; $$() -> switch date
  1.  Q $P(^PX(815,1,0),U,3)