Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RORHDT

RORHDT.m

Go to the documentation of this file. 
  1. RORHDT ;HCIOFO/SG - HISTORICAL DATA EXTRACTION ; 3/14/06 10:54am
  1.  ;;1.5;CLINICAL CASE REGISTRIES;**1**;Feb 17, 2006;Build 24
  1.  ;
  1.  ; RORHDT -------------- HISTORICAL DATA EXTRACTION DESCRIPTOR
  1.  ;
  1.  ; RORHDT("BHS")         If this node has a non-zero value, the
  1.  ;                       $$COMMIT^RORHDT05 function outputs a BHS
  1.  ;                       segment before writing the data from the
  1.  ;                       ^TMP("HLS",$J) node. Then it kills the
  1.  ;                       RORHDT("BHS") node.
  1.  ;
  1.  ; See also descriptions of the ^TMP("RORHDT") node in the ^ROR01
  1.  ; routine.
  1.  ;
  1.  Q
  1.  ;
  1.  ;***** (RE)CREATES A DATA EXTRACTION TASK TABLE
  1. CREATE ;
  1.  N RORERRDL      ; Default error location
  1.  N RORERROR      ; Error processing data
  1.  N RORPARM       ; Application parameters
  1.  ;
  1.  N HDEIEN,RC
  1.  S RORPARM("ERR")=1
  1.  ;S RORPARM("DEBUG")=2 ; Remove the first ';' to start in debug mode
  1.  D CLEAR^RORERR("CREATE^RORHDT")
  1.  ;--- Select a data extraction
  1.  S HDEIEN=$$SELHDE^RORHDTUT()  G:HDEIEN<0 ERROR
  1.  Q:'HDEIEN
  1.  ;--- Request a confirmation
  1.  S RC=$$CREATE^RORHDTAC(HDEIEN)
  1.  I RC  G:RC<0 ERROR  Q
  1.  ;--- Create a new task table
  1.  S RC=$$CREATE^RORHDT02(HDEIEN)    G:RC<0 ERROR
  1.  W:'RC !,"New task table has been created."
  1.  Q
  1.  ;
  1.  ;***** EDITS THE EXTRACTION DEFINITION
  1. EDITHDE ;
  1.  N DA,DIE,DIDEL,DR,DTOUT,NATIONAL
  1.  ;--- Select a data extraction
  1.  S DA=$$SELHDE^RORHDTUT("A",,.NATIONAL)  G:DA<0 ERROR
  1.  Q:'DA
  1.  ;--- Edit the parameters
  1.  S DIE=$$ROOT^DILFD(799.6)
  1.  S DR="[RORHDT EDIT "_$S(NATIONAL:"NATIONAL EXTRACT]",1:"EXTRACTION]")
  1.  W !  D ^DIE
  1.  Q
  1.  ;
  1.  ;***** DISPLAYS THE ERRORS
  1. ERROR ;
  1.  D DSPSTK^RORERR()
  1.  Q
  1.  ;
  1.  ;***** DISPLAYS THE LATEST LOG OF THE TASK
  1. LOG ;
  1.  N RORERRDL      ; Default error location
  1.  N RORERROR      ; Error processing data
  1.  N RORPARM       ; Application parameters
  1.  ;
  1.  N HDEIEN,POP,RC,TASKIEN
  1.  S RORPARM("ERR")=1
  1.  ;S RORPARM("DEBUG")=2 ; Remove the first ';' to start in debug mode
  1.  D CLEAR^RORERR("LOG^RORHDT")
  1.  ;--- Select data extraction and task
  1.  S HDEIEN=$$SELHDE^RORHDTUT()           G:HDEIEN<0 ERROR
  1.  Q:'HDEIEN
  1.  S TASKIEN=$$SELTASK^RORHDTUT(HDEIEN)  G:TASKIEN<0 ERROR
  1.  Q:'TASKIEN
  1.  ;--- Display the log
  1.  S RC=$$LOG^RORHDT01(HDEIEN,TASKIEN)        G:RC<0 ERROR
  1.  Q
  1.  ;
  1.  ;***** STARTS A DATA EXTRACTION TASK
  1. START ;
  1.  N RORERRDL      ; Default error location
  1.  N RORERROR      ; Error processing data
  1.  N RORPARM       ; Application parameters
  1.  ;
  1.  N FAM,HDEIEN,RC,SDT,TASKIEN
  1.  S RORPARM("ERR")=1
  1.  ;S RORPARM("DEBUG")=2 ; Remove the first ';' to start in debug mode
  1.  D CLEAR^RORERR("START^RORHDT")
  1.  ;--- Select data extraction and task
  1.  S HDEIEN=$$SELHDE^RORHDTUT()           G:HDEIEN<0 ERROR
  1.  Q:'HDEIEN
  1.  S TASKIEN=$$SELTASK^RORHDTUT(HDEIEN)  G:TASKIEN<0 ERROR
  1.  Q:'TASKIEN
  1.  ;--- Double-check the task status, and request confirmation(s)
  1.  ;--- and start date/time for the task from the user
  1.  S RC=$$START^RORHDTAC(HDEIEN,TASKIEN,.FAM,.SDT)
  1.  I RC  G:RC<0 ERROR  Q
  1.  ;--- Start the task
  1.  S RC=$$START^RORHDT03(HDEIEN,TASKIEN,FAM,SDT)  G:RC<0 ERROR
  1.  Q
  1.  ;
  1.  ;***** DISPLAYS DATA EXTRACTION STATUS
  1. STATUS ;
  1.  N RORERRDL      ; Default error location
  1.  N RORERROR      ; Error processing data
  1.  N RORPARM       ; Application parameters
  1.  ;
  1.  N DIR,HDEIEN,POP,RC,TMP
  1.  S RORPARM("ERR")=1
  1.  ;S RORPARM("DEBUG")=2 ; Remove the first ';' to start in debug mode
  1.  D CLEAR^RORERR("STATUS^RORHDT")
  1.  ;--- Select a data extraction
  1.  S HDEIEN=$$SELHDE^RORHDTUT()  G:HDEIEN<0 ERROR
  1.  Q:'HDEIEN
  1.  ;--- Display status of the data extraction
  1.  S RC=$$STATUS^RORHDT01(HDEIEN)
  1.  W !  D PAGE^RORHDTUT(),^%ZISC     G:RC<0 ERROR
  1.  Q
  1.  ;
  1.  ;***** STOPS A DATA EXTRACTION TASK
  1. STOP ;
  1.  N RORERRDL      ; Default error location
  1.  N RORERROR      ; Error processing data
  1.  N RORPARM       ; Application parameters
  1.  ;
  1.  N HDEIEN,RC,TASKIEN
  1.  S RORPARM("ERR")=1
  1.  ;S RORPARM("DEBUG")=2 ; Remove the first ';' to start in debug mode
  1.  D CLEAR^RORERR("STOP^RORHDT")
  1.  ;--- Select data extraction and task
  1.  S HDEIEN=$$SELHDE^RORHDTUT()           G:HDEIEN<0 ERROR
  1.  Q:'HDEIEN
  1.  S TASKIEN=$$SELTASK^RORHDTUT(HDEIEN)  G:TASKIEN<0 ERROR
  1.  Q:'TASKIEN
  1.  ;--- Stop the task
  1.  S RC=$$STOP^RORHDTAC(HDEIEN,TASKIEN)
  1.  I RC  G:RC<0 ERROR  Q
  1.  S RC=$$STOP^RORHDT03(HDEIEN,TASKIEN)       G:RC<0 ERROR
  1.  Q