Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RGUTOS1

RGUTOS1.m

Go to the documentation of this file. 
  1. RGUTOS ;CAIRO/DKM - Platform-dependent operations;12-Oct-1998 16:40;DKM
  1.  ;;2.1;RUN TIME LIBRARY;;Mar 22, 1999
  1.  ;=================================================================
  1.  ; Return version # of RTL
  1. VER() Q +$P($T(RGUTOS+1),";",3)
  1.  ; Set right margin
  1. RM(X) X ^%ZOSF("RM")
  1.  Q
  1.  ; Test for routine/tag
  1. TEST(X) N Z
  1.  S:X[U Z=$P(X,U),X=$P(X,U,2)
  1.  X ^%ZOSF("TEST")
  1.  Q $S('$T:0,$G(Z)="":1,Z'?.1"%"1.AN:0,1:$T(@Z^@X)'="")
  1.  ; Raise an exception
  1. RAISE(X) ZT $G(X)
  1.  ; Return code to set error trap
  1. TRAP(X) Q $$SUBST^RGUT(^%ZOSF("TRAP"),"X",""""_X_"""")
  1.  ; Check for $ET capability
  1. ETRAP() Q $$NEWERR^%ZTER
  1.  ; Open a file (extrinsic)
  1. OPENX(X1,X2) ;
  1.  D OPEN(.X1,.X2)
  1.  Q X1
  1.  ; Open a file
  1. OPEN(X1,X2) ;
  1.  N IO,POP,X3
  1.  D PARSE(.X1,.X3),OPEN^%ZISH(X3_X1,X3,X1,$G(X2,"R"),32767)
  1.  I POP ZT "OPEN"
  1.  S ^XTMP("RGHFS",$J,IO)=X3_X1,X1=IO
  1.  Q
  1.  ; Close a file
  1. CLOSE(X) N Y
  1.  S Y=$G(^XTMP("RGHFS",$J,X)),IO=X
  1.  K ^(X)
  1.  D CLOSE^%ZISH(Y)
  1.  Q
  1.  ; Close all open HFS
  1. CLOSEALL N Z
  1.  S Z=""
  1.  F  S Z=$O(^XTMP("RGHFS",$J,Z)) Q:Z=""  D CLOSE(Z)
  1.  Q
  1.  ; Parse out directory from filename
  1. PARSE(X,Y) ;
  1.  N D,Z
  1.  S D=$E($$DIRDLM,3),Z=$L(X,D),Y=$P(X,D,1,Z-1)_$S(Z>1:D,1:""),X=$P(X,D,Z)
  1.  Q
  1.  ; Read a line
  1. READ(X,Y) ;
  1.  N IO,%ZA,%ZB,%ZC,%ZL
  1.  S IO=$G(Y,$I)
  1.  D READNXT^%ZISH(.X)
  1.  U IO
  1.  Q $$STATUS^%ZISH&'$L(X)
  1.  ; Delete a file
  1. DELETE(X) ;
  1.  N Z
  1.  D PARSE(.X,.Z)
  1.  S Z(X)="",Z=$$DEL^%ZISH(Z,"Z")
  1.  Q
  1.  ; Rename a file
  1. RENAME(X1,X2) ;
  1.  N X3,X4
  1.  D PARSE(.X1,.X3),PARSE(.X2,.X4)
  1.  I $$MV^%ZISH(X3,X1,X4,X2)
  1.  Q
  1.  ; List files
  1. DIR(X1,X2,X3) ;
  1.  N Z
  1.  D PARSE(.X1,.Z)
  1.  S Z(X1)="",X3=$G(X3,"^UTILITY(""DIR"",$J)")
  1.  K @X3
  1.  I $$LIST^%ZISH(Z,"Z",X3)
  1.  Q
  1.  ; Force error if at EOF
  1. EOF I $$STATUS^%ZISH ZT "EOF"
  1.  Q
  1.  ; Returns true if current error is EOF
  1. EOFERR() Q $$EC^%ZOSV["EOF"
  1.  ; URL format filename-->HFS format
  1. CVTFN(RGFIL,RGROOT) ;
  1.  N RGZ,RGZ1,RGD
  1.  S RGD=$$DIRDLM,RGROOT=$G(RGROOT)
  1.  S:$E(RGROOT,$L(RGROOT))=$E(RGD,3) RGROOT=$E(RGROOT,1,$L(RGROOT)-1)
  1.  S RGZ=$L(RGFIL,"/"),RGZ1=$P(RGFIL,"/",1,RGZ-1),RGFIL=$P(RGFIL,"/",RGZ)
  1.  S:$L(RGZ1) RGROOT=RGROOT_$E(RGD,$S($L(RGROOT):2,1:1))_$TR(RGZ1,"/.-",$E(RGD,2))
  1.  Q RGROOT_$S($L(RGROOT):$E(RGD,3),1:"")_RGFIL
  1.  ; Return directory delimiters
  1. DIRDLM() N X
  1.  S X=$$PWD^%ZISH
  1.  Q $S(X["[":"[.]",X["\":"\\\",1:"///")
  1.  ; FTP file transfer
  1. FTP(X1,X2,X3,X4,X5,X6,X7) ;
  1.  D:$$VERSION^%ZOSV(1)["DSM" VMS^RGUTFTP(.X1,.X2,.X3,.X4,.X5,.X6,.X7)
  1.  Q
  1.  ; Parse error data
  1. ERR(X1,X2,X3) ;
  1.  N X
  1.  S X=$$EC^%ZOSV,X1=$$VERSION^%ZOSV(1)
  1.  G ERRMSM:X1["MSM",ERRDSM:X1["DSM"
  1.  S (X1,X2,X3)=""
  1.  Q
  1. ERRMSM S X1=$E($P(X,">"),2,99),X2=$P($P(X,">",2),":"),X3=X1
  1.  S:X2["*" X2=""
  1.  S:$E(X1)="Z" X3=$E(X1,2,99),X1="ZTRAP"
  1.  Q
  1. ERRDSM S X1=$P($P(X,", ",2),"-",3),X2=$P($P(X,", "),":"),X3=$$TRIM^RGUT($P(X,", ",$S(X1="ZTRAP":4,1:3)))
  1.  Q