Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RCWROFF1

RCWROFF1.m

Go to the documentation of this file.
  1. RCWROFF1 ;WISC/RFJ-partial waiver ;1 Feb 2000
  1. ;;4.5;Accounts Receivable;**168,204,233,301,377**;Mar 20, 1995;Build 45
  1. ;;Per VA Directive 6402, this routine should not be modified.
  1. Q
  1. ;
  1. ;
  1. PARTIAL ; enter a partial waived (menu option)
  1. N DR,RCBILLDA,RCCURPRI,RCFYCNT,RCTOTAL,RCTRANDA,RCWAIVED,Y
  1. F D Q:RCBILLDA<1
  1. . K RCTRANDA ;do not leave around in for loop
  1. . ; select a bill
  1. . S RCBILLDA=$$GETABILL^RCBEUBIL I RCBILLDA<1 Q
  1. . I $D(^PRCA(430,"TCSP",RCBILLDA)) D Q ;prca*4.5*301
  1. . . W !,"BILL HAS BEEN REFERRED TO CROSS-SERVICING.",!,"NO TRANSACTIONS ARE ALLOWED.",!,"** THE RECALL PROCESS MUST BE UTILIZED PRIOR TO PERFORMING THIS FUNCTION **" ;prca*4.5*301 Q
  1. . ; lock the bill
  1. . L +^PRCA(430,RCBILLDA):5 I '$T W !,"ANOTHER USER IS CURRENTLY WORKING WITH THIS BILL." Q
  1. . D SHOWBILL(RCBILLDA)
  1. . I '$G(^PRCA(430,RCBILLDA,7)) W !,"THIS BILL HAS NO PRINCIPAL BALANCE." D UNLOCK^RCWROFF Q
  1. . W !
  1. . ; add a new partial waiver transaction to file 433
  1. . S RCTRANDA=$$ADD433^RCBEUTRA(RCBILLDA,11) I 'RCTRANDA W !,$P(RCTRANDA,"^",2) D UNLOCK^RCWROFF Q
  1. . W !," Transaction number ",RCTRANDA," added ..."
  1. . ; transfer fy multiple from bill
  1. . D FY433^RCBEUTRA(RCTRANDA)
  1. . ;
  1. . ; build dr string for call to die
  1. . S DR="11WAIVED IN PART DATE;"
  1. . ; determine if there is more than one fiscal year for build DR string
  1. . S RCFYCNT=$P($G(^PRCA(433,RCTRANDA,4,0)),"^",4)
  1. . ; single fiscal year in multiple
  1. . I RCFYCNT'>1 D
  1. . . ; get the current principal balance
  1. . . S RCCURPRI=+$P($G(^PRCA(433,RCTRANDA,4,+$O(^PRCA(433,RCTRANDA,4,0)),0)),"^",2)
  1. . . S DR=DR_"15WAIVED AMOUNT;"
  1. . . S DR=DR_"S RCWAIVED=+X;"
  1. . . S DR=DR_"I RCWAIVED'>0 W !,""Amount must be greater than ZERO. Press ^ to exit."" S Y=15;"
  1. . . S DR=DR_"I RCWAIVED>RCCURPRI W !,""Waived amount CAN NOT EXCEED Principal amount ($ "",$J(RCCURPRI,0,2),"")."" S Y=15;"
  1. . . S DR=DR_"I RCWAIVED=RCCURPRI W !,""If you are creating a waiver for the FULL AMOUNT, use the option Full Waiver."" S Y=15;"
  1. . . S DR=DR_"81///^S X=RCWAIVED;"
  1. . ; multiple fiscal years in multiple
  1. . I RCFYCNT>1 D
  1. . . S DR=DR_"S RCTOTAL=0;"
  1. . . S DR=DR_".02;"
  1. . . S DR(2,433.01)="4WAIVED AMOUNT;"
  1. . . S DR(2,433.01)=DR(2,433.01)_"S RCWAIVED=+X,RCCURPRI=+$P(^PRCA(433,DA(1),4,DA,0),U,2);"
  1. . . S DR(2,433.01)=DR(2,433.01)_"I RCWAIVED>RCCURPRI W !,""Waived amount CAN NOT EXCEED Principal Amount ($ "",$J(RCCURPRI,0,2),"") for this Fiscal Year."" S Y=4;"
  1. . . S DR(2,433.01,1)="I RCWAIVED=RCCURPRI W !,""If you are creating a waiver for the FULL AMOUNT, use the option Full Waiver."" S Y=4;"
  1. . . S DR(2,433.01,1)=DR(2,433.01,1)_"1///^S X=$P(^PRCA(433,DA(1),4,DA,0),U,2)-RCWAIVED;"
  1. . . S DR(2,433.01,1)=DR(2,433.01,1)_"S RCTOTAL=$G(RCTOTAL)+RCWAIVED;"
  1. . . S DR=DR_"I RCTOTAL'>0 W !,""Amount must be greater than ZERO. Press ^ to exit."" S Y=.02;"
  1. . . S DR=DR_"15///^S X=RCTOTAL;"
  1. . . S DR=DR_"81///^S X=RCTOTAL;"
  1. . ;
  1. . ; allow user to edit key fields
  1. . S Y=$$EDIT433^RCBEUTRA(RCTRANDA,.DR)
  1. . I 'Y W !,$P(Y,"^",2) D DEL433^RCBEUTRA(RCTRANDA,"",0),UNLOCK^RCWROFF Q
  1. . ;
  1. . ; if only one fiscal year, update the multiple since it was not done
  1. . ; by the user in the die call
  1. . I RCFYCNT=1 D
  1. . . N DA40,DATA40,RCTOTAL
  1. . . S RCTOTAL=$P($G(^PRCA(433,RCTRANDA,8)),"^") ;amount waived
  1. . . S DA40=+$O(^PRCA(433,RCTRANDA,4,0)) I 'DA40 Q
  1. . . S DATA40=$G(^PRCA(433,RCTRANDA,4,DA40,0)) I DATA40="" Q
  1. . . S $P(DATA40,"^",2)=$P(DATA40,"^",2)-RCTOTAL ;principal remaining
  1. . . S $P(DATA40,"^",5)=RCTOTAL ;amount waived
  1. . . S ^PRCA(433,RCTRANDA,4,DA40,0)=DATA40
  1. . ;
  1. . D SHOWTRAN(RCTRANDA)
  1. . I $$ASKOK^RCWROFF("Partial Waiver")'=1 D DEL433^RCBEUTRA(RCTRANDA,"",0),UNLOCK^RCWROFF Q
  1. . ;
  1. . ; move the fy multiple from 433 to 430
  1. . D FYMULT^RCBEUBIL(RCTRANDA)
  1. . ; mark transaction as processed
  1. . D PROCESS^RCBEUTRA(RCTRANDA)
  1. . ; update the principal balance on the bill (subtract the waived amount)
  1. . D SETBAL^RCBEUBIL(RCTRANDA)
  1. . ;PRCA*4.5*377 - Update active repayment plan attached to bill.
  1. . D UPDBAL^RCRPU1(RCBILLDA,RCTRANDA)
  1. . ; create fms write off document, if not accrued
  1. . I '$$ACCK^PRCAACC(RCBILLDA) D FMSDOC^RCWROFF(RCTRANDA)
  1. . ;
  1. . W !," * * * * * Partial Waiver has been PROCESSED! * * * * *"
  1. .I '$G(REFMS)&(DT>$$LDATE^RCRJR(DT)) S Y=$E($$FPS^RCAMFN01(DT,1),1,5)_"01" D DD^%DT W !!," * * * * Transmission will be held until "_Y_" * * * *"
  1. . D UNLOCK^RCWROFF
  1. Q
  1. ;
  1. ;
  1. SHOWTRAN(RCTRANDA) ; show data for transaction
  1. N %,DATA0,DATA1,DATA40,RCWRLINE,Y
  1. S DATA0=$G(^PRCA(433,RCTRANDA,0))
  1. S DATA1=$G(^PRCA(433,RCTRANDA,1))
  1. S RCWRLINE="",$P(RCWRLINE,"=",79)=""
  1. W !!,RCWRLINE
  1. W !,"BILL NUMBER: ",$P($G(^PRCA(430,+$P(DATA0,"^",2),0)),"^")
  1. W ?40,"WAIVED AMOUNT: ",$J($P(DATA1,"^",5),0,2)
  1. S Y=$P($P(DATA1,"^"),".") I Y D DD^%DT
  1. W !?42,"WAIVED DATE: ",Y
  1. W !!,"FISCAL YEAR",?30,"WAIVED AMOUNT",?50,"NEW PRINCIPAL BALANCE DUE"
  1. S %=0 F S %=$O(^PRCA(433,RCTRANDA,4,%)) Q:'% D
  1. . S DATA40=$G(^PRCA(433,RCTRANDA,4,%,0))
  1. . W !,$P(DATA40,"^"),?30,$J($P(DATA40,"^",5),13,2),?50,$J($P(DATA40,"^",2),25,2)
  1. W !!,RCWRLINE
  1. Q
  1. ;
  1. ;
  1. SHOWBILL(RCBILLDA) ; show data for bill
  1. N DATA7,DATA20,FYDA
  1. S DATA7=$G(^PRCA(430,RCBILLDA,7))
  1. W !?8,"Principal Balance: ",$J($P(DATA7,"^"),11,2)
  1. ;
  1. ; show fy data
  1. S FYDA=$O(^PRCA(430,RCBILLDA,2,0)),DATA20=$G(^PRCA(430,RCBILLDA,2,FYDA,0))
  1. W ?40,"FY: ",$P(DATA20,"^"),?48,"Principal Balance: ",$J($P(DATA20,"^",2),0,2)
  1. ; if multiple fiscal years, show them here
  1. F S FYDA=$O(^PRCA(430,RCBILLDA,2,FYDA)) Q:'FYDA D
  1. . S DATA20=$G(^PRCA(430,RCBILLDA,2,FYDA,0))
  1. . W !?40,"FY: ",$P(DATA20,"^"),?48,"Principal Balance: ",$J($P(DATA20,"^",2),0,2)
  1. ;
  1. W !?8," Interest Balance: ",$J($P(DATA7,"^",2),11,2)
  1. W !?8," Admin Balance: ",$J($P(DATA7,"^",3)+$P(DATA7,"^",4)+$P(DATA7,"^",5),11,2)
  1. W !?27,"-----------"
  1. W !?8," TOTAL Balance: ",$J($P(DATA7,"^")+$P(DATA7,"^",2)+$P(DATA7,"^",3)+$P(DATA7,"^",4)+$P(DATA7,"^",5),11,2)
  1. Q