Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RORX016A

RORX016A.m

Go to the documentation of this file. 
  1. RORX016A ;HOIFO/BH,SG,VAC - OUTPATIENT UTILIZATION (QUERY) ;4/7/09 2:10pm
  1.  ;;1.5;CLINICAL CASE REGISTRIES;**8,13,19,31,39**;Feb 17, 2006;Build 4
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ;
  1.  ; #557          Read access to the file #40.7 (controlled)
  1.  ; #2548         APIs in routine SDQ: ACRP Interface Toolkit (supported)
  1.  ; #10103        FMADD^XLFDT (supported)
  1.  ;
  1.  ;******************************************************************************
  1.  ;******************************************************************************
  1.  ;                 --- ROUTINE MODIFICATION LOG ---
  1.  ;        
  1.  ;PKG/PATCH    DATE        DEVELOPER    MODIFICATION
  1.  ;-----------  ----------  -----------  ----------------------------------------
  1.  ;ROR*1.5*8    MAR 2010    V CARR       Modified to handle ICD9 filter for
  1.  ;                                      'include' or 'exclude'.
  1.  ;ROR*1.5*13   DEC 2010    A SAUNDERS   User can select specific patients
  1.  ;ROR*1.5*19   FEB 2012    J SCOTT      Support for ICD-10 Coding System
  1.  ;ROR*1.5*31   MAY 2017    S ALSAHHAR   Adding AGE/DOB as additional identifiers.
  1.  ;ROR*1.5*39   JUN 2021    F TRAXLER    Replace real SSN with zeroes.
  1.  ;******************************************************************************
  1.  ;******************************************************************************
  1.  Q
  1.  ;
  1.  ;***** LOADS AND PROCESSES THE OUTPATIENT DATA
  1.  ;
  1.  ; RORDFN        Patient IEN (in file #2)
  1.  ;
  1.  ; Return Values:
  1.  ;       <0  Error code
  1.  ;        0  Ok
  1.  ;       >0  Number of non-fatal errors
  1.  ;
  1. OPDATA(RORDFN) ;
  1.  N QUERY,RORDST,RORECNT
  1.  S RORDST=$NA(^TMP("RORX016",$J))
  1.  D OPEN^SDQ(.QUERY)
  1.  D INDEX^SDQ(.QUERY,"PATIENT/DATE","SET")
  1.  D PAT^SDQ(.QUERY,RORDFN,"SET")
  1.  D DATE^SDQ(.QUERY,RORSDT,ROREDT1,"SET")
  1.  D SCANCB^SDQ(.QUERY,"D SCAN^RORX016A(Y,Y0)","SET")
  1.  D ACTIVE^SDQ(.QUERY,"TRUE","SET")
  1.  D SCAN^SDQ(.QUERY,"FORWARD")
  1.  D CLOSE^SDQ(.QUERY)
  1.  Q +$G(RORECNT)
  1.  ;
  1.  ;***** QUERIES THE REGISTRY
  1.  ;
  1.  ; FLAGS         Flags for the $$SKIP^RORXU005
  1.  ;
  1.  ; Return Values:
  1.  ;       <0  Error code
  1.  ;        0  Ok
  1.  ;       >0  Number of non-fatal errors
  1.  ;
  1. QUERY(FLAGS) ;
  1.  N ROREDT1       ; Day after the end date
  1.  N RORLAST4      ; Last 4 digits of the current patient's SSN
  1.  N RORPNAME      ; Name of the current patient
  1.  N RORPTN        ; Number of patients in the registry
  1.  ;
  1.  N CNT,ECNT,IEN,IENS,PATIEN,RC,TMP,VA,VADM,XREFNODE,AGE,AGETYPE
  1.  N RCC,FLAG
  1.  S XREFNODE=$NA(^RORDATA(798,"AC",+RORREG))
  1.  S RORPTN=$$REGSIZE^RORUTL02(+RORREG)  S:RORPTN<0 RORPTN=0
  1.  S ROREDT1=$$FMADD^XLFDT(ROREDT,1)
  1.  S (CNT,ECNT,RC)=0
  1.  ;--- Browse through the registry records
  1.  S IEN=0
  1.  S FLAG=$G(RORTSK("PARAMS","ICDFILT","A","FILTER"))
  1.  F  S IEN=$O(@XREFNODE@(IEN))  Q:IEN'>0  D  Q:RC<0
  1.  . S TMP=$S(RORPTN>0:CNT/RORPTN,1:"")
  1.  . S RC=$$LOOP^RORTSK01(TMP)  Q:RC<0
  1.  . S IENS=IEN_",",CNT=CNT+1
  1.  . ;--- Get the patient DFN
  1.  . S PATIEN=$$PTIEN^RORUTL01(IEN)  Q:PATIEN'>0
  1.  . ;--- Check for patient list and quit if not in list
  1.  . I $D(RORTSK("PARAMS","PATIENTS","C")),'$D(RORTSK("PARAMS","PATIENTS","C",PATIEN)) Q
  1.  . ;--- Check if the patient should be skipped
  1.  . Q:$$SKIP^RORXU005(IEN,FLAGS,RORSDT,ROREDT)
  1.  . ;--- Check the patient against the ICD Filter
  1.  . S RCC=0
  1.  . I FLAG'="ALL" D
  1.  . . S RCC=$$ICD^RORXU010(PATIEN)
  1.  . I (FLAG="INCLUDE")&(RCC=0) Q
  1.  . I (FLAG="EXCLUDE")&(RCC=1) Q
  1.  . ;--- End of ICD Filter check
  1.  . ;
  1.  . ;--- Get the patient's data
  1.  . D VADEM^RORUTL05(PATIEN,1)
  1.  . S RORPNAME=VADM(1),(RORLAST4,VA("BID"))="0000" ;VA("BID")
  1.  . S AGETYPE=$$PARAM^RORTSK01("AGE_RANGE","TYPE")
  1.  . S AGE=$S(AGETYPE="AGE":$P(VADM(4),U),AGETYPE="DOB":$$DATE^RORXU002($P(VADM(3),U)\1),1:"")
  1.  . ;
  1.  . ;--- Get the outpatient data
  1.  . S RC=$$OPDATA(PATIEN)
  1.  . I RC  S ECNT=ECNT+1  Q:RC<0
  1.  . ;
  1.  . ;--- Calculate intermediate totals
  1.  . S RC=$$TOTALS^RORX016B(PATIEN,AGE)
  1.  . I RC  S ECNT=ECNT+1  Q:RC<0
  1.  ;---
  1.  Q $S(RC<0:RC,1:ECNT)
  1.  ;
  1.  ;***** CALLBACK ENTRY POINT FOR ACRP API
  1. SCAN(Y,Y0) ;
  1.  N DTX,STOP,TMP
  1.  ;--- Check the division list
  1.  S TMP=$$PARAM^RORTSK01("DIVISIONS","ALL")
  1.  I 'TMP  Q:'$D(RORTSK("PARAMS","DIVISIONS","C",+$P(Y0,U,11)))
  1.  ;--- Data comes from the OUTPATIENT ENCOUNTER file (409.68)
  1.  S STOP=$P($G(^DIC(40.7,+$P(Y0,U,3),0)),U,2),DTX=Y0\1
  1.  S:STOP="" STOP="NSC"
  1.  S @RORDST@("OP",RORDFN,DTX)=$G(@RORDST@("OP",RORDFN,DTX))+1
  1.  S @RORDST@("OP",RORDFN,DTX,STOP)=$G(@RORDST@("OP",RORDFN,DTX,STOP))+1
  1.  Q