Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RORRP007

RORRP007.m

Go to the documentation of this file. 
  1. RORRP007 ;HCIOFO/SG - RPC: LOGS & MESSAGES ; 11/4/05 8:56am
  1.  ;;1.5;CLINICAL CASE REGISTRIES;;Feb 17, 2006
  1.  ;
  1.  Q
  1.  ;
  1.  ;***** LOADS THE LOG INFORMATION INTO THE BUFFER
  1.  ;
  1.  ; IEN           Log IEN
  1.  ;
  1.  ; ROR8DST       Closed root of the destination buffer
  1.  ;
  1.  ; [[.]OFFSET]   Offset in the buffer (modified by the function
  1.  ;               if passed by reference)
  1.  ;
  1.  ; Return Values:
  1.  ;       <0  Error code
  1.  ;        0  Ok
  1.  ;       >0  Skip the log
  1.  ;
  1. LOAD(IEN,ROR8DST,OFFSET) ;
  1.  N BUF,IENS,IENS1,RORBUF,RORMSG
  1.  S IENS=IEN_","  K RORBUF
  1.  D GETS^DIQ(798.7,IENS,RORFLDS,"EI","RORBUF","RORMSG")
  1.  Q:$G(DIERR) 1
  1.  ;--- Skip the 'Access Violation' activities
  1.  Q:$G(RORBUF(798.7,IENS,1,"I"))=6 2
  1.  S BUF="L^"_IEN
  1.  ;--- Activity (external)
  1.  S $P(BUF,"^",3)=$G(RORBUF(798.7,IENS,1,"E"))
  1.  ;--- Activity (internal)
  1.  S $P(BUF,"^",4)=$G(RORBUF(798.7,IENS,1,"I"))
  1.  ;--- Start Date/Time
  1.  S $P(BUF,"^",5)=$G(RORBUF(798.7,IENS,.01,"E"))
  1.  ;--- Contains messages
  1.  S $P(BUF,"^",6)=($O(^RORDATA(798.7,IEN,2,0))>0)
  1.  ;--- Job Number
  1.  S $P(BUF,"^",7)=$G(RORBUF(798.7,IENS,2,"E"))
  1.  ;--- End Date/Time
  1.  S $P(BUF,"^",8)=$G(RORBUF(798.7,IENS,5,"E"))
  1.  ;--- Number of Processed Patients
  1.  S $P(BUF,"^",9)=$G(RORBUF(798.7,IENS,6.01,"E"))
  1.  ;--- Number of Patients with Errors
  1.  S $P(BUF,"^",10)=$G(RORBUF(798.7,IENS,6.02,"E"))
  1.  ;--- Processing Rate
  1.  S $P(BUF,"^",11)=$G(RORBUF(798.7,IENS,6.03,"E"))
  1.  ;--- Task Number
  1.  S $P(BUF,"^",12)=$G(RORBUF(798.7,IENS,8,"I"))
  1.  ;--- Add the log descriptor to the output
  1.  S OFFSET=$G(OFFSET)+1,@ROR8DST@(OFFSET)=BUF
  1.  ;--- Load the list of registries
  1.  S IENS1=""
  1.  F  S IENS1=$O(RORBUF(798.73,IENS1))  Q:IENS1=""  D
  1.  . S BUF="R^"_$G(RORBUF(798.73,IENS1,.01,"I"))
  1.  . S $P(BUF,"^",3)=$G(RORBUF(798.73,IENS1,.01,"E"))
  1.  . ;--- Add the registry descriptor to the output
  1.  . S OFFSET=OFFSET+1,@ROR8DST@(OFFSET)=BUF
  1.  ;---Add the 'End of log' marker
  1.  S OFFSET=OFFSET+1,@ROR8DST@(OFFSET)="L^END"
  1.  Q 0
  1.  ;
  1.  ;***** RETURNS THE LOG INFORMATION
  1.  ; RPC: [ROR LOG INFO]
  1.  ;
  1.  ; .RORRES       Reference to a local variable where the results
  1.  ;               are returned to.
  1.  ;
  1.  ; LOGIEN        Log IEN
  1.  ;
  1.  ; Return Values:
  1.  ;
  1.  ; A negative value of the first "^"-piece of the RORRES(0) indicates
  1.  ; an error (see the RPCSTK^RORERR procedure for more details).
  1.  ;
  1.  ; Otherwise, either 0 (the log does not exist) or 1 is returned
  1.  ; in the RORRES(0) and the subsequent nodes of the RORRES array
  1.  ; contain the log information.
  1.  ; 
  1.  ; RORRES(0)             0 or 1
  1.  ;
  1.  ; RORRES(i)             See description of the LOGLIST^RORRP007
  1.  ;
  1. LOGINFO(RORRES,LOGIEN) ;
  1.  N RC,RORFLDS
  1.  ;--- Initialize the variables
  1.  K RORRES  S RORRES(0)=0
  1.  S RORFLDS=".01;1;2;3*;5;6.01;6.02;6.03;8"
  1.  ;--- Check the parameters
  1.  S LOGIEN=+$G(LOGIEN)  Q:LOGIEN'>0
  1.  Q:'$D(^RORDATA(798.7,LOGIEN,0))
  1.  ;--- Load the log information
  1.  S RC=$$LOAD(LOGIEN,"RORRES")
  1.  ;--- Check for the errors
  1.  I 'RC  S RORRES(0)=1
  1.  E  D:RC<0 RPCSTK^RORERR(.RORRES,RC)
  1.  Q
  1.  ;
  1.  ;***** RETURNS THE LIST OF LOGS
  1.  ; RPC: [ROR LOG GET LIST]
  1.  ;
  1.  ; .RESULTS      Reference to a local variable where the results
  1.  ;               are returned to.
  1.  ;
  1.  ; REGIEN        Registry IEN
  1.  ;
  1.  ; [STDT]        Start date (by default, from the earliest log)
  1.  ; [ENDT]        End date (by default, to the latest log)
  1.  ;
  1.  ; Return Values:
  1.  ;
  1.  ; A negative value of the first "^"-piece of the RESULTS(0) indicates
  1.  ; an error (see the RPCSTK^RORERR procedure for more details).
  1.  ;
  1.  ; Otherwise, number of logs is returned in the @RESULTS@(0) and the
  1.  ; subsequent nodes of the RESULTS array contain the logs.
  1.  ; 
  1.  ; @RESULTS@(0)          Number of logs
  1.  ;
  1.  ; @RESULTS@(i)          Log descriptor
  1.  ;                         ^01: "L"
  1.  ;                         ^02: Log IEN
  1.  ;                         ^03: Activity (external)
  1.  ;                         ^04: Activity (internal)
  1.  ;                         ^05: Start Date/Time (external)
  1.  ;                         ^06: Contains messages (0/1)
  1.  ;                         ^07: Job Number
  1.  ;                         ^08: End Date/Time (external)
  1.  ;                         ^09: Number of Processed Patients
  1.  ;                         ^10: Number of Patients with Errors
  1.  ;                         ^11: Processing Rate
  1.  ;                         ^12: Task Number (optional)
  1.  ;
  1.  ; @RESULTS@(...)        Registry descriptor (optional)
  1.  ;                         ^01: "R"
  1.  ;                         ^02: Registry IEN
  1.  ;                         ^03: Registry Name
  1.  ;
  1.  ; @RESULTS@(i+n)        'End of log' marker
  1.  ;                         ^01: "L"
  1.  ;                         ^02: "END"
  1.  ;
  1. LOGLIST(RESULTS,REGIEN,STDT,ENDT) ;
  1.  N CNT,DATE,IEN,RORFLDS,RC,XREF
  1.  D CLEAR^RORERR("LOGLIST^RORRP007",1)
  1.  S RORFLDS=".01;1;2;3*;5;6.01;6.02;6.03;8"
  1.  ;--- Check the parameters
  1.  I $G(REGIEN)'>0  D  D RPCSTK^RORERR(.RESULTS,RC)  Q
  1.  . S RC=$$ERROR^RORERR(-88,,,,"REGIEN",$G(REGIEN))
  1.  S REGIEN=+REGIEN,STDT=$G(STDT)\1,ENDT=$G(ENDT)\1
  1.  S ENDT=$S(ENDT>0:$$FMADD^XLFDT(ENDT,1),1:9999999)
  1.  ;--- Initialize the variables
  1.  S XREF=$NA(^RORDATA(798.7,"ARD",REGIEN)),CNT=0
  1.  K RESULTS  S RESULTS=$$ALLOC^RORTMP()
  1.  ;--- Browse through the logs
  1.  S CNT("L")=0,DATE=ENDT
  1.  F  S DATE=$O(@XREF@(DATE),-1)  Q:DATE=""  Q:DATE<STDT  D
  1.  . S IEN=""
  1.  . F  S IEN=$O(@XREF@(DATE,IEN),-1)  Q:IEN=""  D
  1.  . . S RC=$$LOAD(IEN,RESULTS,.CNT)
  1.  . . S:'RC CNT("L")=CNT("L")+1
  1.  ;--- Number of logs
  1.  S @RESULTS@(0)=CNT("L")
  1.  Q
  1.  ;
  1.  ;***** RETURNS THE LIST OF MESSAGES
  1.  ; RPC: [ROR LOG GET MESSAGES]
  1.  ;
  1.  ; .RESULTS      Reference to a local variable where the results
  1.  ;               are returned to.
  1.  ;
  1.  ; LOGIEN        IEN of the log
  1.  ;
  1.  ; Return Values:
  1.  ;
  1.  ; A negative value of the first "^"-piece of the RESULTS(0) indicates
  1.  ; an error (see the RPCSTK^RORERR procedure for more details).
  1.  ;
  1.  ; Otherwise, number of messages is returned in the RESULTS(0) and
  1.  ; the subsequent nodes of the RESULTS array contain the messages.
  1.  ;
  1.  ; @RESULTS@(0)          Number of messages
  1.  ;
  1.  ; @RESULTS@(i)          Message descriptor
  1.  ;                         ^01: "M"
  1.  ;                         ^02: Message IENS
  1.  ;                         ^03: Type (external)
  1.  ;                         ^04: Type (internal)
  1.  ;                         ^05: Date/Time (external)
  1.  ;                         ^06: Has Additional Info (0/1)
  1.  ;                         ^07: Patient Name
  1.  ;                         ^08: Patient IEN (DFN)
  1.  ;
  1.  ; @RESULTS@(i+1)        Message
  1.  ;                         ^01: "T"
  1.  ;                         ^02: Message Text
  1.  ;
  1.  ; @RESULTS@(...)        Line of the ADDITIONAL INFO text
  1.  ;                         ^01: "A"
  1.  ;                         ^02: Text
  1.  ;                         
  1.  ; @RESULTS@(i+n)        'End of message' marker
  1.  ;                         ^01: "M"
  1.  ;                         ^02: "END"
  1.  ;
  1. MSGLIST(RESULTS,LOGIEN) ;
  1.  N CNT,I,IEN,IENS,RC,ROOT,RORBUF,RORMSG
  1.  D CLEAR^RORERR("MESSAGE^RORRP007",1)
  1.  ;--- Check the parameters
  1.  I $G(LOGIEN)'>0  D  D RPCSTK^RORERR(.RESULTS,RC)  Q
  1.  . S RC=$$ERROR^RORERR(-88,,,,"LOGIEN",$G(LOGIEN))
  1.  S LOGIEN=+LOGIEN
  1.  ;--- Initialize the variables
  1.  S ROOT=$$ROOT^DILFD(798.7,,1),CNT=0
  1.  K RESULTS  S RESULTS=$$ALLOC^RORTMP()
  1.  ;--- Browse through the messages
  1.  S (CNT("M"),IEN)=0
  1.  F  S IEN=$O(@ROOT@(LOGIEN,2,IEN))  Q:IEN'>0  D
  1.  . S IENS=IEN_","_LOGIEN_","  K RORBUF
  1.  . ;--- Load the message details
  1.  . D GETS^DIQ(798.74,IENS,".01;1;2;3;4","EI","RORBUF","RORMSG")
  1.  . Q:$G(DIERR)
  1.  . S BUF="M^"_IENS
  1.  . ;--- Type (external)
  1.  . S $P(BUF,"^",3)=$G(RORBUF(798.74,IENS,1,"E"))
  1.  . ;--- Type (Internal)
  1.  . S $P(BUF,"^",4)=$G(RORBUF(798.74,IENS,1,"I"))
  1.  . ;--- Date/Time
  1.  . S $P(BUF,"^",5)=$G(RORBUF(798.74,IENS,.01,"E"))
  1.  . ;--- Has Additional Info
  1.  . S $P(BUF,"^",6)=($D(RORBUF(798.74,IENS,4))>1)
  1.  . ;--- Patient Name
  1.  . S $P(BUF,"^",7)=$G(RORBUF(798.74,IENS,3,"E"))
  1.  . ;--- Patient IEN (DFN)
  1.  . S $P(BUF,"^",8)=$G(RORBUF(798.74,IENS,3,"I"))
  1.  . ;--- Add the descriptor to the output
  1.  . S CNT=CNT+1,@RESULTS@(CNT)=BUF
  1.  . ;--- Add the message text to the output
  1.  . S CNT=CNT+1,@RESULTS@(CNT)="T^"_$G(RORBUF(798.74,IENS,2,"E"))
  1.  . ;--- Append the ADDITIONAL INFO
  1.  . S I=0
  1.  . F  S I=$O(RORBUF(798.74,IENS,4,I))  Q:'I  D
  1.  . . S CNT=CNT+1,@RESULTS@(CNT)="A^"_RORBUF(798.74,IENS,4,I)
  1.  . ;---Add the 'End of message' marker
  1.  . S CNT=CNT+1,@RESULTS@(CNT)="M^END"
  1.  . S CNT("M")=CNT("M")+1
  1.  ;--- Number of messages
  1.  S @RESULTS@(0)=CNT("M")
  1.  Q