Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RAO7UTL1

RAO7UTL1.m

Go to the documentation of this file.
  1. RAO7UTL1 ;HISC/GJC,FPT-Utilities for HL7 messages. ;9/14/98 08:00
  1. ;;5.0;Radiology/Nuclear Medicine;**2,76**;Mar 16, 1998;Build 4
  1. BRKOUT ; Breakout the 'MSH', 'ORC' & 'PID' segments.
  1. ; Called from: RAO7RON & RAO7RCH
  1. N RADATA,RAHEAD,RASEG,X S X=0
  1. F S X=$O(RAMSG(X)) Q:X'>0 D
  1. . S RASEG=$G(RAMSG(X)),RAHEAD=$P(RASEG,RAHLFS)
  1. . Q:RAHEAD'="PID"&(RAHEAD'="ORC")&(RAHEAD'="MSH")
  1. . S RADATA=$P(RASEG,RAHLFS,2,999)
  1. . S:RAHEAD="MSH" RAMSH3=$P(RADATA,RAHLFS,3)
  1. . S:RAHEAD="ORC" RAORC2=$P(RADATA,RAHLFS,2),RAORC3=$P(RADATA,RAHLFS,3)
  1. . S:RAHEAD="PID" RAPID3=$P(RADATA,RAHLFS,3),RAPID5=$P(RADATA,RAHLFS,5)
  1. . Q
  1. S RADIV(.119)=$P($G(^RA(79,RAMSH3,.1)),U,19)
  1. S:RADIV(.119)="" RADIV(.119)="n"
  1. Q
  1. ABNOR(RAOIFN,RADFN,RADTI) ; test code to find 'Diagnostic Code' for
  1. ; descendents and adopted procedures. Called from RAO7CMP.
  1. ; 'RAOIFN'-> ien of file 75.1
  1. ; 'RADFN' -> ien of the Rad/Nuc Med Patient
  1. ; 'RADTI' -> inverse date of the registered exam
  1. Q:'($D(^RADPT("AO",RAOIFN,RADFN,RADTI))\10) ""
  1. N RABN,RACNI,RAXAM S RABN="",RACNI=0
  1. F S RACNI=$O(^RADPT("AO",RAOIFN,RADFN,RADTI,RACNI)) Q:RACNI'>0 D Q:RABN]""
  1. . S RAXAM(0)=$G(^RADPT(RADFN,"DT",RADTI,"P",RACNI,0))
  1. . Q:'$P(RAXAM(0),"^",25) ; Quit if not part of the set.
  1. . S RABN=$$DIAG^RAO7UTL(RADFN,RADTI,RACNI)
  1. . Q
  1. Q RABN
  1. ;
  1. XAMDT(RADFN) ;Return exam date/time for interpreted non-cancelled case. The
  1. ;'Cancelled' EXAMINATION STATUS record has an order number of zero.
  1. ;IA#: 4875 Private w/MPI
  1. ; input: RADFN=The DFN of the patient
  1. ;return: RAXAMDT=The exam date/time (FM internal) of the most recent
  1. ; non-cancelled interpreted case, else "0^an active exam
  1. ; with interpretation was not found for this patient"
  1. N RAXAMDT S RAXAMDT="0^an active exam with interpretation was not found for this patient"
  1. S RADTI=0 F S RADTI=$O(^RADPT(RADFN,"DT",RADTI)) Q:'RADTI D Q:RAXAMDT
  1. .S RACNI=0
  1. .F S RACNI=$O(^RADPT(RADFN,"DT",RADTI,"P",RACNI)) Q:'RACNI D Q:RAXAMDT
  1. ..S RAX=$G(^RADPT(RADFN,"DT",RADTI,"P",RACNI,0)) Q:$P(RAX,U,17)="" ;no rpt
  1. ..Q:$P($G(^RA(72,+$P(RAX,U,3),0)),U,3)=0 ;cancelled case
  1. ..S RAXAMDT=(9999999.9999-RADTI)
  1. ..Q
  1. .Q
  1. K RACNI,RADTI,RAX
  1. Q RAXAMDT
  1. ;