Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RARTE1

RARTE1.m

Go to the documentation of this file.
  1. RARTE1 ;HISC/CAH,FPT,GJC AISC/MJK,RMO-Edit/Delete a Report ; Aug 25, 2020@15:11:03
  1. ;;5.0;Radiology/Nuclear Medicine;**2,15,17,23,31,68,56,47,124,163,162,173**;Mar 16, 1998;Build 1
  1. ;Private IA #4793 DELETE^WVRALINK, CREATE^WVRALINK
  1. ;Supported IA #10035
  1. ;Supported IA #10007
  1. ;11/07/2005 KAM/BAY 110020 - Correct DUZ ID from Talk Technology
  1. ; During the Unverify process
  1. DEL D SET^RAPSET1 I $D(XQUIT) K XQUIT Q
  1. S (RAPRG74,RAXIT)=0
  1. S DIC("A")="Select Report Day-Case#: "
  1. S DIC("W")="S RA0=^(0) W "" "",$S($D(^DPT(+$P(RA0,""^"",2),0)):$P(^(0),""^""),1:""Unknown"") K RA0 W "" "",$$FLD^RARTFLDS(+Y,""PROC"")"
  1. S DIC("S")="I $P(^(0),U,5)'=""X""" ;select only non-deleted reports
  1. S DIC="^RARPT(",DIC(0)="AEMQZ" D ^DIC K DIC G END:Y<0
  1. S RA0=Y(0),(DA,RAIEN)=+Y
  1. I $O(^RARPT(RAIEN,2005,0)) D D END Q
  1. . W !!?5,"Cannot delete a report that is associated with an image."
  1. . W !?5,"Contact your Imaging Coordinator for further assistance.",!
  1. . S DIR(0)="E",DIR("A")="Press RETURN to continue"
  1. . D ^DIR K DIR,DIRUT,DUOUT
  1. . Q ;08/23/00
  1. D CHK17^RARTE3 ;see this subroutine for values of RAOK
  1. G:RAOK=1 END ;can't del rpt w/o RACN or RACNI so avoid err at UP1^RAUTL1
  1. S RAXIT=$$LOCK^RAUTL12("^RARPT(",RAIEN)
  1. I RAXIT K RAXIT D END Q ; record locked by another
  1. ASKDEL ; ask if deletion is appropriate
  1. R !!,"Do you wish to delete this report? NO// ",X:DTIME
  1. S:'$T!(X="")!(X["^") X="N"
  1. I "Nn"[$E(X) D UNLOCK^RAUTL12("^RARPT(",RAIEN) G DEL
  1. I "Yy"'[$E(X) D G ASKDEL
  1. . W:X'["?" $C(7)
  1. . W !!?3,"Enter 'YES' to delete this report, or 'NO' not to."
  1. . Q
  1. ; comment out next line, these 3 vars are already set by CHK17^RARTE3
  1. ;S RADFN=+$P(RA0,"^",2),RADTI=9999999.9999-$P(RA0,"^",3),RACN=$P(RA0,"^",4)
  1. G:RAOK=2 AD2 ;don't remove piece 17 if rpt doesn't match exm's rpt ptr
  1. ; del other member's REPORT TEXT xrefs, and set pointer to #74 as null
  1. D DEL17^RARTE2(RAIEN) ;del ptrs to file 74 excluding lead case of prtset
  1. S RACNI=$O(^RADPT(RADFN,"DT",RADTI,"P","B",RACN,0))
  1. G:'$D(^RADPT(RADFN,"DT",RADTI,"P",+RACNI,0))#2 AD2
  1. ; kill any xrefs for file #70's REPORT TEXT
  1. S DA(2)=RADFN,DA(1)=RADTI,DA=RACNI D ENKILL^RAXREF(70.03,17,RAIEN,.DA)
  1. ; set REPORT TEXT to null
  1. S $P(^RADPT(RADFN,"DT",RADTI,"P",+RACNI,0),"^",17)=""
  1. AD2 K RAXIT S RAPRG74=1 ;RAPRG74 used in kill logic file 74 fld .01
  1. D MARKDEL^RARTE7 ; mark report deleted, save DXs, remov DXs fm case(s)
  1. W !?10,"...report deletion complete."
  1. D:RAOK'=2 UP1^RAUTL1 ;skip update status if report doesn't belong to exm
  1. D UPDTPNT^RAUTL9(RAIEN) ; Update pointers in 74.2, and 74.4!
  1. D UNLOCK^RAUTL12("^RARPT(",RAIEN) ; unlock report
  1. I RAOK'=2,$T(DELETE^WVRALINK)]"" D DELETE^WVRALINK(RADFN,RADTI,RACNI) ; women's health, skip if report doesn't belong to exm
  1. END K %,%Y,D0,DA,DIC,DIE,RAJ1,DIK,RADFN,RADTI,RACN,RACNI,RA0,RAIEN,RAOR
  1. K RAORDIFN,RAPRG74,RASN,RASTI,Y ;KLM/163 - removed RADUZ from kill
  1. K RADATE,RADTE,X
  1. K RA791,RACANC,RACN0,RACPT,RACPTNDE,RAI,RAN,RAOBR4,RAPKG,RAPRCNDE,RAPROC,RAPROCIT,RAPRV,RASULT,RAXIT
  1. K C,D,D1,DDER,DDH,DFN,DI,DISYS,DIWF,DIWL,DIWR,DQ,DR,GMRAL,HLN,HLRESLT,HLSAN,I,VA,VADM,VAERR,X0
  1. Q
  1. ;
  1. UNVER(RAXRPT) ; unverify a report
  1. ; Input: if RAXRPT>0 then we know the report we wish to delete
  1. ; this requires no user interaction.
  1. ; RAXRPT=0 user is prompted for the report they wish to
  1. ; delete (interactive)
  1. ;
  1. I 'RAXRPT D SET^RAPSET1 G Q:$D(XQUIT)
  1. ;p173/KLM lookup on IEN should not be ambiguous.
  1. I RAXRPT N X S X="`"_RAXRPT
  1. S RAXIT=0,DIC="^RARPT(",DIC("S")="I $P(^(0),U,5)=""V"""
  1. S DIC(0)=$S('RAXRPT:"AEMQZ",1:"NZ")
  1. D DICW,^DIC K DIC I Y<0 D Q Q
  1. S RA74B4=$G(Y(0))
  1. S (RARPT,DA)=+Y,RADFN=$P(Y(0),U,2)
  1. S RADTI=9999999.9999-$P(Y(0),"^",3),RACN=$P(Y(0),"^",4)
  1. I 'RAXRPT S DR="D EN1^RAUTL9 I $D(DIRUT) S Y=""@99"";S:RASTATX'=""PD"" Y=""@10"";25;@10;5////^S X=RASTATX;S:X=""V"" Y=""@99"";9///@;17///@;100///NOW;@99"
  1. S:RAXRPT DR="5////^S X=""D"";9///@;17///@;100///NOW"
  1. ;11/07/2005 KAM/BAY 110020 Modified next line to look for voice recognition
  1. S DIE="^RARPT(",DR(2,74.01)="2////U;3////"_$S(($D(RAQUIET)#2)&($D(RASUB)#2):$G(^TMP("RARPT-REC",$J,RASUB,"RAVERF")),1:DUZ)
  1. S RAXIT=$$LOCK^RAUTL12("^RARPT(",RARPT)
  1. ;
  1. ;this check is to see if a report from the outside is to be amended $G(RAXRPT)>0
  1. I RAXIT S:$G(RAXRPT)>0 RAERR="^RARPT("_RARPT_", could not be locked for addendum." D Q QUIT
  1. ;if called from RAHLO1 and the lock fails we need to set RAERR
  1. ;RAERR is needed back in RAHLO1 p162
  1. ;
  1. D ^DIE K DE,DQ,DIE,DR D UNLOCK^RAUTL12("^RARPT(",RARPT)
  1. N RA1,RA2,RA3,RA4 S RA1=RADFN,RA2=RADTI,RA3=RACN,RA4=RARPT
  1. S RA(0)=$G(^RARPT(RARPT,0)),RA(5)=$P(^RARPT(RARPT,0),"^",5)
  1. S RA(7)=$P(^RARPT(RARPT,0),"^",7),RA(10)=$P(^RARPT(RARPT,0),"^",10)
  1. I RA(5)'="V" D
  1. . I RA(7)]"" D ENKILL^RAXREF(74,7,RA(7),RARPT) S $P(^RARPT(RARPT,0),"^",7)=""
  1. . I RA(10)]"" D ENKILL^RAXREF(74,10,RA(10),RARPT) S $P(^RARPT(RARPT,0),"^",10)=""
  1. . N RADDEN,RAUTOE S (RADDEN,RAUTOE)="" D ^RARTR,EN1^RARTE3(RA4)
  1. . Q
  1. S RADFN=RA1,RADTI=RA2,RACN=RA3,RARPT=RA4
  1. S RACNI=$O(^RADPT(RADFN,"DT",RADTI,"P","B",RACN,0)) I $D(^RADPT(RADFN,"DT",RADTI,"P",+RACNI,0)) D UP1^RAUTL1 I $D(^RABTCH(74.4,"B",RARPT)) D
  1. .S DA=0 F S DA=$O(^RABTCH(74.4,"B",RARPT,DA)) Q:'DA D
  1. ..S DIK="^RABTCH(74.4," D ^DIK
  1. ..Q
  1. .Q
  1. I "^V^EF^"'[("^"_$P($G(^RARPT(RARPT,0)),"^",5)_"^"),$T(DELETE^WVRALINK)]"" D DELETE^WVRALINK(RADFN,RADTI,RACNI) ; women's health
  1. ;
  1. Q ; Kill and quit
  1. K DFN,DI,DIW,DIWF,DIWI,DIWL,DIWT,DIWTC,DIWX,RAACNT,RANUM,RAST,RAWHOVER
  1. K %,%DT,%W,%Y,%Y1,C,D,D0,D1,DA,DIC,DIE,DIK,DR,RA,RACN,RACNI,RADATE
  1. K RADFN,RADIV,RADTE,RADTI,RAJ,RAOR,RAORDIFN,RARPT,RASET,RASN,RASTATX
  1. K RASTI,RAXIT,X,XQUIT,Y,RA74B4,DDH,DIPGM,DISYS,I ;KLM/163 - removed RADUZ from kill
  1. Q
  1. ;
  1. STD S (RALR,RALI)=1
  1. STD1 S DIC="^RA(74.1,",DIC("A")="Select 'Standard' Report to Copy: ",DIC(0)="AEMQ" D ^DIC K DIC("A") Q:Y<0
  1. ASKSEL W:$$IMPRPT(RARPT) !!,"Report already exists. This will over-write it."
  1. W !,"Are you sure you want the '",$P(Y,"^",2),"' standard report? No// " R X:DTIME G STD1:'$T!(X="")!(X["^")!("Nn"[$E(X))
  1. I "Yy"'[$E(X) W:X'["?" $C(7) W !!?3,"Enter 'YES' to select the '",$P(Y,"^",2),"' standard report, or 'NO' not to." G ASKSEL
  1. I RALR=1,RALI=1 K ^RARPT(RARPT,"R"),^("I")
  1. F I=1:1 Q:'$D(^RA(74.1,+Y,"R",I,0)) S ^RARPT(RARPT,"R",RALR,0)=^(0),RALR=RALR+1
  1. F I=1:1 Q:'$D(^RA(74.1,+Y,"I",I,0)) S ^RARPT(RARPT,"I",RALI,0)=^(0),RALI=RALI+1
  1. ASKADD R !!,"Do you want to add another standard to this report? No// ",X:DTIME Q:'$T!(X="")!(X["^")!("Nn"[$E(X)) I "Yy"'[$E(X) W:X'["?" $C(7) W !!?3,"Enter 'YES' to add another standard to this report, or 'NO' not to." G ASKADD
  1. S (^RARPT(RARPT,"R",RALR,0),^RARPT(RARPT,"I",RALI,0))="",RALR=RALR+1,RALI=RALI+1 W ! G STD1
  1. ;
  1. EDTRPT ; Called from 'RARTE4' and 'RARTVER'.
  1. N RAXIT S RACT=$S('+$G(^RARPT(RARPT,"T")):"I",1:"E")
  1. S:'$D(^RARPT(RARPT,"T")) ^("T")=""
  1. S DA=RARPT,DR="[RA REPORT EDIT]",DIE="^RARPT(" D ^DIE K DE,DQ ;,RAFLAGK
  1. I $D(Y),RACT="V",'$P(^RARPT(RARPT,0),"^",9) W !,$C(7),"You must enter a verifying Interpreting Physician to 'VERIFY' a report.",!?3,"...report status will now be changed to 'DRAFT'." S DA=RARPT,DR="5///D" D ^DIE K DE,DQ ;Q
  1. Q:$D(RAONLINE)&($G(RARDX)="E")
  1. ; move PACS line to its own subroutine
  1. ;I $D(RAFLAGK) K RAFLAGK Q
  1. G:$D(Y) PACS
  1. ;Since report editing is not necessarily screened by sign-on imaging
  1. ;type, use the imaging type on the exam record ;ch
  1. S RAIMGTYI=$P($G(^RADPT(RADFN,"DT",RADTI,0)),U,2),RAIMGTYJ=$P($G(^RA(79.2,+RAIMGTYI,0)),U)
  1. S X=+$O(^RA(72,"AA",RAIMGTYJ,9,0)),DA(2)=RADFN,DA(1)=RADTI,DA=RACNI,DIE="^RADPT("_DA(2)_",""DT"","_DA(1)_",""P""," K RAIMGTYI,RAIMGTYJ
  1. S DR=13_$S(RACT'="V":"",'$D(^RA(72,X,.1)):"",$P(^(.1),"^",5)'="Y":"",1:"R")_";I $D(^RA(78.3,+X,0)),$P(^(0),""^"",4)=""y"" S RAAB=1"
  1. ;
  1. ;lock the correct sub-file (pset?)
  1. D DXLOC
  1. ;
  1. I RACT="V",$P($G(^RA(72,X,.1)),"^",5)="Y" S DIE("NO^")="BACK"
  1. I 'RAXIT D ^DIE K DA,DE,DQ,DIE,DR
  1. I RAXIT!($P(^RADPT(RADFN,"DT",RADTI,"P",RACNI,0),U,13)="")!($D(Y)) D DXULOC G PACS
  1. S DR="50///"_RACN
  1. S DR(2,70.03)=13.1
  1. S DR(3,70.14)=.01_";I $D(^RA(78.3,+X,0)),$P(^(0),""^"",4)=""y"" S RAAB=1"
  1. S DA(1)=RADFN,DA=RADTI,DIE="^RADPT("_DA(1)_",""DT"","
  1. ;
  1. I 'RAXIT D ^DIE K DA,DE,DQ,DIE,DR
  1. ;
  1. COPYDX ;if we have a printset copy over the Dx code data (both primary & secondary)
  1. ;to all our descendents before building our HL7 ORU messsages.
  1. I RAPRTSET S RADRS=1,RAXIT=0 D COPY^RARTE2 ;P47
  1. ;unlock the correct sub-file (pset?)
  1. D DXULOC
  1. ;
  1. PACS I ($P(^RARPT(RARPT,0),U,5)="V")!($P(^(0),U,5)="R") D RPT^RAHLRPC
  1. ;pre p124: "^V^EF" post p124 "^V^EF^"
  1. I "^V^EF^"[("^"_$P(^RARPT(RARPT,0),U,5)_"^"),$T(CREATE^WVRALINK)]"" D CREATE^WVRALINK(RADFN,RADTI,RACNI) ; women's health
  1. Q
  1. ;
  1. ASKBTCH R !!,"Do you want to batch print reports? Yes// ",X:DTIME S:'$T X="^" S:X="" X="Y" Q:X["^" I "Nn"'[$E(X),"Yy"'[$E(X) W:X'["?" $C(7) W !!?3,"Enter 'YES' to batch print reports, or 'NO' not to." G ASKBTCH
  1. Q
  1. ;
  1. ASKPRT R !!,"Do you want to print batch now? No// ",X:DTIME S:'$T!(X="")!(X["^") X="N" I "Nn"'[$E(X),"Yy"'[$E(X) W:X'["?" $C(7) W !!?3,"Enter 'YES' to print this batch, or 'NO' not to." G ASKPRT
  1. Q
  1. DICW ; Build DIC("W") string
  1. N DO D DO^DIC1
  1. S DIC("W")=$S($G(DIC("W"))]"":DIC("W")_" ",1:"")_"W "" "",$$FLD^RARTFLDS(+Y,""PROC"")"
  1. Q
  1. IMPRPT(Y) ; Does the report we are currently editing have either Report
  1. ; or Impression Text?
  1. ; Input : 'Y' - the ien of the report being edited
  1. ; Output: '1' - either impression or report text exists, '0' - neither
  1. ; report or impression text exists.
  1. Q $S(+$O(^RARPT(Y,"I",0)):1,+$O(^RARPT(Y,"R",0)):1,1:0)
  1. ;
  1. DXLOC ;lock the correct RAD/NUC MED PATIENT sub-file
  1. S:'RAPRTSET RAXIT=$$LOCK^RAUTL12("^RADPT("_RADFN_",""DT"","_RADTI_",""P"",",RACNI)
  1. S:RAPRTSET RAXIT=$$LOCK^RAUTL12("^RADPT("_RADFN_",""DT"",",RADTI)
  1. Q
  1. ;
  1. DXULOC ;unlock the correct RAD/NUC MED PATIENT sub-file
  1. D:'RAPRTSET UNLOCK^RAUTL12("^RADPT("_RADFN_",""DT"","_RADTI_",""P"",",RACNI)
  1. D:RAPRTSET UNLOCK^RAUTL12("^RADPT("_RADFN_",""DT"",",RADTI)
  1. Q
  1. ;