Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RCDPESPC

RCDPESPC.m

Go to the documentation of this file. 
  1. RCDPESPC ;AITC/MBS - ePayment Lockbox Site Parameter Reports ; 4/23/19 8:52am
  1.  ;;4.5;Accounts Receivable;**349,424**;Mar 20, 1995;Build 11
  1.  ;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1.  Q
  1.  ;
  1. APOST(AUPSTYP,ONOFF) ;EP from RCDPESP Turn Auto-Posting On/Off for Medical,RX,TRICARE Claims
  1.  ; PRCA*4.5*345
  1.  ; PRCA*4.5*424 Moved from RCDPESP because of routine size 
  1.  ; Input: AUPSTYP - 0 - Medical Auto-Posting
  1.  ;                  1 - Pharmacy Auto-Posting
  1.  ;                  2 - TRICARE Auto-Posting
  1.  ;                  3 - Zero Pay Auto-Posting   ;*PRCA*4.5.424 Added line
  1.  ; Output: ONOFF passed by ref. 1 - Auto-Posting, 0 otherwise
  1.  ; Returns: 1 - User '^' or timed out, 0 otherwise
  1.  N APCT,DIR,DIROUT,DIRUT,DTOUT,DUOUT,FLD,FDAEDI,RCAUDVAL
  1.  S FLD=$S(AUPSTYP=0:.02,AUPSTYP=1:1.01,AUPSTYP=2:1.05,1:1.11) ; PRCA*4.5*349 - Add TRICARE, PRCA*4.5*424 - Add ZERO PAY
  1.  S APCT=$$GET1^DIQ(344.61,"1,",FLD,"I")
  1.  S DIR(0)="YA",DIR("B")=$S((APCT=1)!(APCT=""):"Yes",1:"No")
  1.  S DIR("A")=$$PADPRMPT^RCDPESPB($$GET1^DID(344.61,FLD,,"TITLE"))
  1.  S DIR("?")=$$GET1^DID(344.61,FLD,,"HELP-PROMPT")
  1.  D ^DIR
  1.  I $D(DTOUT)!$D(DUOUT) Q 1
  1.  S ONOFF=Y
  1.  I APCT'=Y D  ; User updated value
  1.  . S FDAEDI(344.61,"1,",FLD)=Y
  1.  . D FILE^DIE(,"FDAEDI")
  1.  . ;
  1.  . ; Changed D NOTIFY to D NOTIFY^RCDPESP
  1.  . D NOTIFY^RCDPESP(Y,AUPSTYP)
  1.  . S RCAUDVAL(1)="344.61^"_FLD_"^1^"_Y_U_APCT
  1.  . ;
  1.  . ; Changed D AUDIT to D AUDIT^RCDPESP
  1.  . D AUDIT^RCDPESP(.RCAUDVAL)
  1.  Q 0
  1.  ; PRCA*4.5*349 - New subroutine to display parameter settings by category
  1. SPRPT ; EP from RCDPESP1
  1.  ; Site parameter report entry point updated to select categories
  1.  ; Input: RCTYPE - Type of report (Medical/Rx/TRICARE/All)
  1.  ;        RCCATS - List of categories selected for report
  1.  ; RCLSTMGR - 1 if user selected to display report in List Manager
  1.  ; RCNTR - counter
  1.  ; RCFLD - DD field number
  1.  ; RCHDR - header information
  1.  ; RCPARM - parameters
  1.  ; RCSTOP - exit flag
  1.  N CATS,J,LN,NUMCATS,RCACTV,RCCARCD,RCCIEN,RCCODE,RCDATA,RCDESC,RCFLD,RCGLB,RCHDR,RCI,RCITEM,RCNTR,RCPARM,RCSTAT,RCSTOP,RCSTRING,V,X,XX,Y
  1.  ;
  1.  S X="RC" F  S X=$O(^TMP($J,X)) Q:'($E(X,1,2)="RC")  K ^TMP($J,X) ; clear out old data
  1.  ;
  1.  S NUMCATS=$L(RCCATS,U)
  1.  S RCCATS=$$SRTCATS(RCCATS)
  1.  ;
  1.  ; RCGLB - ^TMP global storage locations
  1.  ; ^TMP($J,"RC342") - AR SITE PARAMETER file (#342)
  1.  ; ^TMP($J,"RC344.6") - RCDPE AUTO-PAY EXCLUSION file (#344.6)
  1.  ; ^TMP($J,"RC344.61") - RCDPE PARAMETER file (#344.61)
  1.  F J=342,344.6,344.61 S RCGLB(J)=$NA(^TMP($J,"RC"_J)) K @RCGLB(J)
  1.  ;
  1.  S RCHDR("RUNDATE")=$$FMTE^XLFDT($$NOW^XLFDT,"10S")
  1.  S RCHDR("PGNMBR")=0  ; page number
  1.  ;
  1.  ; AR SITE PARAMETER file (#342)
  1.  D GETS^DIQ(342,"1,",".01;.14;.15;7.02;7.03;7.04;7.05;7.06;7.07;7.08;7.09","E",RCGLB(342)) ; PRCA*4.5*345
  1.  ; RCDPE PARAMETER file (#344.61),  *future build*, add Tricare auto-decrease fields
  1.  S Y=".02;.03;.04;.05;.06;.07;.1;.11;.12;.13;1.01;1.02;1.03;1.04"  ; PRCA*4.5*345
  1.  S Y=Y_";1.05;1.06;1.07;1.08;1.09;1.1"  ; PRCA*4.5*349 - Add TRICARE
  1.  S Y=Y_";1.11"                          ; PRCA*4.5*424 - Add Zero Pay Auto Post parameter
  1.  D GETS^DIQ(344.61,"1,",Y,"E",RCGLB(344.61)) ; PRCA*4.5*321/PRCA*4.5*326/PRCA*4.5*332
  1.  ; add site to header data
  1.  S RCHDR("SITE")="Site: "_@RCGLB(342)@(342,"1,",.01,"E")
  1.  ;
  1.  ; get auto-post and auto-decrease settings, save zero node
  1.  S X=$G(^RCY(344.61,1,0))
  1.  S XX=$G(^RCY(344.61,1,1))                      ; PRCA*4.5*349 - Added line
  1.  S RCPARM("AUTO-POST")=$P(X,U,2)
  1.  S RCPARM("AUTO-DECREASE")=$P(X,U,3)
  1.  S RCPARM(344.61,0)=X
  1.  S RCPARM(344.61,1)=XX                          ; PRCA*4.5*349 - Added line
  1.  S RCPARM("RX AUTO-POST")=$P(XX,U,1)
  1.  S RCPARM("RX AUTO-DECREASE")=$P(XX,U,2)        ; PRCA*4.5*349 - Added line
  1.  S RCPARM("TRI AUTO-POST")=$P(XX,U,5)           ; PRCA*4.5*349 - Added line
  1.  S RCPARM("TRI AUTO-DECREASE")=$P(XX,U,6)       ; PRCA*4.5*349 - Added line
  1.  ;
  1.  ; Display categories in order selected
  1.  F I=1:1:NUMCATS D
  1.  . S LN="RPT"_$P(RCCATS,U,I) D @LN
  1.  ;
  1.  D AD2RPT^RCDPESP1(" "),AD2RPT^RCDPESP1($$ENDORPRT^RCDPEARL)
  1.  ;
  1.  I $G(RCLSTMGR) Q  ; PRCA*4.5*349 - If displaying as ListMan report, return here and let ListMan handle it
  1.  ;
  1.  S RCSTOP=0 U IO D SPHDR^RCDPESP1(.RCHDR)
  1.  S J=0 F  S J=$O(^TMP($J,"RC SP REPORT",J)) Q:'J!RCSTOP  S Y=^TMP($J,"RC SP REPORT",J,0) D
  1.  . I $E(Y,1)=$C(12),J>1 D ASK^RCDPEARL(.RCSTOP) I 'RCSTOP D SPHDR^RCDPESP1(.RCHDR) S Y=$E(Y,2,$L(Y))
  1.  . W !,Y Q:'$O(^TMP($J,"RC SP REPORT",J))  ; quit if last line
  1.  . I '$G(ZTSK),$E(IOST,1,2)="C-",$Y+3>IOSL D ASK^RCDPEARL(.RCSTOP) I 'RCSTOP D SPHDR^RCDPESP1(.RCHDR) Q
  1.  . Q:RCSTOP  Q:$Y+2<IOSL
  1.  . D SPHDR^RCDPESP1(.RCHDR)
  1.  ;
  1.  I '$G(ZTSK),$E(IOST,1,2)="C-",'RCSTOP D ASK^RCDPEARL(.RCSTOP)
  1.  ;
  1.  ; close device
  1.  U IO(0) D ^%ZISC
  1.  K @RCGLB(344.6)  ; delete old data
  1.  S X="RC" F  S X=$O(^TMP($J,X)) Q:'($E(X,1,2)="RC")  K ^TMP($J,X) ; clean up
  1.  ;
  1.  Q
  1.  ;
  1. RPTGN ; Display General EDI Lockbox Site Parameters
  1.  D AD2RPT^RCDPESP1($C(12)_"### General EDI Lockbox Site Parameters ###")
  1.  ; 7.02:7.04 - EFT/ERA days unmatched
  1.  F RCFLD=7.02,7.03,7.04 D
  1.  . S Y=$$GET1^DID(342,RCFLD,,"LABEL")_": "_@RCGLB(342)@(342,"1,",RCFLD,"E")
  1.  . D AD2RPT^RCDPESP1(Y)
  1.  ;Workload notification day parameter
  1.  S Y=$$GET1^DID(344.61,.1,,"LABEL")_": "_@RCGLB(344.61)@(344.61,"1,",.1,"E") ; PRCA*4.5*321
  1.  D AD2RPT^RCDPESP1(Y)
  1.  Q
  1.  ;
  1. RPTFP ; Display First Party Parameters
  1.  D AD2RPT^RCDPESP1($C(12)_"### First Party Parameters ###")
  1.  ; .14:.15 - First Party
  1.  F RCFLD=.14,.15 D
  1.  . S Y=$$GET1^DID(342,RCFLD,,"TITLE")_": "_@RCGLB(342)@(342,"1,",RCFLD,"E")
  1.  . D AD2RPT^RCDPESP1(Y)
  1.  Q
  1.  ;
  1. RPTAA ; Display Auto-Audit Parameters
  1.  D AD2RPT^RCDPESP1($C(12)_"### Auto-Audit Site Parameters ###")
  1.  ; 7.05:7.09 - Auto Audit
  1.  F RCFLD=7.05,7.06,7.07,7.08,7.09 D  ; EFT and ERA days unmatched  - PRCA*4.5*321
  1.  . I RCTYPE="P",(RCFLD=7.05)!(RCFLD=7.07)!(RCFLD=7.09) Q  ; PRCA*4.5*349 Exclude TRICARE
  1.  . I RCTYPE="M",(RCFLD=7.06)!(RCFLD=7.08)!(RCFLD=7.09) Q  ; PRCA*4.5*349 Exclude TRICARE
  1.  . I RCTYPE="T",RCFLD>7.04,RCFLD<7.09 Q  ; PRCA*4.5*349 Line Added TRICARE
  1.  . S Y=$$GET1^DID(342,RCFLD,,"TITLE")_": "_@RCGLB(342)@(342,"1,",RCFLD,"E")
  1.  . I RCFLD=7.05 D AD2RPT^RCDPESP1(" ")
  1.  . I (RCFLD=7.06)&(RCTYPE="P") D AD2RPT^RCDPESP1(" ")
  1.  . I (RCFLD=7.09),(RCTYPE="T") D AD2RPT^RCDPESP1(" ")
  1.  . D AD2RPT^RCDPESP1(Y)
  1.  Q
  1.  ;
  1. RPTAP ; Display Auto-Post Parameters
  1.  D AD2RPT^RCDPESP1($C(12)_"### Auto-Post Parameters ###")
  1.  I (RCTYPE="M")!(RCTYPE="A") D
  1.  . D AD2RPT^RCDPESP1("*** Medical Auto-Post Parameters ***")
  1.  . D MEDAUTOP^RCDPESP1(.RCPARM)  ; Display Medical Claim parameters
  1.  ;
  1.  I (RCTYPE="P")!(RCTYPE="A") D
  1.  . D AD2RPT^RCDPESP1("*** Pharmacy Auto-Post Parameters ***")
  1.  . D RXAUTOP^RCDPESP1(.RCPARM) ; Display Rx parameters 
  1.  ;
  1.  I (RCTYPE="T")!(RCTYPE="A") D
  1.  . D AD2RPT^RCDPESP1("*** TRICARE Auto-Post Parameters ***")
  1.  . D TRIAUTOP^RCDPESP1(.RCPARM)  ; Display TRICARE parameters
  1.  ;
  1.  D ZPARAMS ; Display Zero Pay Auto=Post Parameter PRCA*4.5*424
  1.  Q
  1.  ;
  1. RPTAD ; Auto-Decrease Parameteers
  1.  D AD2RPT^RCDPESP1($C(12)_"### Auto-Decrease Parameters ###")
  1.  I (RCTYPE="M")!(RCTYPE="A") D
  1.  . D AD2RPT^RCDPESP1("*** Medical Auto-Decrease Parameters ***")
  1.  . I '$$AUTOPON(0) D  Q
  1.  . . D AD2RPT^RCDPESP1(" ")
  1.  . . D AD2RPT^RCDPESP1("NOTICE: Medical Auto-Decrease unavailable because Auto-Posting of Medical Claims is currently disabled")
  1.  . . D AD2RPT^RCDPESP1(" ")
  1.  . D MEDAUTOD^RCDPESP1(.RCPARM,RCTYPE)  ; Display Medical Claim parameters
  1.  ;
  1.  I (RCTYPE="P")!(RCTYPE="A") D
  1.  . D AD2RPT^RCDPESP1("*** Pharmacy Auto-Decrease Parameters ***")
  1.  . I '$$AUTOPON(1) D  Q
  1.  . . D AD2RPT^RCDPESP1(" ")
  1.  . . D AD2RPT^RCDPESP1("NOTICE: Pharmacy Auto-Decrease unavailable because Auto-Posting of Pharmacy Claims is currently disabled")
  1.  . . D AD2RPT^RCDPESP1(" ")
  1.  . D RXAUTOD^RCDPESP1(.RCPARM,RCTYPE) ; Display Rx parameters 
  1.  ;
  1.  I (RCTYPE="T")!(RCTYPE="A") D
  1.  . D AD2RPT^RCDPESP1("*** TRICARE Auto-Decrease Parameters ***")
  1.  . I '$$AUTOPON(2) D  Q
  1.  . . D AD2RPT^RCDPESP1(" ")
  1.  . . D AD2RPT^RCDPESP1("NOTICE: TRICARE Auto-Decrease unavailable because Auto-Posting of TRICARE Claims is currently disabled")
  1.  . . D AD2RPT^RCDPESP1(" ")
  1.  . D TRIAUTOD^RCDPESP1(.RCPARM,RCTYPE)  ; Display TRICARE parameters ; RCDPE PARAMETER file (#344.61)
  1.  Q
  1.  ;
  1. RPTLK ; Display EFT Lock-Out Parameters
  1.  D AD2RPT^RCDPESP1($C(12)_"### EFT Lock-Out Parameters ###")
  1.  ;  ^DD(344.61,.06,0) > "MEDICAL EFT POST PREVENT DAYS"
  1.  ;  ^DD(344.61,.07,0) > "PHARMACY EFT POST PREVENT DAYS"
  1.  ;  ^DD(344.61,.13,0) > "TRICARE EFT POST PREVENT DAYS"
  1.  F RCFLD=.06,.07,.13 D 
  1.  . Q:(RCFLD=.06)&'((RCTYPE="M")!(RCTYPE="A"))  ; Don't display if not showing Medical parameters
  1.  . Q:(RCFLD=.07)&'((RCTYPE="P")!(RCTYPE="A"))   ; Don't display if not showing Rx parameters
  1.  . Q:(RCFLD=.13)&'((RCTYPE="T")!(RCTYPE="A"))  ; PRCA*4.5*349 - Don't display if not showing TRICARE params
  1.  . S Y=$$GET1^DID(344.61,RCFLD,,"TITLE")_" "_@RCGLB(344.61)@(344.61,"1,",RCFLD,"E")
  1.  . D AD2RPT^RCDPESP1(Y)
  1.  Q
  1.  ;
  1.  ; PRCA*4.5*424 Added Subroutine ZPARAMS
  1. ZPARAMS ; Display Zero Pay Auto-Post Parameters for Report
  1.  ; Input: RCGLB - ^TMP($J,"RC344.61") - RCDPE PARAMETER file (#344.61)
  1.  N V,X,Y
  1.  D AD2RPT^RCDPESP1(" ")
  1.  D AD2RPT^RCDPESP1("*** ZERO PAYMENT AMOUNT ERA Auto-Post Parameters ***")
  1.  S X=$$GET1^DID(344.61,1.11,,"TITLE") ;
  1.  S V=" (Y/N)" S:X[V X=$P(X,V,1)_$P(X,V,2) ; Remove yes/no prompt
  1.  S Y=X_" "_@RCGLB(344.61)@(344.61,"1,",1.11,"E")
  1.  D AD2RPT^RCDPESP1(Y)
  1.  D AD2RPT^RCDPESP1(" ")
  1.  Q
  1.  ;
  1. SRTCATS(CATS) ; If user selected both Auto-Post and Auto-Decrease, ensure AD displays after AP
  1.  N ADL,APL,I
  1.  F I=1:1:NUMCATS D
  1.  . I $P(CATS,U,I)="AP" S APL=I Q
  1.  . I $P(CATS,U,I)="AD" S ADL=I
  1.  I $G(APL),$G(ADL),APL>ADL D
  1.  . S APL=$F(CATS,"AP")
  1.  . S CATS=$E(CATS,1,APL-4)_$E(CATS,APL,$L(CATS))
  1.  . S $P(CATS,U,ADL)="AP;AD"
  1.  . S CATS=$TR(CATS,";",U)
  1.  Q CATS
  1.  ;
  1.  ; PRCA*4.5*349 - Added new subroutine to present parameters by category
  1. ENCATS ; EP from RCDPESP
  1.  ; Filter questions by category
  1.  ; Input: CATS - List of categories to display
  1.  ;
  1.  ; Call below answers:
  1.  ; NUMBER OF DAYS EFT UNMATCHED
  1.  ; NUMBER OF DAYS ERA UNMATCHED
  1.  ; # OF DAYS ENTRY CAN REMAIN IN SUSP
  1.  N I,LN,NUMCATS,RCQUIT
  1.  S RCQUIT=0,(APL,ADL)=0,NUMCATS=$L(CATS,U)
  1.  ; If user selected both Auto-Post and Auto-Decrease, ensure AD will display after AP
  1.  S CATS=$$SRTCATS(CATS)
  1.  ; Display categories in order selected
  1.  F I=1:1:NUMCATS D  Q:RCQUIT
  1.  . S LN=$P(CATS,U,I) D @LN
  1.  D EXIT^RCDPESP
  1.  Q
  1.  ;
  1. GN ; Ask General EDI Lockbox Site Questions
  1.  W #,"### General EDI Lockbox Site Parameters ###",!
  1.  S Y=$$GEN  ; General EDI Lockbox Site parameters
  1.  I Y S RCQUIT=1
  1.  Q
  1.  ;
  1. FP ; Ask First Party Questions
  1.  W #,"### First Party Parameters ###",!
  1.  S RCQUIT=$$FIRSTP  ; First party parameters
  1.  Q
  1.  ;
  1.  ; PRCA*4.5*304 - Enable/disable auto-auditing of paper bills
  1. AA ; Ask Auto-Audit Questions
  1.  W #,"### Auto-Audit Site Parameters ###",!
  1.  S RCQUIT=$$AUDIT^RCDPESP5  ; Auto-Audit site parameters
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. AP ; Ask Auto-Post Questions
  1.  W #,"### Auto-Post Parameters ###",!
  1.  W !,"*** Medical Auto-Post Parameters ***",!
  1.  S RCQUIT=$$MAUTOP^RCDPESP
  1.  I '$G(RCQUIT) D
  1.  . W !!,"*** Pharmacy Auto-Post Parameters ***",!
  1.  . S RCQUIT=$$RXAUTOP^RCDPESP
  1.  I '$G(RCQUIT) D
  1.  . W !!,"*** TRICARE Auto-Post Parameters ***",!
  1.  . S RCQUIT=$$TAUTOP^RCDPESP
  1.  I '$G(RCQUIT) D
  1.  . W !!,"*** ZERO PAY Auto-Post Parameters ***",!
  1.  . S RCQUIT=$$APOST(3)
  1.  W !
  1.  Q
  1.  ;
  1.  ;
  1.  W #,"### Auto-Decrease Parameters ###",!
  1.  W !,"*** Medical Auto-Decrease Parameters ***"
  1.  S RCQUIT=$$MAUTOD
  1.  I '$G(RCQUIT) D
  1.  . W !!,"*** Pharmacy Auto-Decrease Parameters ***"
  1.  . S RCQUIT=$$RXAUTOD
  1.  I '$G(RCQUIT) D
  1.  . W !!,"*** TRICARE Auto-Decrease Parameters ***"
  1.  . S RCQUIT=$$TAUTOD
  1.  W !
  1.  Q
  1.  ;
  1. LK ; Ask EFT Lock-Out Questions
  1.  W #,"### EFT Lock-Out Parameters ###",!
  1.  S RCQUIT=$$EFTLK^RCDPESP  ; Set EFT lock-out paramters
  1.  Q
  1.  ;
  1.  ; PRCA*4.5*349 - Added to provide one place to get list of categories
  1. LSTCATS(CATS,SHORT) ; Return list of categories
  1.  S SHORT=+$G(SHORT)
  1.  S CATS("GN")="General EDI Lockbox Site"_$S('SHORT:" Parameters",1:"")
  1.  S CATS("AA")="Auto-Audit Site"_$S('SHORT:" Parameters",1:"")
  1.  S CATS("FP")="First Party"_$S('SHORT:" Parameters",1:"")
  1.  S CATS("AP")="Auto-Post"_$S('SHORT:" Parameters",1:"")
  1.  S CATS("AD")="Auto-Decrease"_$S('SHORT:" Parameters",1:"")
  1.  S CATS("LK")="EFT Lock-Out"_$S('SHORT:" Parameters",1:"")
  1.  Q
  1.  ; 
  1.  ; PRCA*4.5*349 - New function to prompt for categories
  1. CATS() ; Get categories to display
  1.  N CATS,CTLST,DIR
  1.  S CTLST=""
  1.  D LSTCATS(.CATS)
  1.  S DIR(0)="SO^"_$$BLDCATS("")_"AL:All",DIR("B")="All"
  1.  D ^DIR
  1.  I Y="AL" S CTLST=Y G QCATS
  1.  F  Q:$D(DIRUT)  S CTLST=$S($L(CTLST):CTLST_U,1:"")_Y D
  1.  . K DIR
  1.  . S DIR(0)="SO^"_$$BLDCATS(CTLST)
  1.  . D ^DIR
  1.  S:Y=U CTLST=""
  1. QCATS Q CTLST
  1.  ;
  1.  ; PRCA*4.5*349 - New function to support CATS()
  1. BLDCATS(CUR) ; Build set of code string for categories question
  1.  N I,OUT
  1.  S OUT=""
  1.  S I="" F  S I=$O(CATS(I)) Q:I=""  D
  1.  . S:CUR'[(I) OUT=OUT_I_":"_CATS(I)_";"
  1.  Q OUT
  1.  ;
  1.  ; PRCA*4.5*349 - New function to display "general" questions (including bulletin day)
  1.  ;                as separate from First Party questions
  1. GEN() ; General Questions
  1.  N RSLT S RSLT=""
  1.  I '$D(^RC(342,1,0)) D BEG^RCMSITE
  1.  S:'$D(^RC(342,1,0)) RSLT="^no site defined"  ; can't continue
  1.  ;
  1.  Q:RSLT]"" RSLT
  1.  N DA,DR,DIE,Y
  1.  S RSLT=0
  1.  S DA=1,DR="7.02:7.04",DIE="^RC(342,"
  1.  D ^DIE
  1.  S RSLT=$S($D(Y):1,1:0)
  1.  I 'RSLT Q $$BULLDAY^RCDPESP
  1.  Q RSLT
  1.  ;
  1.  ; PRCA*4.5*349 - New function to ask First Party questions as their own category
  1. FIRSTP() ; First Party questions
  1.  N RSLT S RSLT=""
  1.  I '$D(^RC(342,1,0)) D BEG^RCMSITE
  1.  S:'$D(^RC(342,1,0)) RSLT="^no site defined"  ; can't continue
  1.  ;
  1.  Q:RSLT]"" RSLT
  1.  N DA,DIE,DR,Y
  1.  S DA=1,DR="[RCDPE FIRST PARTY]",DIE="^RC(342," D ^DIE
  1.  S RSLT=$S($D(Y):"^user aborted",1:1)  ; if Y remains from ^DIE call
  1.  Q 'RSLT
  1.  ;
  1.  ; PRCA*4.5*349 - New function to ask only Medical Auto-Decrease questions if Auto-Post enabled
  1. MAUTOD() ; Medical Claims Auto-Decrease Questions
  1.  ; Returns: 1 - User '^' or timed out, 0 otherwise
  1.  N ONOFF,RCQUIT
  1.  S RCQUIT=0
  1.  S ONOFF=$$GET1^DIQ(344.61,"1,",.02,"I")
  1.  ; Do not display Auto-Decrease questions when Auto-Post Disabled
  1.  I ONOFF=0 D  Q 0
  1.  . W !,"NOTICE: Medical Auto-Decrease unavailable because Auto-Posting of Medical Claims is currently disabled"
  1.  ; Enable/disable Auto-Decrease of medical claims with payments
  1.  S RCQUIT=$$PAID^RCDPESP7(0)  ; PRCA*4.5*345 - Added 0 parameter
  1.  Q:RCQUIT=1 1
  1.  Q:RCQUIT=2 0  ; Auto-Decrease of Med Claims w/Payments is OFF
  1.  ;
  1.  ; Enable/disable Auto-Decrease of Med Claims with/No Payments
  1.  S RCQUIT=$$NOPAY^RCDPESP7(0)  ; PRCA*4.5*345 - Added 0 parameter
  1.  I RCQUIT=1 Q 1
  1.  ; Set/Reset payer exclusions for medical claim decrease
  1.  D EXCLLIST^RCDPESP(2)  ; Display exclusion list
  1.  S RCQUIT=$$SETEXCL^RCDPESP(2)
  1.  Q:RCQUIT 1
  1.  D EXCLLIST^RCDPESP(2)  ; Display exclusion list
  1.  ;
  1.  Q 0
  1.  ;
  1.  ; PRCA*4.5*349 - New function to ask only Pharmacy Auto-Decrease questions if Auto-Post enabled
  1. RXAUTOD() ; Enable/disable Auto-Decrease of pharmacy claims with payments
  1.  ; Returns: 1 - User '^' or timed out, 0 otherwise
  1.  N ONOFF,RETURN
  1.  S RETURN=0
  1.  S ONOFF=$$GET1^DIQ(344.61,"1,",1.01,"I")
  1.  ; Do not display Auto-Decrease questions when Auto-Post Disabled
  1.  I ONOFF=0 D  Q 0
  1.  . W !,"NOTICE: Pharmacy Auto-Decrease unavailable because Auto-Posting of Pharmacy Claims is currently disabled"
  1.  ; Enable/disable Auto-Decrease of Rx claims with payments
  1.  S RETURN=$$PAID^RCDPESP7(1)
  1.  Q:RETURN=1 1
  1.  Q:RETURN=2 0
  1.  ;
  1.  ; Set/Reset payer exclusions for pharmacy claim decrease
  1.  D EXCLLIST^RCDPESP(4) ; Display the exclusion list
  1.  Q:$$SETEXCL^RCDPESP(4) 1
  1.  D EXCLLIST^RCDPESP(4) ; Display the exclusion list
  1.  Q 0
  1.  ;
  1.  ; PRCA*4.5*349 - New function to ask only TRICARE Auto-Decrease questions if Auto-Post enabled
  1. TAUTOD() ; Enable/disable Auto-Decrease of TRICARE claims with payments
  1.  ; Returns: 1 - User '^' or timed out, 0 otherwise
  1.  N ONOFF,RETURN
  1.  S RETURN=0
  1.  S ONOFF=$$GET1^DIQ(344.61,"1,",1.05,"I")
  1.  ; Do not display Auto-Decrease questions when Auto-Post Disabled
  1.  I ONOFF=0 D  Q 0
  1.  . W !,"NOTICE: TRICARE Auto-Decrease unavailable because Auto-Posting of TRICARE Claims is currently disabled"
  1.  ;
  1.  ; Enable/disable Auto-Decrease of TRICARE claims with payments
  1.  S RETURN=$$PAID^RCDPESP7(2)
  1.  Q:RETURN=1 1
  1.  Q:RETURN=2 0                      ; Auto-Decrease of TRICARE Claims w/Payments is OFF
  1.  ;
  1.  ; Enable/disable Auto-Decrease of TRICARE with/No Payments
  1.  S RETURN=$$NOPAY^RCDPESP7(2)
  1.  I RETURN=1 Q 1
  1.  ;
  1.  ; Set/Reset payer exclusions for TRICARE claim decrease
  1.  D EXCLLIST^RCDPESP(6)                      ; Display the exclusion list
  1.  Q:$$SETEXCL^RCDPESP(6) 1
  1.  D EXCLLIST^RCDPESP(6)                      ; Display the exclusion list
  1.  W !
  1.  Q 0
  1.  ;
  1.  ; PRCA*4.5*349 - Added function
  1. AUTOPON(WHICH) ; Is Auto-Post on for the selected parameters?
  1.  ; Input: WHICH - 0 - Medical, 1 - Rx, 2 - TRICARE (defaults to 0 - Medical)
  1.  ; Returns: 1 if Auto-Posting is turned on for the selected parameter type
  1.  ;          0 if Auto-Posting is turned off for the selected parameter type
  1.  S WHICH=+$G(WHICH)
  1.  Q $$GET1^DIQ(344.61,"1,",$S(WHICH=0:.02,WHICH=1:1.01,1:1.05),"I")
  1.  ;
  1. MPARAMS(RCPARM) ; Display Medical Parameters for Report
  1.  ; Input: RCPARM("AUTO-DECREASE") - 1 if Medical Auto-Posting is turned for claims w/Payments
  1.  ; 0 otherwise
  1.  ; RCPARM("AUTO-POST") - 1 if Medical Auto-Posting is Turned on, 0 otherwise
  1.  ; @RCGLB(344.6) - LIST^DIC array of fields
  1.  ; @RCGLB(344.61) - LIST^DIC array of fields
  1.  ; PRCA*4.5*349 - Added method
  1.  D AD2RPT^RCDPESP1("### Medical Claims Auto-Post/Auto-Decrease Parameters ###")
  1.  D MEDAUTOP^RCDPESP1(.RCPARM)
  1.  D AD2RPT^RCDPESP1(" ")
  1.  D MEDAUTOD^RCDPESP1(.RCPARM,RCTYPE)
  1.  ;
  1.  Q
  1.  ;
  1. RXPARAMS(RCPARM) ; Display Rx Parameters for Report
  1.  ; PRCA*4.5*349 - New method
  1.  ; Input: RCPARM("RX AUTO-DECREASE") - 1 if Rx Auto-Posting is turned for claims w/Payments
  1.  ; 0 otherwise
  1.  ; RCPARM("RX AUTO-POST") - 1 if Rx Auto-Posting is Turned on, 0 otherwise
  1.  ; @RCGLB(344.6) - LIST^DIC array of fields
  1.  ; @RCGLB(344.61) - LIST^DIC array of fields
  1.  D AD2RPT^RCDPESP1("### Pharmacy Auto-Post/Auto-Decrease Parameters ###")
  1.  D RXAUTOP^RCDPESP1(.RCPARM)
  1.  D AD2RPT^RCDPESP1(" ")
  1.  D RXAUTOD^RCDPESP1(.RCPARM,RCTYPE)
  1.  Q
  1.  ;
  1. TPARAMS(RCPARM) ; Display TRICARE Parameters for Report
  1.  ; Input: RCPARM("TRI AUTO-DECREASE") - 1 if TRICARE Auto-Posting is turned for claims w/Payments
  1.  ; 0 otherwise
  1.  ; RCPARM("TRI AUTO-POST") - 1 if TRICARE Auto-Posting is Turned on, 0 otherwise
  1.  ; @RCGLB(344.6) - LIST^DIC array of fields
  1.  ; @RCGLB(344.61) - LIST^DIC array of fields
  1.  ; PRCA*4.5*349 - Added method
  1.  D AD2RPT^RCDPESP1("### TRICARE Auto-Post/Auto-Decrease Parameters ###")
  1.  D TRIAUTOP^RCDPESP1(.RCPARM)
  1.  D AD2RPT^RCDPESP1(" ")
  1.  D TRIAUTOD^RCDPESP1(.RCPARM,RCTYPE)
  1.  Q
  1.  ;
  1. LMHDR(HDR,RCTYPE,RCCATS) ; EP from RCDPESP1
  1.  ; HDR passed by ref.
  1.  ; PRCA*4.5*349 - New subroutine to build ListMan Header
  1.  ; Inputs: RCTYPE - M - Medical, P - Pharmacy, T - TRICARE, A - ALL
  1.  ;         RCCATS - GN - General EDI Lockbox Site
  1.  ;                  AA - Auto-Audit Site
  1.  ;                  FP - First Party
  1.  ;                  AP - Auto-Post"
  1.  ;                  AD - Auto-Decrease
  1.  ;                  LK - EFT Lock-Out
  1.  ; Outputs: HDR - Passed by reference
  1.  ;
  1.  N CNT,CUR,CTLST,P,X,Y
  1.  S HDR("TITLE")="EDI LOCKBOX PARAMETERS REPORT "
  1.  ;
  1.  S X="Medical/Pharmacy/TRICARE: "
  1.  S X=X_$S(RCTYPE="A":"ALL",RCTYPE="M":"MEDICAL",RCTYPE="P":"PHARMACY",RCTYPE="T":"TRICARE",1:"")
  1.  S HDR(1)="Site: "_$$GET1^DIQ(342,"1,",.01,"E")
  1.  S HDR(1)=HDR(1)_$J(X,IOM-($L(HDR(1))+1))
  1.  ; Add categories
  1.  S Y="Categories: "
  1.  S CNT=$L(RCCATS,U),CUR=""
  1.  D LSTCATS^RCDPESPC(.CTLST,1)
  1.  S CTLST("AL")="All"
  1.  F I=1:1:CNT D
  1.  . S X=$G(CTLST($P(RCCATS,U,I)))
  1.  . I ($L(Y)+$L(X))>IOM D
  1.  . . W !,Y
  1.  . . S Y="               "
  1.  . S Y=Y_X
  1.  . I I<CNT S Y=Y_", "
  1.  S HDR(2)=Y
  1.  Q