Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RCDPEWLB

RCDPEWLB.m

Go to the documentation of this file. 
  1. RCDPEWLB ;ALB/TMK - EEOB WORKLIST BATCH PROCESSING ;Jun 06, 2014@19:11:19
  1.  ;;4.5;Accounts Receivable;**208,298**;Mar 20, 1995;Build 121
  1.  ;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1. SETBATCH(RCERA) ; Set up batches for a worklist entry RCERA
  1.  ; Returns ^TMP($J,"BATCHES",batch criteria code,start param data)=
  1.  ;              batch #^end param data
  1.  ; Ask to split the ERA
  1.  ; prca*4.5*298 per requirements, keep code for creating/maintaining batches but remove from execution
  1.  Q  ;prca*4.5*298 
  1.  N DIR,DTOUT,DUOUT,RCBAT,RCNAMES,RCNUM,RCS,RCSEL,RCY,RCZ,X,Y,Z,Z0
  1.  K ^TMP($J,"BATCHES")
  1.  S RCNUM=+$$CTEEOB(RCERA)
  1.  Q:RCNUM'>1
  1.  S DIR("A",1)="THERE ARE APPROXIMATELY "_RCNUM_" EEOBS IN THIS ERA",DIR("A")="DO YOU WANT TO SPLIT THIS ERA INTO BATCHES?: ",DIR(0)="YA",DIR("B")=$S(RCNUM>30:"YES",1:"NO") W ! D ^DIR K DIR
  1.  I Y'=1 Q
  1.  ;
  1.  S DIR("A",1)="YOU MAY USE ANY ONE OF THE FOLLOWING CRITERIA TO SPLIT THE ERA INTO BATCHES: ",DIR("A",2)=" ",DIR("A",3)=$J("",10)_"1 - BY MAX # OF EEOBs TO INCLUDE IN A BATCH"
  1.  S DIR("A",4)=$J("",10)_"2 - BY RANGES OF PATIENT LAST NAME",DIR("A",5)=$J("",10)_"3 - BY EEOB PAYMENT STATUS (FULL/PARTIAL/NO PAY)"
  1.  S DIR("A",6)=$J("",10)_"4 - BY CO-PAY AND NON-COPAY FOR THE DATE OF SERVICE",DIR("A",7)=" "
  1.  S DIR(0)="SAO^1:MAX #;2:LAST NAME;3:PAY STATUS;4:CO-PAY STATUS",DIR("A")="CRITERIA SELECTION: "
  1.  W !! D ^DIR K DIR
  1.  Q:$D(DUOUT)!$D(DTOUT)!(Y="")
  1.  S RCBAT=0,RCSEL=Y,^TMP($J,"BATCHES")=RCSEL
  1.  S DIR(0)="YA",DIR("A")="DO YOU WANT TO NAME YOUR OWN BATCHES?: ",DIR("B")="NO" W ! D ^DIR K DIR
  1.  Q:$D(DUOUT)!$D(DTOUT)
  1.  S RCNAMES=+Y
  1.  I RCSEL=1 D
  1.  . W ! S DIR(0)="NA^1:"_RCNUM,DIR("A")="MAX # OF EEOBS TO INCLUDE IN A BATCH: ",DIR("?")="ENTER A NUMBER FROM 1 TO "_RCNUM D ^DIR K DIR
  1.  . I $D(DTOUT)!$D(DUOUT) Q
  1.  . S RCY=Y
  1.  . F RCZ=1:1:RCNUM\RCY+$S(RCNUM#RCY:1,1:0) S RCS=((RCZ-1)*RCY)+1 D NEWBAT(RCERA,1,"",RCS_U_(RCS+RCY-1),.RCBAT,RCNAMES) S ^TMP($J,"BATCHES",1,RCS)=RCBAT_U_(RCS+RCY-1)
  1.  ;
  1.  I RCSEL=2 D
  1.  . N RCNMF,RCQUIT,RCDONE
  1.  . S RCNMF="A",(RCQUIT,RCDONE)=0
  1.  . F  D  Q:RCQUIT!RCDONE
  1.  .. W !!,"START FROM LAST NAME BEGINNING WITH: ",RCNMF
  1.  .. S DIR("?")="ENTER A LETTER IN UPPERCASE"
  1.  .. S DIR(0)="FA^1:1^K:X'?.U X",DIR("A")="INCLUDE THROUGH LAST NAME BEGINNING WITH: " D ^DIR K DIR
  1.  .. I $D(DTOUT)!$D(DUOUT) S RCQUIT=1 Q
  1.  .. S RCY=Y,RCSEL("NAME",RCNMF)=Y_"ZZZ"
  1.  .. I $A(RCY)=90 S RCDONE=1 Q
  1.  .. S RCNMF=$A(RCY)+1,RCNMF=$C(RCNMF)
  1.  . Q:RCQUIT
  1.  . S Z="" F  S Z=$O(RCSEL("NAME",Z)) Q:Z=""  D NEWBAT(RCERA,2,"",Z_U_RCSEL("NAME",Z),.RCBAT,RCNAMES) S ^TMP($J,"BATCHES",2,Z)=RCBAT_U_RCSEL("NAME",Z)
  1.  ;
  1.  I RCSEL=3 D
  1.  . F Y=1:1:3 D NEWBAT(RCERA,3,$P("FULL PAYMENT^PARTIAL PAYMENT^NO PAYMENT",U,Y),Y,.RCBAT,RCNAMES) S ^TMP($J,"BATCHES",3,Y)=RCBAT
  1.  ;
  1.  I RCSEL=4 D
  1.  . F Y=1,2 D NEWBAT(RCERA,RCSEL,$P("CO-PAY EXISTS^NO CO-PAY EXISTS",U,Y),Y,.RCBAT,RCNAMES) S ^TMP($J,"BATCHES",4,Y)=RCBAT
  1.  ;
  1.  S DIR(0)="EA",DIR("A")=RCBAT_" BATCHES CREATED.  PRESS RETURN TO CONTINUE " W ! D ^DIR K DIR
  1.  Q
  1.  ;
  1. NEWBAT(RCERA,RCSEL,RCDAT,RCVAL,RCBAT,RCNAMES) ; Add a new batch at the top level entry
  1.  ; RCERA = the ien of the entry in file 344.49
  1.  ; RCSEL = the # of the selection criteria selected
  1.  ; RCDAT = the default 'name' of the batch based on the criteria used
  1.  ; RCVAL = the start value^the end value
  1.  ; RCBAT = if passed by reference, returned as the next batch #
  1.  ; RCNAMES = 1 if user wants to name each batch, 0 to accept default
  1.  ;
  1.  ; prca*4.5*298 per requirements, keep code related to creating/maintaining batches but remove from execution
  1.  Q  ;prca*4.5*298 
  1.  N DA,DD,DIC,DLAYGO,DO,DR,X,Y
  1.  S RCBAT=RCBAT+1
  1.  S DA(1)=RCERA,DIC="^RCY(344.49,"_DA(1)_",3,",DLAYGO=344.493,DIC(0)="L",X=RCBAT
  1.  I $G(RCNAMES) W !!,"**BATCH #: "_RCBAT
  1.  S DIC("DR")=".03////0;.04////"_DUZ_";.05////0;.06////"_RCSEL_";.07////"_$P(RCVAL,U)_$S($P(RCVAL,U,2)'="":";.08////"_$P(RCVAL,U,2),1:"")
  1.  S DIC("DR")=DIC("DR")_";.02R//"_$S(RCNAMES:"",1:"//")_$S(RCSEL=1:"BATCH #: "_RCBAT,RCSEL=2:"LAST NAME FROM "_$P(RCVAL,U)_" - "_$P(RCVAL,U,2),1:RCDAT)
  1.  D FILE^DICN K DLAYGO,DIC,DD,DO W !
  1.  Q
  1.  ;
  1. GETBATCH(RCZ0) ; Returns the batch # to be assigned to the data in RCZ0
  1.  ; RCZ0 = 0-node of the entry in file 344.41 to be assigned to a batch
  1.  N BNUM,Z,Z0
  1.  S BNUM=""
  1.  I $G(^TMP($J,"BATCHES"))=1 D  ; Max #
  1.  . N CT
  1.  . S CT=+$G(^TMP($J,"BATCHES","CT"))+1
  1.  . S ^TMP($J,"BATCHES","CT")=CT
  1.  . S Z=+$O(^TMP($J,"BATCHES",1,CT+1),-1),BNUM=+$G(^TMP($J,"BATCHES",1,Z)) S:'BNUM BNUM=1
  1.  ;
  1.  I $G(^TMP($J,"BATCHES"))=2 D  ; last name
  1.  . S Z=$P(RCZ0,U,15)
  1.  . I $P(RCZ0,U,2) S Z0=$P($G(^DGCR(399,+$G(^IBM(361.1,+$P(RCZ0,U,2),0)),0)),U,2),Z0=$P($G(^DPT(Z0,0)),U) I Z0'="" S Z=Z0
  1.  . S Z0=$A($E(Z))-1,Z0=$C(Z0),Z0=$O(^TMP($J,"BATCHES",2,Z0),-1)
  1.  . S BNUM=$S(Z0="":1,1:+$G(^TMP($J,"BATCHES",2,Z0))) S:'BNUM BNUM=1
  1.  ;
  1.  I $G(^TMP($J,"BATCHES"))=3 D  ; payment amount
  1.  . S Z=+$P(RCZ0,U,3)
  1.  . I Z'>0!'$P(RCZ0,U,2) S BNUM=3 Q  ; 0-PAY/ADJUSTMENT/UNKNOWN CLAIM
  1.  . I +$P($G(^IBM(361.1,+$P(RCZ0,U,2))),U,4)'>+Z S BNUM=1 Q  ; FULL PAY
  1.  . S BNUM=2 ; PARTIAL PAY
  1.  ;
  1.  I $G(^TMP($J,"BATCHES"))=4 D  ; Co-pay/not
  1.  . S BNUM=2
  1.  . Q:'$P(RCZ0,U,2)
  1.  . I $$COPAY^RCDPEWL1(+$G(^IBM(361.1,+$P(RCZ0,U,2),0))) S BNUM=1
  1.  ;
  1.  Q BNUM
  1.  ;
  1. EDIT(RCERA,RCB,ABORT) ; Edit name and posting status of an existing batch
  1.  ; RCERA = the ien of the worklist entry
  1.  ; RCB = the ien of the current batch
  1.  ; RCABORT = if passed by reference, returned as 1 if user aborts
  1.  ;
  1.  ; prca*4.5*298 per requirements, keep code related to creating/maintaining batches but remove from execution
  1.  Q  ;prca*4.5*298 
  1.  N DA,DIE,DR,X,Y
  1.  D FULL^VALM1
  1.  S ABORT=0
  1.  S DA(1)=RCERA,DA=RCB,DIE="^RCY(344.49,"_DA(1)_",3,",DR=".02;.03" D ^DIE I $D(Y) S ABORT=1
  1.  K VALMHDR ; Used to rebuild the header
  1.  S VALMBCK="R"
  1.  Q
  1.  ;
  1. MARKALL(RCERA) ; Mark all batches as ready to post
  1.  ;  prca*4.5*298 per requirements, keep code related to creating/maintaining batches but remove from execution
  1.  Q  ;prca*4.5*298 
  1.  N DIR,X,Y,Z,RCT,DA,DIE,DR
  1.  D FULL^VALM1
  1.  S VALMBCK="R"
  1.  I $G(^TMP("RCBATCH_SELECTED",$J)) D NOBATCH^RCDPEWL S VALMBCK="R" Q
  1.  I '$O(^RCY(344.49,RCERA,3,0)) D NOTSET^RCDPEWLC Q
  1.  S DIR(0)="YA",DIR("A",1)="THIS ACTION WILL MARK ALL BATCHES FOR THIS ERA AS READY TO POST",DIR("A")="ARE YOU SURE YOU WANT TO DO THIS?: ",DIR("B")="NO" W ! D ^DIR K DIR
  1.  S RCT=0
  1.  I Y D
  1.  . S Z=0 F  S Z=$O(^RCY(344.49,RCERA,3,Z)) Q:'Z  I '$P($G(^(Z,0)),U,3) S RCT=RCT+1,DA(1)=RCERA,DA=Z,DIE="^RCY(344.49,"_DA(1)_",3,",DR=".03////1" D ^DIE
  1.  . W !!,RCT," BATCHES CHANGED TO READY TO POST",!,"ALL BATCHES ARE NOW READY TO POST"
  1.  . S DIR(0)="EA",DIR("A")="PRESS RETURN TO CONTINUE " W ! D ^DIR K DIR
  1.  . K VALMHDR
  1.  Q
  1.  ;
  1. EDITALL(RCERA) ; Edit all batches
  1.  ; prca*4.5*298 per requirements, keep code related to creating/maintaining batches but remove from execution
  1.  Q  ;prca*4.5*298 
  1.  N Z,RCQUIT
  1.  D FULL^VALM1
  1.  S VALMBCK="R"
  1.  W !
  1.  I '$O(^RCY(344.49,RCERA,3,0)) D NOTSET^RCDPEWLC Q
  1.  S (RCQUIT,Z)=0 F  S Z=$O(^RCY(344.49,RCERA,3,Z)) Q:'Z  W !!,"BATCH #: "_+$G(^(Z,0)) D EDIT(RCERA,Z,.RCQUIT) Q:RCQUIT
  1.  Q
  1.  ;
  1. REBATCH(RCERA) ; Allow to recreate batches
  1.  ;  prca*4.5*298 per requirements, keep code related to creating/maintaining batches but remove from execution
  1.  Q  ;prca*4.5*298 
  1.  N DA,DIE,DIK,DIR,DR,RCLINE,RCQUIT,X,Y,Z,Z0
  1.  D FULL^VALM1
  1.  I $G(^TMP("RCBATCH_SELECTED",$J)) D NOBATCH^RCDPEWL G REBQ
  1.  ;
  1.  I '$O(^RCY(344.49,RCERA,3,0)) W !!," ***** THIS ERA CURRENTLY HAS NO BATCHES DEFINED *****"
  1.  ;
  1.  S RCQUIT=0
  1.  I $O(^RCY(344.49,RCERA,3,0)) D  G:RCQUIT REBQ
  1.  . S DIR(0)="YA",DIR("B")="NO",DIR("A",1)="THIS ACTION REMOVES ALL BATCH REFERENCES.  THE BATCHES CAN THEN BE REBUILT.",DIR("A")="ARE YOU SURE YOU WANT TO CONTINUE?: " W ! D ^DIR K DIR
  1.  . I Y'=1 S RCQUIT=1 Q
  1.  . S Z=0 F  S Z=$O(^RCY(344.49,RCERA,3,Z)) Q:'Z  S DA(1)=RCERA,DIK="^RCY(344.49,"_DA(1)_",3,",DA=Z D ^DIK
  1.  ;
  1.  K ^TMP($J,"BATCHES")
  1.  D SETBATCH(RCERA)
  1.  S Z=0 F  S Z=$O(^RCY(344.49,RCERA,1,Z)) Q:'Z  S Z0=$G(^(Z,0)) I +Z0'["." D
  1.  . S RCLINE=$G(^RCY(344.4,RCERA,1,+$P(Z0,U,9),0)),DA(1)=RCERA,DIE="^RCY(344.49,"_DA(1)_",1,",DA=Z,DR=".14///"_$S(RCLINE="":"@",1:"/"_$$GETBATCH^RCDPEWLB(RCLINE)) D ^DIE
  1.  K ^TMP($J,"BATCHES")
  1. REBQ S VALMBCK="R"
  1.  Q
  1.  ;
  1. CTEEOB(RCERA) ; Returns the approx # of EEOBs in ERA ien RCERA (file 344.4)
  1.  N RCNUM,Z
  1.  S (RCNUM,Z)=0 F  S Z=$O(^RCY(344.4,RCERA,1,Z)) Q:'Z  I $P($G(^(Z,0)),U,3)'<0 S RCNUM=RCNUM+1
  1.  Q RCNUM
  1.  ;