Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RARPTUT

RARPTUT.m

Go to the documentation of this file. 
  1. RARPTUT ;HISC/GJC - rad/nuc med report utilities ;04 Dec 2017 9:26 AM
  1.  ;;5.0;Radiology/Nuclear Medicine;**106,114,144**;Mar 16, 1998;Build 1
  1.  ;
  1.  ;Integration Agreements
  1.  ;----------------------
  1.  ;$$FIND^DIC  - 2051 (supported)
  1.  ;FILE^DIE    - 2053 (supported)
  1.  ;UPDATE^DIE  - 2053 (supported)
  1.  ;WP^DIE      - 2053 (supported)
  1.  ;$$IENS^DILF - 2054 (supported)
  1.  ;CLEAN^DILF  - 2054 (supported)
  1.  ;$$GET1^DIQ  - 2056 (supported)
  1.  ;
  1.  ;Events that cause reports to be deleted or to revert back to a
  1.  ;stub form need to make the appropriate case available to be read.
  1.  ;
  1. REL(RARPT,RAERR) ;NTP II - mark a report as 'X' (Deleted) or null
  1.  ;(mimics 'images collected'). Called when an inbound report has a RESULT
  1.  ;STATUS (OBR-25) value of 'VAQ'.
  1.  ;
  1.  ;Input : RARPT = the IEN of the rad/nuc med report record
  1.  ;Output: RAERR = 0 if successful
  1.  ;                <0 error code^Message text^Error location^Type
  1.  ;
  1.  ;    A positive value of RAERR will not trigger a negative acknowledgment
  1.  ;    to be broadcast.
  1.  ;
  1.  S U="^",RAERR=0
  1.  N C,RAPARAMS,RATIMOUT,X,Y S RATIMOUT=300
  1.  ;------------------------------------------------------------------------
  1.  ;lock the report record in question. if unsuccessful quit w/error
  1.  S RAERR=$$LOCKFM^RALOCK(74,RARPT_",",,RATIMOUT) ;(+1)
  1.  S RAERR=$$LOCKERR^RAERR(RAERR,"Rad/Nuc Med Reports file")
  1.  ;RAERR = -15^The Rad/Nuc Med Reports file is locked by other user/task. Please try later.
  1.  ;        ^LOCKERR+1~RAERR^W
  1.  I RAERR D  QUIT
  1.  .N RATXT S RATXT(1)=$P(RAERR,U,2),RATXT(2)="IEN: "_$G(RARPT,-1)
  1.  .S RATXT(3)="Calling Routine: "_$P(RAERR,U,3)
  1.  .D MM(74,.RATXT)
  1.  .Q
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. CHKSTS ;In order to 'mark as deleted', NTP reports those reports must have a
  1.  ;REPORT STATUS of 'R' (RELEASED/NOT VERIFIED). If the report status is
  1.  ;not set to 'R' log the error, unlock the report & quit.
  1.  ;RAERR="-19^Invalid value of field #5 in file #74, IENS='2317'.^^E"                 
  1.  S RARPT(0)=$G(^RARPT(RARPT,0))
  1.  I $P(RARPT(0),U,5)'="R" D  Q
  1.  .S RAERR=$$ERROR^RAERR(-19,,74,RARPT,5)
  1.  .D UNLOCKFM^RALOCK(74,RARPT_",") ;(-1)
  1.  .N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  .S RATXT(2)=$P($G(RAERR),U,3) D MM(74,.RATXT)
  1.  .Q
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. IMG ;Can't 'mark as deleted' a report being held if images have been
  1.  ;attached to that report record. Held reports w/images get moved to
  1.  ;a null report status.
  1.  ;  RAIMAGES=1 if images are attached
  1.  ;  else RAIMAGES=0
  1.  N RAIMAGES S RAIMAGES=$S($O(^RARPT(RARPT,2005,0))>0:1,1:0)
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. REGEX ;lock at the REGISTERED EXAM (#70.02) record associated with this report
  1.  ;piece 2: Patient DFN, piece 3: EXAM DATE/TIME, piece 4: CASE NUMBER
  1.  ;>>> Note: RAIEN70 is the IEN string at the 70.02 level. <<<
  1.  N RACN,RACNI,RADFN,RADTI,RAIEN70,RAX
  1.  S (DA(1),RADFN)=$P(RARPT(0),U,2),(DA,RADTI)=9999999.9999-$P(RARPT(0),U,3)
  1.  S RACN=+$P(RARPT(0),U,4),RACNI=$O(^RADPT(RADFN,"DT",RADTI,"P","B",RACN,0))
  1.  S RAIEN70=$$IENS^DILF(.DA) K DA
  1.  S RAERR=$$LOCKFM^RALOCK(70.02,RAIEN70,,RATIMOUT) ;(+2)
  1.  S RAERR=$$LOCKERR^RAERR(RAERR,"Registered Exams Sub-File #70.02")
  1.  ;I the case at the REGISTERED EXAMS level is locked
  1.  I RAERR D  QUIT
  1.  .D UNLOCKFM^RALOCK(74,RARPT_",") ;(-1)
  1.  .N RATXT S RATXT(1)=$P($G(RAERR),U,2),RATXT(2)="IEN(s): "_$G(RAIEN70,-1)
  1.  .S RATXT(3)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  .D MM(74,.RATXT)
  1.  .Q
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. RPTXT ;delete the REPORT TEXT (70.03; #17) field value for a exam liked to
  1.  ;a report that does not have attached images.
  1.  ;>>> Note: RAIENS70 is the IEN string at the 70.03 level. <<<
  1.  I RAIMAGES=0 D
  1.  .;make sure you consider printsets
  1.  .S RADA=0 N RAIENS70
  1.  .F  S RADA=$O(^RADPT(RADFN,"DT",RADTI,"P",RADA)) Q:'RADA  D
  1.  ..S RA7003=$G(^RADPT(RADFN,"DT",RADTI,"P",RADA,0)) Q:$P(RA7003,U,17)'=RARPT
  1.  ..S DA=RADA,DA(1)=RADTI,DA(2)=RADFN
  1.  ..S RAIENS70=$$IENS^DILF(.DA) K DA
  1.  ..S RAFDA(70.03,RAIENS70,17)="@"
  1.  ..Q
  1.  .I ($D(RAFDA(70.03))\10) D
  1.  ..D FILE^DIE("","RAFDA") K RA7003,RADA,RAFDA
  1.  ..I $D(DIERR)#2 D
  1.  ...;RAERR="-9^FileMan DBS call error(s); File #70.03; 
  1.  ...;IENS: "1,6917999.9999,76,"^DBS+14~RAERR^E"
  1.  ...S RAERR=$$DBS^RAERR("",-9,70.03,RAIENS70)
  1.  ...D UNLOCKFM^RALOCK(70.02,RAIEN70) ;(-2)
  1.  ...D UNLOCKFM^RALOCK(74,RARPT_",") ;(-1)
  1.  ...N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  ...S RATXT(2)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  ...S RATXT(3)="Calling subroutine: RPTXT"
  1.  ...D MM(70.02,.RATXT)
  1.  ...Q
  1.  ..D CLEAN^DILF
  1.  ..Q
  1.  .Q
  1.  Q:RAERR
  1.  ;
  1. PIS ;delete the PRIMARY INTERPRETING STAFF (70.03; #15) field value
  1.  ;for a exam liked to a report regardless of whether that report has
  1.  ;attached images.
  1.  ;>>> Note: RAIENS70 is the IEN string at the 70.03 level. <<<
  1.  D
  1.  .;make sure you consider printsets
  1.  .S RADA=0 N RAIENS70
  1.  .F  S RADA=$O(^RADPT(RADFN,"DT",RADTI,"P",RADA)) Q:'RADA  D
  1.  ..S RA7003=$G(^RADPT(RADFN,"DT",RADTI,"P",RADA,0))
  1.  ..S DA=RADA,DA(1)=RADTI,DA(2)=RADFN
  1.  ..S RAIENS70=$$IENS^DILF(.DA) K DA
  1.  ..S RAFDA(70.03,RAIENS70,15)="@"
  1.  ..Q
  1.  .I ($D(RAFDA(70.03))\10) D
  1.  ..D FILE^DIE("","RAFDA") K RA7003,RADA,RAFDA
  1.  ..I $D(DIERR)#2 D
  1.  ...;RAERR="-9^FileMan DBS call error(s); File #70.03; 
  1.  ...;IENS: "1,6917999.9999,76,"^DBS+14~RAERR^E"
  1.  ...S RAERR=$$DBS^RAERR("",-9,70.03,RAIENS70)
  1.  ...D UNLOCKFM^RALOCK(70.02,RAIEN70) ;(-2)
  1.  ...D UNLOCKFM^RALOCK(74,RARPT_",") ;(-1)
  1.  ...N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  ...S RATXT(2)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  ...S RATXT(3)="Calling subroutine: PIS"
  1.  ...D MM(70.02,.RATXT)
  1.  ...Q
  1.  ..D CLEAN^DILF
  1.  ..Q
  1.  .Q
  1.  Q:RAERR
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. BATCH ;if the report does not have associated images check the REPORT BATCHES
  1.  ;(#74.2) file for references to the report in question. If there are
  1.  ;references to this report those references (pointers) must be deleted.
  1.  ;If there is an error within the RA742 function do not quit. The code
  1.  ;within RA742 will trigger the correct emails. Continue on and update
  1.  ;the REPORT STATUS field.
  1.  I RAIMAGES=0 D RA742(RARPT)
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. RSTATUS ;1) set the REPORT STATUS for reports absent of images to 'X'
  1.  ;          (Deleted)
  1.  ;       2) set the REPORT STATUS for reports w/images present to null
  1.  ;          (mimics 'images collected')
  1.  K RAFDA S RAFDA(74,RARPT_",",5)=$S(RAIMAGES=1:"@",1:"X")
  1.  D FILE^DIE("","RAFDA") K RAFDA
  1.  I $D(DIERR)#2 D
  1.  .;RAERR="-9^FileMan DBS call error(s); File #74; 
  1.  .;IENS: "2370,"^DBS+14~RAERR^E"
  1.  .S RAERR=$$DBS^RAERR("",-9,74,RARPT_",")
  1.  .D UNLOCKFM^RALOCK(70.02,RAIEN70) ;(-2)
  1.  .D UNLOCKFM^RALOCK(74,RARPT_",") ;(-1)
  1.  .N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  .S RATXT(2)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  .D MM(74,.RATXT)
  1.  .Q
  1.  Q:RAERR
  1.  ;
  1. IMPRPTXT ;Delete the IMPRESSION TEXT (#300) and REPORT TEXT (#200)
  1.  ;for a report record, w/images, being released back to the local
  1.  ;facility for interpretation.
  1.  I RAIMAGES=1 D WP^DIE(74,RARPT_",",300,,"@"),WP^DIE(74,RARPT_",",200,,"@")
  1.  ;------------------------------------------------------------------------
  1.  ;
  1. ACTIVLOG ;update the activity log. If an error occurs here inform the mail group
  1.  ;and fall through to the code that unlocks the exam and report records.
  1.  ;
  1.  ;>>> Note: RAIEN is the record number for the newly created activity log sub-file
  1.  ;record. <<<
  1.  ;
  1.  S RAIEN=$$ACTLOG()
  1.  ;
  1.  ;if no error, and there are not images associated with this report build
  1.  ;the RAFDA array for Dx Codes, sec. staff & sec. resident & file the data
  1.  ;in the proper lower level sub-files.
  1.  I RAIEN>0,(RAIMAGES=0) S RAERR=$$ACTLOGX(RAIEN)
  1.  ;
  1.  ;------------------------------------------------------------------------
  1.  ;unlock the records
  1.  D UNLOCKFM^RALOCK(70.02,RAIEN70) ;(-2)
  1.  D UNLOCKFM^RALOCK(74,RARPT_",") ;(-1)
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  ;------------------------------------------------------------------------
  1. MAIL ;Whether the event was a success of failure update the users in the RAD 
  1.  ;HL7 MESSAGES mail group about the change in REPORT STATUS.
  1.  S RARPTSTS=$$GET1^DIQ(74,RARPT_",",5)
  1.  S:RAERR RAX="NTP failed to release a study back to the local facility."
  1.  S:'RAERR RAX="NTP succeeded in releasing a study back to the local facility."
  1.  S RATXT(1)=RAX,RATXT(2)=""
  1.  S RATXT(3)="NTP released Rad/Nuc Med Report: "_$P(RARPT(0),U)_"."
  1.  S RATXT(4)="The REPORT STATUS of this report is: "_$S(RARPTSTS'="":RARPTSTS,1:"N/A")
  1.  D MM(74,.RATXT) K RARPTSTS,RATXT,RAX
  1.  ;------------------------------------------------------------------------
  1.  ;
  1.  D CLEAN^DILF K RAIEN QUIT  ;end of main body...
  1.  ;
  1.  ;>>> subroutines follow <<<
  1.  ;
  1. RA742(RARPT) ;delete a report (without images) from the REPORT BATCHES (#74.2)
  1.  ;REPORTS sub-file 
  1.  ;Input: RARPT = IEN of the RAD/NUC MED REPORT record
  1.  ;;>>> Note: RAIEN742 is the IEN string at the 74.2 level. <<<
  1.  I ($D(^RABTCH(74.2,"D",RARPT))\10) D
  1.  .K DA,RA,RAFDA,RAIEN742,RAX N RAY1,RAY2 S RAY1=0,RA=74.2
  1.  .F  S RAY1=$O(^RABTCH(74.2,"D",RARPT,RAY1)) Q:RAY1'>0  D
  1.  ..S RAY2=0 F  S RAY2=$O(^RABTCH(74.2,"D",RARPT,RAY1,RAY2)) Q:RAY2'>0  D
  1.  ...S DA=RAY2,DA(1)=RAY1 S RAIEN742=$$IENS^DILF(.DA) K DA
  1.  ...S RAERR=$$LOCKFM^RALOCK(74.21,RAIEN742,,RATIMOUT) ;(+3)
  1.  ...S RAERR=$$LOCKERR^RAERR(RAERR,"Report Batches File #74.2")
  1.  ...;
  1.  ...;RAERR = -15^The Rad/Nuc Med Reports file is locked by other user/task. Please try later.
  1.  ...;        ^LOCKERR+1~RAERR^W
  1.  ...I RAERR D  QUIT
  1.  ....N RATXT S RATXT(1)=$P($G(RAERR),U,2),RATXT(2)="IEN: "_$G(RARPT,-1)
  1.  ....S RATXT(3)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  ....D MM(RA,.RATXT)
  1.  ....Q
  1.  ...;
  1.  ...S RAFDA(74.21,RAIEN742,.01)="@"
  1.  ...D FILE^DIE("","RAFDA") K RAFDA
  1.  ...;
  1.  ...I $D(DIERR)#2 D
  1.  ....;RAERR="-9^FileMan DBS call error(s); File #74.21; 
  1.  ....;IENS: "1,113,"^DBS+14~RAERR^E"
  1.  ....S RAERR=$$DBS^RAERR("",-9,74.21,RAIEN742)
  1.  ....N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  ....S RATXT(2)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  ....D MM(RA,.RATXT)
  1.  ....Q
  1.  ...D UNLOCKFM^RALOCK(74.21,RAIEN742) ;(-3)
  1.  ...D CLEAN^DILF K RA,RAIEN742,RAX
  1.  ...Q
  1.  ..Q
  1.  .Q
  1.  Q
  1.  ;
  1. ACTLOG() ;update the Activity Log (#74.01) whenever a report is
  1.  ;has a REPORT STATUS value of DELETED. Remember that printsets
  1.  ;share primary/secondary staff, resident & Dx Codes across all
  1.  ;studies.
  1.  ;
  1.  ;Given: RADFN, RADTI, RACNI, RARPT & RAIMAGE (indicates if DELETED)
  1.  ;Note: the report record remains locked.
  1.  ;>>> Note: RAIENS74 is the IEN string at the 74.01 level. <<<
  1.  ;>>> RAIEN "finds" the next available IEN in the Activity Log sub-file <<<
  1.  N RAERR,RAFDA,RAIEN,RAIENS74,RAUSER,RAY3
  1.  S RAIEN=$O(^RARPT(RARPT,"L",$C(32)),-1),RAIEN=RAIEN+1
  1.  S RAUSER=$$FIND1^DIC(200,,"X","RADIOLOGY,OUTSIDE SERVICE")
  1.  S RAY3=$$GETEXM(),RAIENS74="+"_RAIEN_","_RARPT_","
  1.  S RAFDA(74.01,RAIENS74,.01)=$$NOW^XLFDT() ;to the second
  1.  S RAFDA(74.01,RAIENS74,2)="Q" ;QUIT released back to local VAMC
  1.  S RAFDA(74.01,RAIENS74,3)=$S(RAUSER>0:RAUSER,1:.5) ;a tipoff on a NTP action
  1.  S RAFDA(74.01,RAIENS74,4)="R" ;must be "R" (Released/not Verified)
  1.  ;
  1.  ;if there are no images linked to this report file primary & secondary
  1.  ;Dx Code, resident, & staff into the Activity Log
  1.  I RAIMAGES=0 D
  1.  .S:$P(RAY3,U,2) RAFDA(74.01,RAIENS74,5)=$P(RAY3,U,2) ;dx
  1.  .S:$P(RAY3,U,3) RAFDA(74.01,RAIENS74,7)=$P(RAY3,U,3) ;stf
  1.  .S:$P(RAY3,U) RAFDA(74.01,RAIENS74,9)=$P(RAY3,U) ;res
  1.  .Q
  1.  ;
  1.  D UPDATE^DIE("","RAFDA","RAIEN")
  1.  ;if successful RAIEN(RAIEN) is the new record # for 74.01 sub-file
  1.  I $D(DIERR)#2 D
  1.  .S RAERR=$$DBS^RAERR("",-9,74.01,RAIENS74)
  1.  .N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  .S RATXT(2)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  .D MM(RA,.RATXT)
  1.  .Q
  1.  Q $S(($D(RAERR)#2)<0:RAERR,1:RAIEN(RAIEN))
  1.  ;
  1. ACTLOGX(RAIEN) ;update the lower level sub-files...
  1.  ;given: RARPT
  1.  ;Input: RAIEN is the new record number created @ the 74.01 level
  1.  ;>>> Note: RAIENS74 is the IEN string at the 74.01 level. <<< 
  1.  N RA,RAERR,RAFDA,RAIENS74
  1.  S RAIENS74=","_RAIEN_","_RARPT_",",RA=74.01
  1.  ;build the RAFDA array for Dx Codes, sec. staff & sec. resident
  1.  D SECDX,SECSTF,SECRES
  1.  ;if there's data to be filed, file it. Note: the input transforms
  1.  ;are "clean" so I stuff the internal value (equivalent of a four slash) 
  1.  D:($D(RAFDA)\10) UPDATE^DIE("","RAFDA",,)
  1.  I $D(DIERR)#2 D
  1.  .S RAERR=$$DBS^RAERR("",-9,74.01,RAIENS74)
  1.  .N RATXT S RATXT(1)=$P($G(RAERR),U,2)
  1.  .S RATXT(2)="Calling Routine: "_$P($G(RAERR),U,3)
  1.  .D MM(RA,.RATXT)
  1.  .Q
  1.  Q $S(($D(RAERR)#2)<0:RAERR,1:0)
  1.  ;
  1. MM(RAY,RAX) ;call MailMan; let the members of the mail group know
  1.  ;if a problem exists.
  1.  ;Input: RAY = file #
  1.  ;       RAX = information passed to RAD HL7 MESSAGES members 
  1.  ;I $$GOTLOCAL^XMXAPIG("RAD HL7 MESSAGES") D
  1.  N DIERR,DUZ,RARY,X,XMDUN,XMDUZ,XMMG,XMZ S DUZ=.5,XMDUZ="POSTMASTER"
  1.  S XMSUB="NTP releases a case back to the local facility: #"_RAY
  1.  S XMTEXT="RAX(",XMY("G.RAD HL7 MESSAGES")="",XMY("POSTMASTER")=""
  1.  D ^XMD
  1.  Q
  1.  ;
  1. GETEXM() ;return primary Resident, primary Dx Code & primary Staff data (if any) #70.03
  1.  ;given: RADFN, RADTI & RACNI
  1.  ;return: primary Resident (piece 12)^Dx Code (piece 13)^primary Staff (piece 15)
  1.  N X S X=$G(^RADPT(RADFN,"DT",RADTI,"P",RACNI,0))
  1.  Q ($P(X,U,12)_U_$P(X,U,13)_U_$P(X,U,15))
  1.  ;
  1. SECRES ;return secondary Resident data (if any) #70.09 place in #74.19
  1.  ;given: RADFN, RADTI & RACNI & RAIENS74 (global scope; defined in ACTLOGX)
  1.  N RAIEN,RAX,RAY,RAZ S RAX=500,RAY=0
  1.  F  S RAY=$O(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"SRR",RAY)) Q:'RAY  D
  1.  .S RAZ=$G(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"SRR",RAY,0))
  1.  .S RAIEN="+"_RAX,RAFDA(74.19,RAIEN_RAIENS74,.01)=$P(RAZ,U)
  1.  .S RAX=RAX+1
  1.  .Q
  1.  Q
  1.  ;
  1. SECDX ;return secondary Dx Code data (if any) #70.14 place in #74.16
  1.  ;given: RADFN, RADTI & RACNI & RAIENS74 (global scope; defined in ACTLOGX)
  1.  N RAIEN,RAX,RAY,RAZ S RAX=100,RAY=0
  1.  F  S RAY=$O(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"DX",RAY)) Q:'RAY  D
  1.  .S RAZ=$G(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"DX",RAY,0))
  1.  .S RAIEN="+"_RAX,RAFDA(74.16,RAIEN_RAIENS74,.01)=$P(RAZ,U)
  1.  .S RAX=RAX+1
  1.  .Q
  1.  Q
  1.  ;
  1. SECSTF ;return secondary Staff data (if any) #70.11 place in #74.18
  1.  ;given: RADFN, RADTI & RACNI & RAIENS74 (global scope; defined in ACTLOGX)
  1.  N RAIEN,RAX,RAY,RAZ S RAX=300,RAY=0
  1.  F  S RAY=$O(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"SSR",RAY)) Q:'RAY  D
  1.  .S RAZ=$G(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"SSR",RAY,0))
  1.  .S RAIEN="+"_RAX,RAFDA(74.18,RAIEN_RAIENS74,.01)=$P(RAZ,U)
  1.  .S RAX=RAX+1
  1.  .Q
  1.  Q
  1.  ;
  1. EN ;entry point called (from RAHLO) to trigger the logic that updates the
  1.  ;REPORT STATUS field of a report w/o images to 'deleted'. If the report
  1.  ;does associate with images the report is to be treated as an imaging
  1.  ;stub report.
  1.  ;
  1.  Q:RARPT'>0
  1.  D REL^RARPTUT(RARPT,.RAERR)
  1.  D RELEASE^RAHLRPC ;KLM/p144
  1.  Q:$G(RAERR)'=0
  1.  ;
  1.  ;RAERR will be defined so if RAERR=0 proceed to update the
  1.  ;status of the exam. If RAERR'=0 do not update the status of
  1.  ;the exam.
  1.  ;
  1.  ;Update the exam status. RAMDV (set in RAHLO) is a string that
  1.  ;identifies division specific attributes. 11/NORPT^RASTREQ
  1.  ;determine whether a report exists (an imaging stub is not
  1.  ;a report).
  1.  ;
  1.  ;Note: exam records are locked within UP1^RAUTL1
  1.  I $D(RAMDV)#2,(RAMDV'="") D UP1^RAUTL1
  1.  ;
  1.  ;Note - the fact of the matter is this: upon returning to
  1.  ;RAHLTCPB (which is done after the next 'Q'uit), GENACK is
  1.  ;called only if an error has occurred. Because of this I
  1.  ;call GENACK^RAHLTCPB below because there is no error.
  1.  K:$G(RAERR)=0 RAERR
  1.  D GENACK^RAHLTCPB ; generate 'ACK' message
  1.  Q
  1.  ;