Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMEXLD

PXRMEXLD.m

Go to the documentation of this file. 
  1. PXRMEXLD ;SLC/PJH - Reminder Dialog Exchange Main Routine. ;04/28/2009
  1.  ;;2.0;CLINICAL REMINDERS;**4,6,12**;Feb 04, 2005;Build 73
  1.  ;
  1. START N PXRMBG,PXRMMODE,VALMBCK,VALMBG,VALMCNT,VALMSG,X,XMZ
  1.  S X="IORESET"
  1.  D EN^VALM("PXRM EX LIST DIALOG")
  1.  ;Rebuild Display
  1.  D CDISP^PXRMEXLC(PXRMRIEN)
  1.  K ^TMP("PXRMEXDGH",$J)
  1.  Q
  1.  ;
  1. ENTRY ; Entry point for List Manager
  1.  D FIND Q
  1.  ;
  1. DETAIL ;Detailed display
  1.  S PXRMMODE=0 D DISP(PXRMMODE) Q
  1.  ;
  1. FIND ;Display findings
  1.  S PXRMMODE=2 D DISP(PXRMMODE) Q
  1.  ;
  1. SUM ;Display dialog summary
  1.  S PXRMMODE=3 D DISP(PXRMMODE) Q
  1.  ;
  1. USE ;Display dialog usage
  1.  S PXRMMODE=4 D DISP(PXRMMODE) Q
  1.  ;
  1. TEXT ;Display dialog text
  1.  S PXRMMODE=1 D DISP(PXRMMODE) Q
  1.  ;
  1. EXIT ;
  1.  K ^TMP("PXRMEXLD",$J)
  1.  K ^TMP("PXRMEXDGH",$J)
  1.  Q
  1.  ;
  1. DISP(VIEW) ;Build the requested view and display it.
  1.  D BLDDISP^PXRMEXDB(VIEW)
  1.  ;Change header
  1.  I VIEW=0 D CHGCAP^VALM("HEADER2","Dialog Details")
  1.  I VIEW=1 D CHGCAP^VALM("HEADER2","Dialog Text")
  1.  I VIEW=2 D CHGCAP^VALM("HEADER2","Dialog Findings")
  1.  I VIEW=3 D CHGCAP^VALM("HEADER2","Dialog Summary")
  1.  I VIEW=4 D CHGCAP^VALM("HEADER2","Dialog Usage")
  1.  S VALMCNT=^TMP("PXRMEXLD",$J,"VALMCNT"),VALMBG=1,VALMBCK="R"
  1.  ;Reset protocol
  1.  D XQORM
  1.  Q
  1.  ;
  1. HELP ;
  1.  N ORU,ORUPRMT,XQORM,PXRMTAG
  1.  S PXRMTAG="DLG"
  1.  D EN^VALM("PXRM EX DIALOG HELP")
  1.  Q
  1.  ;
  1. HDR ;
  1.  S VALMHDR(1)="Packed reminder dialog: "
  1.  S VALMHDR(1)=VALMHDR(1)_$G(^TMP("PXRMEXTMP",$J,"PXRMDNAME"))
  1.  I $D(^TMP("PXRMEXTMP",$J,"PXRMDNAT")) S VALMHDR(1)=VALMHDR(1)_" [NATIONAL DIALOG]"
  1.  S VALMHDR("TITLE")=VALMHDR(1)
  1.  S VALMSG="+ Next Screen   - Prev Screen   ?? More Actions"
  1.  Q
  1.  ;
  1. PEXIT ;PXRM EXCH DIALOG MENU protocol exit code
  1.  S VALMSG="+ Next Screen   - Prev Screen   ?? More Actions"
  1.  ;Reset after page up/down etc
  1.  D XQORM
  1.  Q
  1.  ;
  1. VALID(STRING) ;Validate sequence numbers
  1.  N CNT,FOUND,OK
  1.  S FOUND=0,OK=1
  1.  F CNT=1:1 S SEL=$P(STRING,",",CNT) Q:'SEL  D
  1.  .;Invalid selection
  1.  .I ('SEL)!(SEL>VALMCNT)!('$D(@VALMAR@("SEL",SEL))) D  Q
  1.  ..S OK=0 W $C(7),!,SEL_" is not a valid item number." H 2
  1.  .S FOUND=1
  1.  Q:OK&FOUND 1
  1.  Q 0
  1.  ;
  1. XQORM S XQORM("#")=$O(^ORD(101,"B","PXRM EXCH SELECT DIALOG",0))_U_"1:"_VALMCNT
  1.  S XQORM("A")="Select Action: "
  1.  Q
  1.  ;
  1. XSEL ;PXRM EXCH SELECT DIALOG validation
  1.  N ALL,CNT,ERR,IEN,IND,NAME,PXRMDONE,SELECT,SEL
  1.  S ALL="",PXRMDONE=0,PXRMBG=$G(VALMBG)
  1.  ;Invalid selection
  1.  S SELECT=$P(XQORNOD(0),"=",2) I '$$VALID(SELECT) S VALMBCK="R" Q
  1.  ;
  1.  ;Sort the SELECTION into reverse order
  1.  D ORDER^PXRMEXLC(.SELECT,-1)
  1.  ;
  1.  ;Lock the file
  1.  I '$$LOCK^PXRMEXID S VALMBCK="R" Q
  1.  ;
  1.  S NAME=$G(^TMP("PXRMEXTMP",$J,"PXRMDNAME"))
  1.  ;Install dialog component(s)
  1.  S CNT=0
  1.  F CNT=1:1 S SEL=$P(SELECT,",",CNT) Q:'SEL  D  Q:PXRMDONE
  1.  .D INSCOM^PXRMEXID(NAME,SEL,0)
  1.  ;
  1.  ;Unlock file
  1.  D UNLOCK^PXRMEXID
  1.  ;
  1.  ;Rebuild Workfile
  1.  D DISP^PXRMEXLD(PXRMMODE)
  1.  ;
  1.  ;Refresh
  1.  S VALMBCK="R" I $D(PXRMBG) S VALMBG=PXRMBG
  1.  Q