Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCMSP1

SCMSP1.m

Go to the documentation of this file. 
  1. SCMSP1 ;ALB/JRP - POST INIT ROUTINE;07-JUN-1996
  1.  ;;5.3;Scheduling;**44**;AUG 13, 1993
  1.  ;
  1. FIXEVNT ;Enable Ambulatory Care event handler
  1.  ;
  1.  ;Input  : None
  1.  ;Output : None
  1.  ;Notes  : This is a KIDS complient check point
  1.  ;
  1.  ;Declare variables
  1.  N DIC,DIE,DA,DR,X,Y,DTOUT,DUOUT,MSGTXT,PTRPROT
  1.  D BMES^XPDUTL(">>> Enabling Ambulatory Care event handler")
  1.  ;Find protocol
  1.  S PTRPROT=+$O(^ORD(101,"B","SCDX AMBCARE EVENT",""))
  1.  I ('PTRPROT) D  Q
  1.  .S MSGTXT(1)="    ** Unable to find SCDX AMBCARE EVENT in PROTOCOL file (#101)"
  1.  .S MSGTXT(2)="    ** Entry must be manually created"
  1.  .D MES^XPDUTL(.MSGTXT)
  1.  ;Enable protocol
  1.  S DIE="^ORD(101,"
  1.  S DA=PTRPROT
  1.  S DR="2///@"
  1.  D ^DIE
  1.  ;Done
  1.  Q
  1.  ;
  1. FIXSRVR ;Fix entry in PROTOCOL file (#101) for server protocol
  1.  ;
  1.  ;Input  : None
  1.  ;Output : None
  1.  ;Notes  : This is a KIDS complient check point
  1.  ;
  1.  ;Declare variables
  1.  N DIC,DIE,DA,DR,X,Y,DTOUT,DUOUT,MSGTXT,PTRPROT,PTRAPP
  1.  D BMES^XPDUTL(">>> Correcting entry in PROTOCOL file (#101) for server protocol")
  1.  ;Find server protocol
  1.  S PTRPROT=+$O(^ORD(101,"B","SCDX AMBCARE SEND SERVER FOR ADT-Z00",""))
  1.  I ('PTRPROT) D  Q
  1.  .S MSGTXT(1)="    ** Unable to find SCDX AMBCARE SEND SERVER FOR ADT-Z00"
  1.  .S MSGTXT(2)="       in PROTOCOL file (#101)"
  1.  .S MSGTXT(3)="    ** Entry must be manually created"
  1.  .D MES^XPDUTL(.MSGTXT)
  1.  ;Find server application
  1.  S PTRAPP=+$O(^HL(771,"B","AMBCARE-DHCP",""))
  1.  I ('PTRAPP) D  Q
  1.  .S MSGTXT(1)="    ** Unable to find AMBCARE-DHCP in HL7 APPLICATION file (#771)"
  1.  .S MSGTXT(2)="    ** Entry must be manually created and attached to"
  1.  .S MSGTXT(3)="       the SCDX AMBCARE SEND SERVER FOR ADT-Z00 protocol"
  1.  .D MES^XPDUTL(.MSGTXT)
  1.  ;Fix entry
  1.  S DIE="^ORD(101,"
  1.  S DA=PTRPROT
  1.  S DR="2///@;770.1////^S X=PTRAPP;770.3///ADT;770.11///ADT;770.4///Z00;770.8///NE;770.9///AL;770.95///2.2"
  1.  D ^DIE
  1.  ;Done
  1.  Q
  1.  ;
  1. FIXCLNT ;Fix entry in PROTOCOL file (#101) for client protocol
  1.  ;
  1.  ;Input  : None
  1.  ;Output : None
  1.  ;Notes  : This is a KIDS complient check point
  1.  ;
  1.  ;Declare variables
  1.  N DIC,DIE,DA,DR,X,Y,DTOUT,DUOUT,MSGTXT,PTRPROT,PTRAPP,PTRLINK
  1.  D BMES^XPDUTL(">>> Correcting entry in PROTOCOL file (#101) for client protocol")
  1.  ;Find client protocol
  1.  S PTRPROT=+$O(^ORD(101,"B","SCDX AMBCARE SEND CLIENT FOR ADT-Z00",""))
  1.  I ('PTRPROT) D  Q
  1.  .S MSGTXT(1)="    ** Unable to find SCDX AMBCARE SEND CLIENT FOR ADT-Z00"
  1.  .S MSGTXT(2)="       in PROTOCOL file (#101)"
  1.  .S MSGTXT(3)="    ** Entry must be manually created"
  1.  .D MES^XPDUTL(.MSGTXT)
  1.  ;Find client application
  1.  S PTRAPP=+$O(^HL(771,"B","NPCD-AAC",""))
  1.  I ('PTRAPP) D  Q
  1.  .S MSGTXT(1)="    ** Unable to find NPCD-AAC in HL7 APPLICATION file (#771)"
  1.  .S MSGTXT(2)="    ** Entry must be manually created and attached to"
  1.  .S MSGTXT(3)="       the SCDX AMBCARE SEND CLIENT FOR ADT-Z00 protocol"
  1.  .D MES^XPDUTL(.MSGTXT)
  1.  ;Find logical link
  1.  S PTRLINK=+$O(^HLCS(870,"B","AMB-CARE",0))
  1.  I ('PTRLINK) D  Q
  1.  .S MSGTXT(1)="    ** Unable to find AMB-CARE in HL LOGICAL LINK file (#870)"
  1.  .S MSGTXT(2)="    ** Entry must be manually created and attached to"
  1.  .S MSGTXT(3)="       the SCDX AMBCARE SEND CLIENT FOR ADT-Z00 protocol"
  1.  .D MES^XPDUTL(.MSGTXT)
  1.  ;Fix entry
  1.  S DIE="^ORD(101,"
  1.  S DA=PTRPROT
  1.  S DR="2///@;770.2////^S X=PTRAPP;770.3///ADT;770.11///ADT;770.4///Z00;770.7////^S X=PTRLINK;770.95///2.2"
  1.  D ^DIE
  1.  Q