Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RORLOG01

RORLOG01.m

Go to the documentation of this file. 
  1. RORLOG01 ;HCIOFO/SG - LOG FILE MANAGEMENT (UTILITIES) ; 1/17/06 10:09am
  1.  ;;1.5;CLINICAL CASE REGISTRIES;;Feb 17, 2006
  1.  ;
  1.  Q
  1.  ;
  1.  ;***** PROCESSES AN ACCESS VIOLATION ALERT
  1. ACLRTN ;
  1.  N I,PARAMS,RORBUF
  1.  ;--- Prepare the parameters
  1.  S (PARAMS("DUZ"),I)=+$P(XQADATA,U)
  1.  I I>0  D  K RORBUF
  1.  . S PARAMS("USERNAME")=$$GET1^DIQ(200,I_",",.01,,,"RORBUF")
  1.  S:$G(PARAMS("USERNAME"))="" PARAMS("USERNAME")="unknown user"
  1.  S PARAMS("DATETIME")=$$FMTE^XLFDT($P(XQADATA,U,2))
  1.  ;--- Generate the text of alert
  1.  D BLD^DIALOG(7980000.015,.PARAMS,,"RORBUF","S")
  1.  ;--- Display the alert details
  1.  S I=0  W !
  1.  F  S I=$O(RORBUF(I))  Q:I'>0  W !,RORBUF(I)
  1.  Q
  1.  ;
  1.  ;***** LOADS THE LOG SUBSYSTEM PARAMETERS
  1.  ;
  1.  ; .RORLST       Reference to a local array containing names
  1.  ;               of the registries to process (as subscripts).
  1.  ;
  1.  ; Return Values:
  1.  ;       <0  Error code
  1.  ;        0  Ok
  1.  ;
  1. PARAMS(RORLST) ;
  1.  N ENABLE,IENS,IR,IRS,RC,RORBUF,RORMSG,RORSB,SCR,TYPE
  1.  ;--- Load a list of parameters of active registries
  1.  S SCR="I '$P(^(0),U,7),$D(RORLST($P(^(0),U)))"
  1.  D LIST^DIC(798.1,,"@;8I","U","*",,,"B",SCR,,"RORBUF","RORMSG")
  1.  S RC=$$DBS^RORERR("RORMSG",-9)  Q:RC<0 RC
  1.  I '$G(RORBUF("DILIST",0))  S RORPARM("LOG")=1  Q 0
  1.  ;--- Process the list of log parameters
  1.  S IR="",RC=0
  1.  F  S IR=$O(RORBUF("DILIST","ID",IR))  Q:IR=""  D  Q:RC
  1.  . ;--- Check if the log is enabled
  1.  . Q:'$G(RORBUF("DILIST","ID",IR,8))
  1.  . S ENABLE=1
  1.  . ;--- Load a list of event types to log
  1.  . S IRS=","_RORBUF("DILIST",2,IR)_","  K RORSB
  1.  . D LIST^DIC(798.11,IRS,"@;.01I","U","*",,,"B",,,"RORSB","RORMSG")
  1.  . S RC=$$DBS^RORERR("RORMSG",-9)  Q:RC<0
  1.  . ;--- If there are no event types, log all events
  1.  . I '$G(RORSB("DILIST",0))  D  Q
  1.  . . K RORPARM("LOG")  S RC=1
  1.  . ;--- Process the list of event types
  1.  . S IRS=""
  1.  . F  S IRS=$O(RORSB("DILIST","ID",IRS))  Q:IRS=""  D
  1.  . . S TYPE=+$G(RORSB("DILIST","ID",IRS,.01))
  1.  . . S:TYPE RORPARM("LOG",TYPE)=1
  1.  S:$G(ENABLE) RORPARM("LOG")=1
  1.  ;--- If not all types of errors are recorded,
  1.  ;    enable recording of the type "Error"
  1.  S:$D(RORPARM("LOG"))>1 RORPARM("LOG",6)=1
  1.  Q $S(RC<0:RC,1:0)
  1.  ;
  1.  ;***** PURGES THE OLD LOGS
  1.  ;
  1.  ; [DKEEP]       Days to keep logs in the file (by default = 31)
  1.  ;
  1.  ; Return Values:
  1.  ;       <0  Error code
  1.  ;        0  Ok
  1.  ;
  1. PURGE(DKEEP) ;
  1.  N HDR,IEN,IR,RC,RORFDA,RORFROM,RORMSG
  1.  S RORFROM=$$FMADD^XLFDT($$DT^XLFDT,-$G(DKEEP,31))+1
  1.  S RC=0
  1.  F  D  Q:'$P($G(HDR),U,3)!(RC<0)
  1.  . K RORFDA,RORMSG
  1.  . ;--- Get the next 10 records
  1.  . D LIST^DIC(798.7,,"@","BU",10,.RORFROM,,"B",,,"RORFDA","RORMSG")
  1.  . S RC=$$DBS^RORERR("RORMSG",-9)  Q:RC<0
  1.  . ;--- Stop if no records left
  1.  . S HDR=$G(RORFDA("DILIST",0))  Q:'HDR
  1.  . ;--- Prepare the data
  1.  . S IR=""
  1.  . F  S IR=$O(RORFDA("DILIST",2,IR),-1)  Q:IR=""  D
  1.  . . S IEN=RORFDA("DILIST",2,IR)
  1.  . . ;--- Check if the cross-reference entries are valid
  1.  . . D XREFCHK(IEN)
  1.  . . ;--- Delete the log only if it is not referenced
  1.  . . S:'$D(^RORDATA(798.7,"AREF",IEN)) RORFDA(798.7,IEN_",",.01)="@"
  1.  . K RORFDA("DILIST")
  1.  . Q:$D(RORFDA)<10
  1.  . ;--- Delete the records
  1.  . D FILE^DIE(,"RORFDA","RORMSG")
  1.  . S RC=$$DBS^RORERR("RORMSG",-9,,,798.7)
  1.  Q $S(RC<0:RC,1:0)
  1.  ;
  1.  ;***** CHECK IF THE LOG IS REALLY REFERENCED
  1.  ;
  1.  ; LOGIEN        IEN of the log
  1.  ;
  1. XREFCHK(LOGIEN) ;
  1.  N FIELD,FILE,IENS,NODE,RORMSG,TMP
  1.  S NODE=$NA(^RORDATA(798.7,"AREF",IEN))
  1.  S FILE=""
  1.  F  S FILE=$O(@NODE@(FILE))  Q:FILE=""  D
  1.  . S IENS=""
  1.  . F  S IENS=$O(@NODE@(FILE,IENS))  Q:IENS=""  D
  1.  . . S FIELD=""
  1.  . . F  S FIELD=$O(@NODE@(FILE,IENS,FIELD))  Q:FIELD=""  D
  1.  . . . S TMP=+$$GET1^DIQ(FILE,IENS,FIELD,"I",,"RORMSG")
  1.  . . . K:TMP'=LOGIEN @NODE@(FILE,IENS,FIELD)
  1.  Q