Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RCXVTSK

RCXVTSK.m

Go to the documentation of this file. 
  1. RCXVTSK ;DAOU/ALA-AR Data Extract Nightly Task ;23-JUL-03
  1.  ;;4.5;Accounts Receivable;**201,227,228,232**;Mar 20, 1995
  1.  ;
  1.  ;** Program Description **
  1.  ;  This program is the nightly task program for the
  1.  ;  CBO Data Extract to the Boston Allocation Resource
  1.  ;  Center
  1.  ;
  1. EN ;  Entry point
  1.  ;
  1.  ;  If a test system has 'turned off' extract, quit
  1.  I '$$GET1^DIQ(342,"1,",20.04,"I") Q
  1.  ;
  1.  N $ES,$ET
  1.  S $ET="D ER^RCXVTSK"
  1.  ;
  1.  L +^RCXVTSK:60 E  Q
  1.  ;
  1.  ;  Purge completed batches
  1.  S IEN="",DIK="^RCXV("
  1.  F  S IEN=$O(^RCXV("AC","C",IEN)) Q:IEN=""  D
  1.  . S DA=IEN D ^DIK
  1.  ;
  1.  K ^TMP("RCXVMSG",$J)
  1.  ;
  1.  ;  Find all deposits/receipts
  1.  S RCXVD0="",RCXVRNUM=0,RCXVDT=$$FMADD^XLFDT(DT,-1)
  1.  F  S RCXVD0=$O(^RCY(344,"ASTAT",0,RCXVD0)) Q:RCXVD0=""  D
  1.  . S RCXVEDT=$P($G(^RCY(344,RCXVD0,0)),U,12)\1
  1.  . I RCXVEDT'=RCXVDT Q
  1.  . S RCXVRNUM=RCXVRNUM+1
  1.  . D FIL^RCXVDEQ("R")
  1.  . D UDR^RCXVDEQ
  1.  ;
  1.  K RCXVD0,RCXVRNUM,RCXVDT,RCXVEDT,RCXVDA,RCVXCTY,RCXVBDT
  1.  ;
  1.  S RCXVBTN="",RCXVU="^",RCXVXDT=DT
  1.  ;
  1.  ;  If the CCPC calculation is scheduled to run, don't
  1.  ;  run the nightly task
  1.  ; Patch 228 changes software to allow nightly task on CCPC date
  1.  ;S X1=$$STD^RCCPCFN,X2=-3 D C^%DTC I X=DT L -^RCXVTSK K X Q
  1.  ;K X1,X2
  1.  ;
  1. MONTHLY ;Set up monthly transmission batches
  1.  I $E(DT,6,7)="01" D EN^RCXVDC10
  1. NM ;  Find all new batches to be transmitted
  1.  S RBSQ=0,RBTOT=0
  1.  F  S RCXVBTN=$O(^RCXV("AC","P",RCXVBTN)) Q:RCXVBTN=""  D
  1.  . I $G(^RCXV(RCXVBTN,0))="" Q
  1.  . S RBSQ=RBSQ+1,RBTOT=RBTOT+1
  1.  . I $P(^RCXV(RCXVBTN,0),U,1)'=RCXVBTN S RCXVUP(348.4,RCXVBTN_",",.01)=RCXVBTN
  1.  . S RCXVUP(348.4,RCXVBTN_",",.05)=RBSQ
  1.  F  S RCXVBTN=$O(RCXVUP(348.4,RCXVBTN)) Q:RCXVBTN=""  D
  1.  . S RCXVUP(348.4,RCXVBTN,.06)=RBTOT
  1.  D FILE^DIE("","RCXVUP","RCXVERR")
  1.  K RCXVUP
  1.  ;
  1.  S RCXVBTN=""
  1. STRT ;  Start the build and transmission of batches
  1.  D ^RCXVCHK
  1.  F RCSTAT="T","P" F  S RCXVBTN=$O(^RCXV("AC",RCSTAT,RCXVBTN)) Q:RCXVBTN=""  D
  1.  . S RCXVBLN=0,RQFL=0
  1.  . S RCXVSITE=$P($$SITE^VASITE(),U,3)
  1.  . S RCXVDIR=$P($G(^RC(342,1,20)),U,1)
  1.  . S RCXVBDT=$P($G(^RCXV(RCXVBTN,0)),U,2)
  1.  . S RCXVBTY=$P($G(^RCXV(RCXVBTN,0)),U,4)
  1.  . S RCXVSEQ=$P($G(^RCXV(RCXVBTN,0)),U,5)
  1.  . S RCXVSTOT=$P($G(^RCXV(RCXVBTN,0)),U,6)
  1.  . S RCXVLDOM=$P($G(^RC(342,1,20)),U,8)
  1.  . ;S RCXVLEG=+$P($G(^RC(342,1,20)),U,7)
  1.  . ;
  1.  . I RCSTAT'="T" D  Q:RQFL
  1.  .. I $G(RCXVSEQ)="" S RQFL=1 Q
  1.  .. I $P(^RCXV(RCXVBTN,0),U,3)="C" S RQFL=1 Q
  1.  .. S RCXVUP(348.4,RCXVBTN_",",.03)="T"
  1.  .. D FILE^DIE("I","RCXVUP","RCXVERR")
  1.  .. K RCXVUP
  1.  . ;
  1.  . ; If a file has been transmitted but no acknowledgement
  1.  . ; has been received after 5 days, resend
  1.  . I RCSTAT="T" D  Q:RQFL
  1.  .. S RCXVTRD=$P($G(^RCXV(RCXVBTN,0)),U,8)\1
  1.  .. S RCXVARD=$P($G(^RCXV(RCXVBTN,0)),U,9)\1
  1.  .. I $$FMADD^XLFDT(RCXVTRD,5)>DT S RQFL=1
  1.  .. ;I RCXVARD=0,RCXVLEG,RCXVTRD'=0 S RQFL=1
  1.  . ;
  1.  . Q:RQFL
  1.  . ; FILENAME=SITE_DATE_BATCH# 
  1.  . S RCXVFILE="RCXV"_RCXVSITE_RCXVBDT_RCXVBTN_".TXT"
  1.  . S RCXVSCR="TMP_RCXV"_RCXVSITE_"_"_RCXVBTN
  1.  . D OPEN^%ZISH("RCXVHNDL",RCXVDIR,RCXVFILE,"W")
  1.  . U IO
  1.  . S RCXVDMN=$P($G(^XTV(8989.3,1,0)),U,1)
  1.  . S RCXVDMN=$P($G(^DIC(4.2,RCXVDMN,0)),U,1)
  1.  . S RCXVRN=$P($G(^RCXV(RCXVBTN,1,0)),U,4) ; # OF REC FOR BILLS
  1.  . I RCXVRN="" S RCXVRN=$P($G(^RCXV(RCXVBTN,2,0)),U,4) ; # REC DEP/REC
  1.  . S RCXVRT=$P($G(^RCXV(RCXVBTN,0)),U,4) ; TYPE OF DATA 
  1.  . W "HDR:"_RCXVSITE_RCXVU_RCXVDMN_RCXVU_RCXVRT_RCXVU_RCXVRN_RCXVU_RCXVBDT_RCXVU_RCXVXDT_RCXVU_RCXVSEQ_RCXVU_RCXVSTOT_RCXVU_RCXVLDOM,!
  1.  . F  S RCXVBLN=$O(^RCXV(RCXVBTN,1,RCXVBLN)) Q:'RCXVBLN  D
  1.  .. S DFN=$P(^RCXV(RCXVBTN,1,RCXVBLN,0),U,2)
  1.  .. D EN^RCXVDC
  1.  . ;
  1.  . S RCXVD0=0
  1.  . F  S RCXVD0=$O(^RCXV(RCXVBTN,2,RCXVD0)) Q:'RCXVD0  D
  1.  .. S RCXVEDT=$P($G(^RCY(344,RCXVD0,0)),U,12)\1
  1.  .. D D344^RCXVDC8
  1.  . ;
  1.  . S RCXVD0=0
  1.  . F  S RCXVD0=$O(^RCXV(RCXVBTN,3,RCXVD0)) Q:'RCXVD0  D
  1.  .. S DFN=RCXVD0
  1.  .. D D3547^RCXVDC10
  1.  . ;
  1.  . I $D(^RCXV(RCXVBTN,4)) S RCXVMO=$G(^(4)) D PREREG^RCXVDC10
  1.  . ;
  1.  . I $D(^RCXV(RCXVBTN,5)) S RCXVMO=$G(^(5)) D BUFFER^RCXVDC10
  1.  . ;
  1.  . D CLOSE^%ZISH("RCXVHNDL")
  1.  . ;
  1.  . S $P(^RC(342,1,20),U,9)=$$NOW^XLFDT()
  1.  . ;
  1.  . ;  FTP directly to ARC
  1.  . D EN^RCXVFTP(RCXVFILE,RCXVDIR)
  1.  ;
  1.  ;  Check on FTP transfer messages
  1.  D ^RCXVFTR
  1.  ;
  1.  L -^RCXVTSK
  1. EXIT D MSG^RCXVCHK
  1.  K IEN,DIK,DA,RCXVBLN,RCXVBTN,RCSTAT,RCXVBDT,RCXVDMN,RCXVXDT,RCXVTRD
  1.  K RCXVSITE,RCXVFILE,RCXVRN,RCXVRT,RCXVDIR,RCXVATP,RCXVU,DTACT,RBSQ,RBTOT
  1.  K RCFDATE,RCXVCFLG,RCXVDBN,RCXVIDT,RCXVSEQ,RCXVSTOT,RCXVTRD,CCT,DTENT
  1.  K RCBLN,RCDBTR,RCDEBT,RCTRAN,RCXVTR,RCBCN,RCXVPFDT,RCXVPTDT,RCXRMB
  1.  K RCXVLDOM,RCXVARD,RCXVSUB,RCXVBTY,RCXVLEG,RCXVSCR,Y,X,RCXVMO
  1.  K ^TMP("RCXVMSG",$J),^TMP("RCXVA",$J),^TMP("RCXVIN",$J)
  1.  Q
  1.  ;
  1. HIS ;  Historical data extract
  1.  ;
  1.  L +^RCXVTSK:60 E  HANG 600 G HIS
  1.  ;
  1.  I $G(DT)="" D DT^DICRW
  1.  ;
  1.  I $G(RCXVFFD)="" D
  1.  . S RCFDATE=$$FYCY^IBCU8(DT)
  1.  . S RCXVFFD=$P(RCFDATE,U,3),RCXVFTD=$P(RCFDATE,U,4)
  1.  ;
  1.  S RCXVDAT=RCXVFFD-.01
  1.  F  S RCXVDAT=$O(^PRCA(430,"ACTDT",RCXVDAT)) Q:RCXVDAT=""!(RCXVDAT>RCXVFTD)  D
  1.  . S IEN=""
  1.  . F  S IEN=$O(^PRCA(430,"ACTDT",RCXVDAT,IEN)) Q:IEN=""  D
  1.  .. I $P(^PRCA(430,IEN,0),U,8)=16!($P(^PRCA(430,IEN,0),U,8)=40) Q
  1.  .. S RCXVBLN=IEN,DFN=$P(^PRCA(430,IEN,0),U,7)
  1.  .. D FIL^RCXVDEQ("H")
  1.  ;
  1.  L -^RCXVTSK
  1.  ;
  1.  D EN
  1.  K RCXVDAT,RCFDATE,RCXVFFD,RCXVFTD,IEN,DFN,RCXVBLN
  1.  ;
  1.  Q
  1.  ;
  1. CUR ;  Find all current fiscal year bills
  1.  ;
  1.  L +^RCXVTSK:60 E  HANG 600 G CUR
  1.  ;
  1.  S TTYP=""
  1.  F  S TTYP=$O(^PRCA(433,"AT",TTYP)) Q:TTYP=""  D
  1.  . I '+$P(^PRCA(430.3,TTYP,0),U,6) Q
  1.  . S RDATE=RCXVFFD-.01
  1.  . F  S RDATE=$O(^PRCA(433,"AT",TTYP,RDATE)) Q:RDATE=""!(RDATE\1>RCXVFTD)  D
  1.  .. S IEN=""
  1.  .. F  S IEN=$O(^PRCA(433,"AT",TTYP,RDATE,IEN)) Q:IEN=""  D
  1.  ... S RCXVBLN=$P(^PRCA(433,IEN,0),U,2)
  1.  ... I RCXVBLN="" Q
  1.  ... S X=$P($G(^PRCA(430,RCXVBLN,0)),U,8)
  1.  ... I X=16!(X=40) Q
  1.  ... ; Line below changed for patch 228 to do FY05 extract
  1.  ... D FIL^RCXVDEQ("E")
  1.  ;
  1.  L -^RCXVTSK
  1.  ;
  1.  D EN
  1.  K TTYP,RDATE,RCXVFFD,RCXVFTD,RCXVBLN
  1.  Q
  1.  ;
  1. ACT ;  Active data extract
  1.  ;
  1.  L +^RCXVTSK:60 E  HANG 600 G ACT
  1.  ;
  1.  NEW STAT,CSTAT,QFL
  1.  ;  Set up the AR Data Queue for all 'Active' and 'Suspended' bills
  1.  F STAT=16,40 S IEN="" F  S IEN=$O(^PRCA(430,"AC",STAT,IEN)) Q:IEN=""  D
  1.  . S RCXVBLN=IEN,DFN=$P(^PRCA(430,IEN,0),U,7)
  1.  . I $P(^PRCA(430,IEN,0),U,2)="" Q
  1.  . S CSTAT=$P(^PRCA(430,IEN,0),U,8)
  1.  . I CSTAT'=STAT S QFL=0 D  Q:QFL
  1.  .. I CSTAT'=16!(CSTAT'=40) S QFL=1
  1.  . D FIL^RCXVDEQ("A")
  1.  ;
  1.  L -^RCXVTSK
  1.  ;
  1.  D EN
  1.  Q
  1.  ;
  1. ER ; Unlock and log error
  1.  L -^RCXVTSK
  1.  D ^%ZTER
  1.  D UNWIND^%ZTER
  1.  Q