Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCMCTPM

SCMCTPM.m

Go to the documentation of this file. 
  1. SCMCTPM ;ALB/REW - Patient Position Changes MailMessages ; 26 Mar 1996
  1.  ;;5.3;Scheduling;**41,45,48,87,100,130**;AUG 13, 1993
  1.  ;1
  1. MAIL ;Do Patient Team Changes MailMan Message
  1.  ; - called by SCMC PT TEAM CHANGES MAIL MESSAGE protocol
  1.  G:$G(SCNOMAIL) END  ;- flag can be set to stop message generation
  1.  N XMDUZ,XMY,XMSUB,XMTEXT,VA,VAERR,XMZ,Y,ZTQUEUED
  1.  N SCTMAR,SCSTAT,DFN,SCNODE,SCY,SCSPACE,SCPAD,SCTPXM,SCLNCNT,SCTPDT,SCPTNM
  1.  S ZTQUEUED=1
  1.  S $P(SCSPACE," ",80)=""
  1.  ;   SCTMAR - ARRAY OF TEAMS (before & after)
  1.  S:SCTMAF SCTMAR(SCTMAF)=""
  1.  S:SCTMB4 SCTMAR(SCTMB4)=""
  1.  S:'SCTPAF SCSTAT="DELETED"
  1.  S:'SCTPB4 SCSTAT="NEW"
  1.  S:SCTPB4&SCTPAF SCSTAT="CHANGED"
  1.  S DFN=$S(SCSTAT="DELETED":+$G(^SCPT(404.42,+SCPTTPB4,0)),1:+$G(^SCPT(404.42,+SCPTTPAF,0)))
  1.  ;set xmy array for practitioners in positions receiving TMchg notices
  1.  G:'$$PCMMXMY^SCAPMC25(3,DFN,"SCTMAR","SCTPDT",0) END
  1.  ;D:'$G(DGQUIET) EN^DDIOL("Sending "_SCSTAT_" Patient-Position Assignment Message")
  1.  D PID^VADPT6
  1.  S SCPTNM=$P(^DPT(DFN,0),U,1)
  1.  S XMSUB=SCSTAT_" PATIENT-POSITION ASSIGNMENT for Patient ("_$E(SCPTNM,1)_$G(VA("BID"))_")",XMTEXT="^TMP($J,""SCTPXM"",",SCLNCNT=0
  1.  IF SCSTAT="NEW" D
  1.  .D SETLN("Current Patient Team Data:")
  1.  .D SETLN("==========================")
  1.  .F SCX=1:1:9 D
  1.  ..D SETLN($$TEXT(404.43,SCPTTPAF,SCX,SCSPACE,1))
  1.  IF SCSTAT="DELETED" D
  1.  .D SETLN("Previous Patient Team Data:")
  1.  .D SETLN("===========================")
  1.  .F SCX=1:1:9 S SCFLD=SCX*.01 D
  1.  ..D SETLN($$TEXT(404.43,SCPTTPB4,SCX,SCSPACE,1))
  1.  IF SCSTAT="CHANGED" D
  1.  .D SETLN("Fields: "_$E(SCSPACE,1,19)_"Previous Data:           Current Patient Data:")
  1.  .D SETLN("=======================================================================")
  1.  .F SCX=1:1:9 S SCFLD=SCX*.01 D
  1.  ..N SCLAB2,SCY,SCZ
  1.  ..S SCY=$$TEXT(404.43,SCPTTPB4,SCX,SCSPACE,1)
  1.  ..S:'$L(SCY) SCLAB2=2
  1.  ..S SCZ=$$TEXT(404.43,SCPTTPAF,SCX,SCSPACE,+$G(SCLAB2))
  1.  ..D:$L(SCY)!($L(SCZ)) SETLN(SCY_$E(SCSPACE,1,(52-$L(SCY)))_SCZ)
  1.  S SCLNCNT=$$PCMAIL^SCMCMM(DFN,"^TMP($J,""SCTPXM"")",DT)
  1.  S XMDUZ=$G(DUZ,.5)
  1.  D ^XMD
  1. END K ^TMP($J,"SCTPXM")
  1.  Q
  1.  ;
  1. SETLN(TEXT) ;
  1.  Q:$G(TEXT)=""
  1.  ; increments SCLNCNT, adds text to scTPxm(sclncnt)
  1.  S SCLNCNT=SCLNCNT+1
  1.  S ^TMP($J,"SCTPXM",SCLNCNT)=TEXT
  1.  Q
  1.  ;
  1. TEXT(SCFILE,SCNODE,SCPC,SCSPACE,SCLAB) ;returns fldname & external value
  1.  ;returns fldname & external value
  1.  ;   Note- Only works for non wp fields of standard numbering conventions
  1.  ;   SCFLILE =FILENUM
  1.  ;   SCNODE  = 0 NODE
  1.  ;   SCPC    = piece of node
  1.  ;   SCSPACE = 80 SPACES
  1.  ;   SCLAB = 1 if print field name
  1.  N SCX,SCINT,SCFLD
  1.  S SCX=""
  1.  S SCINT=$P(SCNODE,U,SCPC)
  1.  G:SCINT="" QTTXT
  1.  S SCFLD=SCPC*.01
  1.  ;;;
  1.  IF $G(SCLAB) D
  1.  .S SCX=$$DDNAME^SCMCRU(SCFILE,SCFLD)_":"
  1.  .S:$G(SCLAB)=1 SCX=SCX_$E(SCSPACE,1,(27-$L(SCX)))
  1.  .S:$G(SCLAB)=2 SCX=SCX_$E(SCSPACE,1,(52-$L(SCX)))
  1.  S:SCINT]"" SCX=SCX_$$EXTERNAL^DILFD(SCFILE,SCFLD,"",SCINT)
  1. QTTXT Q SCX
  1. DDNAME(FILE,FIELD) ;return the fieldname
  1.  N SCX
  1.  D FIELD^DID(FILE,FIELD,"","LABEL","SCX")
  1.  Q $G(SCX("LABEL"))
  1.  ;
  1. MAILLST(SCTP,SCFIELDA,SCDATE,SCNEWTP,SCOLDTP,SCBADTP) ;
  1.  ; Input:
  1.  ;    SCTP     - Pointer to Team Position File (#404.57)
  1.  ;    SCFIELDA - Field array with internal values
  1.  ;    SCDATE   - Effective Date
  1.  ;    SCNEWTP  - DFN array of newly assigned to position
  1.  ;    SCOLDTP  - DFN array of previously assigned to position
  1.  ;    SCBADTP  - DFN array of patients unassignable to position
  1.  ;
  1.  G:$G(SCNOMAIL) QTMULT  ;- flag can be set to stop message generation
  1.  G:'$D(SCNEWTP) QTMULT
  1.  G:'$O(@SCNEWTP@(0)) QTMULT  ;if no new assignments
  1.  N XMDUZ,XMY,XMSUB,XMTEXT,VA,VAERR,XMZ,Y,SCTPDT,ZTQUEUED
  1.  N SCTPNM,DFN,SCOK,SCPTNM,SCFLD,SCNODE,SCNDX,SCSPACE,SCE,SCB,SCTMNM,SCDELTEM,SCDETAIL
  1.  S ZTQUEUED=1
  1.  S SCDELTEM=1 ;ok to delete tmp global
  1.  IF $D(SCFIELDA) D
  1.  .IF $D(SCFIELDA(.03)) S SCB=SCFIELDA(.03)
  1.  .IF $D(SCFIELDA(.04)) S SCE=SCFIELDA(.04)
  1.  S SCB=$G(SCB,DT)
  1.  S SCE=$G(SCE,DT)
  1.  S $P(SCSPACE," ",80)=""
  1.  S SCTPDT("BEGIN")=$S(SCB<SCDATE:SCB,1:SCDATE)
  1.  S SCTPDT("END")=$S(SCE>SCDATE:SCE,1:SCDATE)
  1.  S SCTPDT("INCL")=0
  1.  S SCTPNM=$P($G(^SCTM(404.57,+SCTP,0)),U,1)
  1.  S XMSUB="Multiple PATIENT-POSITION ASSIGNMENT for "_SCTPNM,XMTEXT="^TMP($J,""SCTPXM"",",SCLNCNT=0
  1.  D:'$G(DGQUIET) EN^DDIOL("Sending Multiple Patient-Position Assignment Message")
  1.  S SCOK=1
  1.  S SCTPNM=$P($G(^SCTM(404.57,+SCTP,0)),U,1)
  1.  S SCTMNM=$P($G(^SCTM(404.51,+$P($G(^SCTM(404.57,+SCTP,0)),U,2),0)),U,1)
  1.  D SETLN("Team:                  "_SCTMNM)
  1.  D SETLN("Position:              "_SCTPNM)
  1.  S Y=SCDATE X ^DD("DD")
  1.  D SETLN("Effective Date:        "_Y)
  1.  D SETLN(" ")
  1.  IF $D(SCFIELDA) D
  1.  .F SCNDX=1:1:14 S SCFLD=SCNDX*.01 IF $D(SCFIELDA(SCFLD)) D
  1.  ..S $P(SCNODE,U,SCNDX)=SCFIELDA(SCFLD)
  1.  ..D SETLN($$TEXT(404.43,SCNODE,SCNDX,SCSPACE,1))
  1.  D SETLN(" ")
  1.  D SETLN("There has been a new position assignment for the following patients:")
  1.  S DFN=0
  1. NEW F  S DFN=$O(@SCNEWTP@(DFN)) Q:'DFN  D
  1.  .S:$$PCMMXMY^SCAPMC25(3,DFN,,"SCTPDT",0) SCOK=0
  1.  .D PID^VADPT6
  1.  .S SCPTNM=$P(^DPT(DFN,0),U,1)
  1.  .S ^TMP("SCTP MAIL LST",$J,SCTP,1,DFN)=("    "_SCPTNM_" ("_$G(VA("PID"))_")")
  1.  .S ^TMP("SCTP MAIL LST",$J,SCTP,1,"B",SCPTNM,DFN)=""
  1.  S SCPTNM=""
  1.  F  S SCPTNM=$O(^TMP("SCTP MAIL LST",$J,SCTP,1,"B",SCPTNM)) Q:SCPTNM']""  D
  1.  .S DFN=0
  1.  .F  S DFN=$O(^TMP("SCTP MAIL LST",$J,SCTP,1,"B",SCPTNM,DFN)) Q:'DFN  D
  1.  ..S SCDETAIL=$G(^TMP("SCTP MAIL LST",$J,SCTP,1,DFN)) Q:SCDETAIL']""  D SETLN(SCDETAIL)
  1. BAD IF $O(@SCBADTP@(0)) D
  1.  .D SETLN(" ")
  1.  .D SETLN("There has been NO new position assignment for the following patients:")
  1.  .S DFN=0
  1.  .F  S DFN=$O(@SCBADTP@(DFN)) Q:'DFN  D
  1.  ..S:$$PCMMXMY^SCAPMC25(3,DFN,,"SCTPDT",0) SCOK=0
  1.  ..S SCPTNM=$P(^DPT(DFN,0),U,1)
  1.  ..D PID^VADPT6
  1.  ..S ^TMP("SCTP MAIL LST",$J,SCTP,2,DFN)=("    "_SCPTNM_" ("_$G(VA("PID"))_")")
  1.  ..S ^TMP("SCTP MAIL LST",$J,SCTP,2,"B",SCPTNM,DFN)=""
  1.  .S SCPTNM=""
  1.  .F  S SCPTNM=$O(^TMP("SCTP MAIL LST",$J,SCTP,2,"B",SCPTNM)) Q:SCPTNM']""  D
  1.  ..S DFN=0
  1.  ..F  S DFN=$O(^TMP("SCTP MAIL LST",$J,SCTP,2,"B",SCPTNM,DFN)) Q:'DFN  D
  1.  ...S SCDETAIL=$G(^TMP("SCTP MAIL LST",$J,SCTP,2,DFN)) Q:SCDETAIL']""  D SETLN(SCDETAIL)
  1.  S XMDUZ=$G(DUZ,.5)
  1.  D ^XMD
  1. QTMULT K:$G(SCDELTEM) ^TMP("SCTP MAIL LST",$J,SCTP)
  1.  K ^TMP($J,"SCTPXM")
  1.  Q