Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCDXPOV3

SCDXPOV3.m

Go to the documentation of this file. 
  1. SCDXPOV3 ; ALB/SCK - VISIT REPORT BY NPCDB TRANSMISSION STATUS ; 05 Oct 98  8:38 PM
  1.  ;;5.3;Scheduling;**73,159,173**;AUG 13, 1993
  1.  Q
  1. VISIT(SCXDT,SCXP,SCXE,SCXET,SCXV,SCXC) ; Update visit count for this encounter
  1.  ;   Input:
  1.  ;      SCXDT - Visit date
  1.  ;      SCXP  - Patients DFN
  1.  ;      SCXE  - Vet Eligibility status of encounter
  1.  ;      SCXET - Vet. or Non-Vet status
  1.  ;      SCXV  - Category of visit
  1.  ;      SCXC  - C&P status of encounter
  1.  ;
  1.  ;   Variables:
  1.  ;      SCHL  - Current Hierarchy level
  1.  ;      L1    - Local variable
  1.  ;
  1.  N L1,SCHL
  1.  ;
  1.  I $D(^TMP("SCDXV",$J,"ELG",SCXDT,SCXP)) D
  1.  . S SCHL=$P(^TMP("SCDXV",$J,"ELG",SCXDT,SCXP),U,3)
  1.  . S L1=$$ELGPRI^SCDXPOV2(SCXE,SCHL)
  1.  . S:$P(L1,U,2) ^TMP("SCDXV",$J,"ELG",SCXDT,SCXP)=SCXE_U_SCXET_U_$P(L1,U)
  1.  E  S ^TMP("SCDXV",$J,"ELG",SCXDT,SCXP)=SCXE_U_SCXET_U_$P($$ELGPRI^SCDXPOV2(SCXE,0),U)
  1.  ;
  1.  I $D(^TMP("SCDXV",$J,"COV",SCXDT,SCXP)) D
  1.  . S SCHL=$P(^TMP("SCDXV",$J,"COV",SCXDT,SCXP),U,2)
  1.  . S L1=$$COVPRI^SCDXPOV2(SCXV,SCHL)
  1.  . S:$P(L1,U,2) ^TMP("SCDXV",$J,"COV",SCXDT,SCXP)=SCXV_U_$P(L1,U)
  1.  E  S ^TMP("SCDXV",$J,"COV",SCXDT,SCXP)=SCXV_U_$P($$COVPRI^SCDXPOV2(SCXV,0),U)
  1.  ;
  1.  I SCXC,'$D(^TMP("SCDXV",$J,"CP",SCXDT,SCXP)) D
  1.  . S ^TMP("SCDXV",$J,"CP",SCXDT,SCXP)=1
  1.  Q
  1.  ;
  1. WRT ;  Call procedures to initialize report data global, build the report global, and then print the report.
  1.  ;
  1.  ;   Variables
  1.  ;        DVN   -  Facility number from VASITE
  1.  ;        DNAME -  Facility name from VASITE
  1.  ;
  1.  N SDBDASH,SDASH,DNAME,DVN
  1.  S $P(SDBDASH,"=",75)="",$P(SDASH,"-",15)=""
  1.  U IO
  1.  ;
  1.  S DVN=$P($$SITE^VASITE(SCXBEG),U,3),DNAME=$P($$SITE^VASITE(SCXBEG),U,2)
  1.  D INIT^SCDXPOV("VISITS"),BLDRPT,VISRPT
  1.  Q
  1.  ;
  1. BLDRPT ;  Build data global for report.  Order through date/patient TMP global, and count the number of unique
  1.  ;  visits.  Increment the appropriate report data global.
  1.  ;
  1.  ;    Variables
  1.  ;        SCXDT -  Date the Visit occurred (Encounter date)
  1.  ;        SCXP  -  DFN of patient for this encounter 
  1.  ;        SCX   -  Node of TMP global visits are being counted from
  1.  ;        LV1   -  Local variable for incremneting report data global
  1.  ;
  1.  N SCXDT,SCXP,SCX,LV1
  1.  S SCXDT=""
  1.  ;     Count visits for Vet./Non-Vet. eligibility 
  1.  F  S SCXDT=$O(^TMP("SCDXV",$J,"ELG",SCXDT)) Q:SCXDT'>0  D
  1.  . S SCXP="" F  S SCXP=$O(^TMP("SCDXV",$J,"ELG",SCXDT,SCXP)) Q:'SCXP  D
  1.  .. S SCX=^TMP("SCDXV",$J,"ELG",SCXDT,SCXP)
  1.  .. S LV1=$P($G(^TMP("SCDXPOV",$J,"VISITS",$S($P(SCX,U,2)="Y":"VELIG",1:"NVELIG"),$P(SCX,U))),U)
  1.  .. S $P(^TMP("SCDXPOV",$J,"VISITS",$S($P(SCX,U,2)="Y":"VELIG",1:"NVELIG"),$P(SCX,U)),U)=LV1+1
  1.  ;
  1.  ;    Count visits for Category of Visit.
  1.  F  S SCXDT=$O(^TMP("SCDXV",$J,"COV",SCXDT)) Q:SCXDT'>0  D
  1.  . S SCXP="" F  S SCXP=$O(^TMP("SCDXV",$J,"COV",SCXDT,SCXP)) Q:'SCXP  D
  1.  .. S LV1=$P(^TMP("SCDXPOV",$J,"VISITS","COV",$P(^TMP("SCDXV",$J,"COV",SCXDT,SCXP),U)),U)
  1.  .. S $P(^TMP("SCDXPOV",$J,"VISITS","COV",$P(^TMP("SCDXV",$J,"COV",SCXDT,SCXP),U)),U)=LV1+1
  1.  ;
  1.  ;    Count visits with a type of appt. of C&P
  1.  F  S SCXDT=$O(^TMP("SCDXV",$J,"CP",SCXDT)) Q:SCXDT'>0  D
  1.  . S SCXP="" F  S SCXP=$O(^TMP("SCDXV",$J,"CP",SCXDT,SCXP)) Q:'SCXP  D
  1.  .. S $P(^TMP("SCDXPOV",$J,"VISITS","CP"),U)=$P(^TMP("SCDXPOV",$J,"VISITS","CP"),U)+1
  1.  Q
  1.  ;
  1. VISRPT ;  Print body of the Visit report consolidated by number of visits.
  1.  ;
  1.  ;     Variables
  1.  ;        SBTT     - Subtotal of categories
  1.  ;        NUM      - local counting variable
  1.  ;        SCDXABRT - Abort Printing (Screen only)
  1.  ;
  1.  N NUM,SBTT,L1
  1.  ;
  1.  D HDR
  1.  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  W !,?5,"VETERAN ELIGIBILITY",!
  1.  S (NUM,SBTT)=0
  1.  F  S NUM=$O(^TMP("SCDXPOV",$J,"VISITS","VELIG",NUM)) Q:'NUM  D  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  . W !?8,$P(^DIC(8,NUM,0),U),?45,$J($P(^TMP("SCDXPOV",$J,"VISITS","VELIG",NUM),U),6)
  1.  . S SBTT=+$G(SBTT)+$P(^TMP("SCDXPOV",$J,"VISITS","VELIG",NUM),U)
  1.  ;
  1.  W !?42,SDASH,!,?5,"Veteran Sub-Total",?45,$J(SBTT,6)
  1.  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  ;
  1.  W !!,?5,"NON-VETERAN ELIGIBILITY",!
  1.  S (NUM,SBTT)=0
  1.  F  S NUM=$O(^TMP("SCDXPOV",$J,"VISITS","NVELIG",NUM)) Q:'NUM  D  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  . W !?8,$P(^DIC(8,NUM,0),U),?45,$J($P(^TMP("SCDXPOV",$J,"VISITS","NVELIG",NUM),U),6)
  1.  . S SBTT=+$G(SBTT)+$P(^TMP("SCDXPOV",$J,"VISITS","NVELIG",NUM),U)
  1.  ;
  1.  W !?42,SDASH,!,?5,"Non-Veteran Sub-Total",?45,$J(SBTT,6)
  1.  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  ;
  1.  W !!,?5,"CATEGORY OF VISIT",!
  1.  S (NUM,SBTT)=0
  1.  F  S NUM=$O(^TMP("SCDXPOV",$J,"VISITS","COV",NUM)) Q:'NUM  D  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  . W !?8,$P($T(VISIT+NUM^SCDXPOV1),";",3),?45,$J($P(^TMP("SCDXPOV",$J,"VISITS","COV",NUM),U),6)
  1.  . S SBTT=+$G(SBTT)+$P(^TMP("SCDXPOV",$J,"VISITS","COV",NUM),U)
  1.  ;
  1.  W !?42,SDASH,!,?5,"Category Sub-Total",?45,$J(SBTT,6)
  1.  I $Y>(IOSL-8) D NEWPAGE G:SCXABRT VISQ
  1.  ;
  1.  W !!,?8,"Compensation and Penison appointments are included in the above",!?8,"categories and totals and are shown here for information only"
  1.  W !!?8,"COMPENSATION AND PENSION",?45,$J($P(^TMP("SCDXPOV",$J,"VISITS","CP"),U),6)
  1.  ;
  1. VISQ Q
  1.  ;
  1. HDR ;  Print the report header
  1.  ;  Variables
  1.  ;     LINEOUT - Message line for header
  1.  ;     END     - Timeout or Uparrow flag for read
  1.  ;
  1.  N END,LINEOUT,LL,HD1,HD2
  1.  ;
  1.  W @IOF
  1.  S HD2="VISIT REPORT FOR ACTIVITY TRANSMITTED TO NPCDB"
  1.  W !?(IOM-$L(HD2))/2,HD2
  1.  S HD1="FOR PERIOD "
  1.  S Y=SCXBEG D DTS^SDUTL
  1.  S HD1=HD1_Y_" THRU "
  1.  S Y=SCXEND D DTS^SDUTL
  1.  S HD1=HD1_Y
  1.  W !?2,"Facility: "_DNAME,?(IOM-$L(HD1))-5,HD1
  1.  W !!
  1.  F LL=0:1 S LINEOUT=$P($T(MSG+(LL+1)),";;",2) Q:LINEOUT["$$END"  W !?8,LINEOUT
  1.  W !!?48,"VISITS"
  1.  W !,SDBDASH
  1.  Q
  1.  ;
  1. NEWPAGE ;
  1.  N LL
  1.  I IOST?1"C-".E S DIR(0)="E" D ^DIR S SCXABRT='+$G(Y) D CLEAR^SCDXPOV2
  1.  ;W !," Press RETURN to continue or '^' to exit: " R LL:DTIME S SCXABRT='$T!(LL="^")
  1.  I 'SCXABRT D HDR
  1.  Q
  1.  ;
  1. MSG ;
  1.  ;;*NOTE*  This section consolidates all encounters into visits, where
  1.  ;;one visit is all encounters for a patient on a single day.  For
  1.  ;;example, three encounters for a patient on one day, is one visit.  
  1.  ;;$$END