Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RCDPENER

RCDPENER.m

Go to the documentation of this file. 
  1. RCDPENER ;AITC/CJE - NEGATIVE ERA LINE REPORT ;Dec 20, 2014@18:42
  1.  ;;4.5;Accounts Receivable;**424**;Mar 20, 1995;Build 11
  1.  ;Per VA Directive 6402, this routine should not be modified.
  1.  ;Read ^DGCR(399) via Private IA 3820
  1.  ;Read ^DG(40.8) via Controlled IA 417
  1.  ;Read ^IBM(361.1) via Private IA 4051
  1.  ;Use DIVISION^VAUTOMA via Controlled IA 664
  1. RPT ; entry point for Negative ERA Line Report [RCDPE NEGATIVE ERA LINE REPORT]
  1.  N POP,RCDISP,RCDIV,RCDIVS,RCDTRNG,RCJOB,RCLAIM,RCPAGE,RCPAR,RCPARRAY,RCPAY,RCPROG,RCRANGE
  1.  N RCSORT,RCWHICH,STANAM,STANUM,X,Y
  1.  S (RCDTRNG,RCPAGE)=0,RCPROG="RCDPENER",RCJOB=$J    ; Initialize page and start point
  1.  S RCDIV=$$STADIV^RCDPEAPP(.RCDIVS) Q:RCDIV=-1      ; Select Filter/Sort by Division
  1.  ;
  1.  S RCLAIM=$$RTYPE^RCDPEU1() Q:RCLAIM=-1             ; Tricare filter to Med/Pharm/Both
  1.  S RCWHICH=$$NMORTIN^RCDPEAPP() Q:RCWHICH=-1        ; Filter by Payer Name or TIN
  1.  ;
  1.  S RCPAR("SELC")=$$PAYRNG^RCDPEU1(0,1,RCWHICH)      ; Selected or Range of Payers
  1.  Q:RCPAR("SELC")=-1                                 ; '^' or timeout
  1.  S RCPAY=RCPAR("SELC")
  1.  ;
  1.  I RCPAR("SELC")'="A" D  Q:XX=-1                    ; Since we don't want all payers 
  1.  . S RCPAR("TYPE")=RCLAIM
  1.  . S RCPAR("SRCH")=$S(RCWHICH=2:"T",1:"N")          ; prompt for payers we do want
  1.  . S RCPAR("FILE")=344.4
  1.  . S RCPAR("DICA")="Select Insurance Company"_$S(RCWHICH=1:" NAME: ",1:" TIN: ")
  1.  . S XX=$$SELPAY^RCDPEU1(.RCPAR)
  1.  ;
  1.  S RCSORT=$$SORTT^RCDPEAPP() Q:RCSORT=-1            ; Select Sort
  1.  S RCRANGE=$$DTRNG() Q:RCRANGE=0                    ; Select Date Range for Report
  1.  S RCDISP=$$DISPTY^RCDPEAPP() Q:RCDISP=-1           ; Output to Excel?
  1.  I RCDISP D INFO^RCDPEM6                            ; Display capture information for Excel
  1.  ;
  1.  I 'RCDISP W !,"This report requires 132 column display."
  1.  S %ZIS="QM" D ^%ZIS Q:POP                          ; Select output device
  1.  ;
  1.  ; Option to queue
  1.  I 'RCDISP,$D(IO("Q")) D  Q
  1.  . N ZTDESC,ZTQUEUED,ZTRTN,ZTSAVE,ZTSK
  1.  . S ZTRTN="REPORT^RCDPENER"
  1.  . S ZTDESC="EDI LOCKBOX NEGATIVE ERA LINE REPORT"
  1.  . S ZTSAVE("RC*")="" ;**FA** ,ZTSAVE("VAUTD")=""
  1.  . S ZTSAVE("^TMP(""RCDPEU1"",$J,")="" ;
  1.  . D ^%ZTLOAD
  1.  . I $D(ZTSK) W !!,"Task number "_ZTSK_" was queued."
  1.  . E  W !!,"Unable to queue this job."
  1.  . K IO("Q")
  1.  . D HOME^%ZIS
  1.  ;
  1.  D REPORT                                           ; Compile and print report
  1.  Q
  1. REPORT ; Compile and print report
  1.  ; Input:   RCDISP  - 0 - Output to paper or screen, 1 - Output to Excel
  1.  ;          RCDIV   - 1 - All divisions, 2 - Selected divisions
  1.  ;          RCDIVS()- Array of selected divisions if RCDIV=2
  1.  ;          RCRANGE - 1^Start Date^End Date
  1.  ;          RCJOB   - $J
  1.  ;          RCLAIM  - "M" - Medical Claims, "P" - Pharmacy Claims, "B" - Both
  1.  ;          RCPAGE  - Initialized to 0
  1.  ;          RCPARRAY- Array of selected payers 
  1.  ;          RCPROG  - "RCDPENER"
  1.  ;          RCSORT  - 0 - Sort by Payer Name, 1 - Sort by Payer TIN
  1.  ;          RCWHICH - 1 - Filter by Payer Name, 2 - Filter by Payer TIN
  1.  ;          ^TMP("RCDPEU1",$J) - Selected payerers (see SELPAY^RCDPEU1 for details)
  1.  ;
  1.  N GLOB,GTOTAL,ZTREQ
  1.  K ^TMP(RCPROG,$J),^TMP("RCDPEAPP2",$J)
  1.  S GLOB=$NA(^TMP(RCPROG,$J))
  1.  D COMPILE^RCDPENE1                         ; Scan ERA file for entries in date range
  1.  D DISP                                     ; Display the Report
  1.  ;
  1.  ; Clear ^TMP global
  1.  K ^TMP(RCPROG,$J),^TMP("RCSELPAY",RCJOB),^TMP("RCDPEAPP2",$J),^TMP("RCDPEU1",$J)
  1.  Q
  1.  ;
  1. DISP ; Format the display for screen/printer or MS Excel
  1.  ; Input:   GLOB    - ^TMP("RCDPENER",$J) (See SAVE^RCDPENE1 for field order)
  1.  ;          RCDISP  - 1 - Output to Excel, 0 otherwise
  1.  ;          RCDIV   - 1 - All Divisions selected
  1.  ;          RCDIVS  - Array of selected Divisions (if all not selected)
  1.  ;          RCPARRAY- Array of selected Payers
  1.  ;          RCPAY   - 1 - All Payers selected
  1.  N DIVS,LINE1,LINE2,PAYERS,RCDATA,RCHDRDT,RCSTOP,SPACES,SUB,SUB1,SUB2,SUB3
  1.  S RCHDRDT=$$FMTE^XLFDT($$NOW^XLFDT,"2SZ")       ; Date/time for header
  1.  S LINE1=$TR($J("",131)," ","-"),LINE2=$TR(LINE1,"-","=")
  1.  U IO
  1.  ;
  1.  ; Report by division or 'ALL'
  1.  D LINED^RCDPEAPP(RCDIV,.RCDIVS,.DIVS)                   ; Format Division filter
  1.  D LINEP^RCDPEAPP(RCPAY,.RCPARRAY,RCWHICH,.PAYERS)       ; Format Payer filter
  1.  S SPACES="                    "
  1.  S SUB="",RCSTOP=0
  1.  I RCDISP D HDR(.DIVS,.PAYERS)                           ; Single header for Excel
  1.  F  S SUB=$O(@GLOB@(SUB)) Q:SUB=""  D  Q:RCSTOP  ;
  1.  . I 'RCDISP D
  1.  . . D HDR(.DIVS,.PAYERS)                        ; Display Header
  1.  . . W !,"DIVISION: ",SUB
  1.  . S SUB1=""                                    ; Division
  1.  . F  S SUB1=$O(@GLOB@(SUB,SUB1)) Q:SUB1=""  D  Q:RCSTOP
  1.  . . S SUB2=""
  1.  . . F  S SUB2=$O(@GLOB@(SUB,SUB1,SUB2)) Q:SUB2=""  D  Q:RCSTOP
  1.  . . . ;
  1.  . . . ; Display payer sub-header
  1.  . . . I 'RCDISP D HDRP^RCDPEAPP(SUB1_"/"_SUB2)
  1.  . . . S SUB3=""
  1.  . . . F  S SUB3=$O(@GLOB@(SUB,SUB1,SUB2,SUB3)) Q:SUB3=""  D  Q:RCSTOP
  1.  . . . . S RCDATA=@GLOB@(SUB,SUB1,SUB2,SUB3)
  1.  . . . . I 'RCDISP D  Q:RCSTOP
  1.  . . . . . I $Y>(IOSL-6) D HDR(.DIVS,.PAYERS) Q:RCSTOP
  1.  . . . . . W !,$P(RCDATA,U,4)                          ; Patient Name
  1.  . . . . . W ?30,$P(RCDATA,U,5)                        ; ERA#
  1.  . . . . . W ?37,$P(RCDATA,U,6)                        ; Date Received
  1.  . . . . . W ?48,$E($P(RCDATA,U,7),1,12)               ; Bill #
  1.  . . . . . W ?57,$J($P(RCDATA,U,12),8)_"  "            ; Date of Service
  1.  . . . . . W $J($P(RCDATA,U,8),11,2)_"      "         ; Paid Amount
  1.  . . . . . W $E($E($P(RCDATA,U,10),1,11)_SPACES,1,13)  ; Claim Status
  1.  . . . . . W $J($P(RCDATA,U,9),15,2)                   ; Claim Balance
  1.  . . . . . W !,?3,"Trace #: ",$P(RCDATA,U,11)          ; Trace #
  1.  . . . . . ;
  1.  . . . . I RCDISP D
  1.  . . . . . I $L(RCDATA)>255 D  ;
  1.  . . . . . . N RCPAY,RCTIN
  1.  . . . . . . S RCPAY=$P(RCDATA,"^",3)
  1.  . . . . . . S RCTIN=$P(RCPAY,"/",$S(RCSORT=0:2,1:1))
  1.  . . . . . . S RCPAY=$P(RCPAY,"/",$S(RCSORT=0:1,1:2))
  1.  . . . . . . S RCPAY=$E(RCPAY,1,$L(RCPAY)-($L(RCDATA)-255))
  1.  . . . . . . S RCPAY=$S(RCSORT=0:RCPAY_"/"_RCTIN,1:RCTIN_"/"_RCPAY)
  1.  . . . . . . S $P(RCDATA,"^",3)=RCPAY
  1.  . . . . . W !,RCDATA
  1.  . . . ;
  1.  ;
  1.  I '$D(@GLOB) D  ;
  1.  . I 'RCDISP D HDR(.DIVS,.PAYERS)
  1.  . W !!,"*** NO DATA FOUND FOR THIS DATE RANGE AND FILTER CONDITIONS ***",!!
  1.  ;
  1.  I 'RCSTOP D ASK^RCDPEAPP(.RCSTOP)
  1.  ;
  1.  ; Close device
  1.  I '$D(ZTQUEUED) D ^%ZISC
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  Q
  1.  ;
  1. HDR(DIVS,PAYERS) ; Print the report header
  1.  ; Input:   DIVS()      - Array of selected Division lines for Header
  1.  ;          PAYERS()    - Array of selected Payer lines for Header
  1.  ;          RCDISP      - 1 - Output to Excel, 0 otherwise
  1.  ;          RCHDRDT     - External Print Date/Tim
  1.  ;          RCPAGE      - Current Page number
  1.  ;          RCRANGE     - Selected Date Range
  1.  ;          RCSORT      - 0 - Sort by Payer Name, 1 - Sort by Payer TIN
  1.  ;          RCSTOP      - 1 if display aborted
  1.  ; Output:  RCPAGE      - Updated Page Number
  1.  ;          RCSTOP      - 1 if display aborted
  1.  N END,LN,MSG,START,XX,Y
  1.  Q:RCSTOP
  1.  I RCDISP D  Q          ; Output to Excel
  1.  . S XX="STATION^STATION NUMBER^PAYER^PATIENT NAME/SSN^ERA#^DT REC'D"
  1.  . S XX=XX_"^BILL#^AMT PAID^CLAIM BALANCE^CLAIM STATUS^TRACE#^DOS"
  1.  . W !,XX
  1.  S START=$$FMTE^XLFDT($P(RCRANGE,U,2),"2DZ")
  1.  S END=$$FMTE^XLFDT($P(RCRANGE,U,3),"2DZ")
  1.  I RCPAGE D ASK^RCDPEAPP(.RCSTOP) Q:RCSTOP
  1.  S RCPAGE=RCPAGE+1
  1.  W @IOF
  1.  S MSG(1)="EDI LOCKBOX NEGATIVE ERA LINE REPORT"
  1.  S MSG(1)=MSG(1)_$J("",47)_"Print Date: "_RCHDRDT_"    Page: "_RCPAGE
  1.  ;
  1.  S LN=2,XX=""
  1.  F  D  Q:XX=""                              ; Display Division filters
  1.  . S XX=$O(DIVS(XX))
  1.  . Q:XX=""
  1.  . S MSG(LN)=DIVS(XX),LN=LN+1
  1.  ;
  1.  S MSG(LN)="CLAIM TYPE: "
  1.  S MSG(LN)=MSG(LN)_$S(RCLAIM="P":"PHARMACY",RCLAIM="M":"MEDICAL",RCLAIM="T":"TRICARE",1:"ALL")
  1.  S MSG(LN)=MSG(LN)_$J("",55-$L(MSG(LN)))_"SORTED BY: "_$S(RCSORT=0:"PAYER NAME",1:"PAYER TIN")
  1.  S LN=LN+1
  1.  S MSG(LN)=$S(RCWHICH=2:"TINS",1:"PAYERS")_" : "_$S(RCPAY="S":"SELECTED",RCPAY="R":"RANGE",1:"ALL")
  1.  S LN=LN+1
  1.  S MSG(LN)="RESULTS FOR ERA FILED DATE RANGE: "_START_" - "_END
  1.  S LN=LN+1,MSG(LN)=LINE2
  1.  S LN=LN+1
  1.  S MSG(LN)="PATIENT NAME/SSN               ERA#   DT REC'D   BILL#     DOS          AMOUNT      BILL STATUS  CURRENT BALANCE"
  1.  S LN=LN+1,MSG(LN)=LINE2
  1.  D EN^DDIOL(.MSG)
  1.  Q
  1.  ;
  1. DTRNG() ; Get the date range for the report
  1.  ; Input:   None
  1.  ; Returns: 0 - User ^ or timed out
  1.  ;          1^Start Date^End Date
  1.  N DIR,DIROUT,DIRUT,DTOUT,DUOUT,RCEND,RNGFLG,RCSTART,X,Y
  1.  D DATES(.RCSTART,.RCEND)
  1.  Q:RCSTART=-1 0
  1.  Q:RCSTART "1^"_RCSTART_"^"_RCEND
  1.  Q:'RCSTART "0^^"
  1.  Q 0
  1.  ;
  1. DATES(BDATE,EDATE) ; Get a date range.
  1.  ; Input:   None
  1.  ; Output:  BDATE   - Internal Begin date
  1.  ;          EDATE   - Internal End date
  1.  N DIR,DIROUT,DIRUT,DTOUT,DUOUT,X,Y
  1.  S (BDATE,EDATE)=0
  1.  S DIR("?")="Enter the earliest ERA file date date to include on the report"
  1.  S DIR(0)="DAO^:"_DT_":APE",DIR("A")="Start Date: "
  1.  D ^DIR K DIR
  1.  I $D(DTOUT)!$D(DUOUT)!(Y="") S BDATE=-1 Q
  1.  S BDATE=Y
  1.  S DIR("?")="Enter the latest ERA file date date to include on the report"
  1.  S DIR("B")=Y(0)
  1.  S DIR(0)="DAO^"_BDATE_":"_DT_":APE",DIR("A")="End Date: "
  1.  D ^DIR K DIR
  1.  I $D(DTOUT)!$D(DUOUT)!(Y="") S BDATE=-1 Q
  1.  S EDATE=Y
  1.  Q