Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCRPBK11

SCRPBK11.m

Go to the documentation of this file. 
  1. SCRPBK11 ;MJK/ALB - RPC Broker Utilities ; 27 FEB 96
  1.  ;;5.3;Scheduling;**41,520**;AUG 13, 1993;Build 26
  1.  ;
  1. GETSEL(SCDATA,SCTYPE,SCIEN) ; 
  1.  ; -- get SELECTION entity data for details form
  1.  ;
  1.  ;  input:  SCTYPE       := type of autolink (DIVISIOND, TEAM, ectc.)
  1.  ;          SCIEN        := ien of entity
  1.  ; output:  SCDATA(1..n) := info about entity
  1.  ;
  1.  ; -- SEE BOTTOM OF SCRPBK FOR VARIABLE DEFINITIONS
  1.  ;
  1.  ; Related RPC: SCRP FILE ENTRY GETSELECTION
  1.  ;                    
  1.  N SC0,SCI,SCINC
  1.  S SCINC=0,SCID=+SCIEN
  1.  ;
  1.  IF SCTYPE="DIVISION" D DIV G GETSELQ
  1.  ;
  1.  IF SCTYPE="TEAM" D TEAM G GETSELQ
  1.  ;
  1.  IF SCTYPE="PRACTITIONER" D PRAC G GETSELQ
  1.  ;
  1.  IF SCTYPE="ROLE" D ROLE G GETSELQ
  1.  ;
  1.  IF SCTYPE="CLINIC" D CLIN G GETSELQ
  1.  ;
  1.  IF SCTYPE="USERCLASS" D USER G GETSELQ
  1.  ;
  1. GETSELQ Q
  1.  ;
  1. SET(X,INC,SCDATA) ; -- set value in return array
  1.  S INC=$G(INC)+1,SCDATA(INC)=X
  1.  Q
  1.  ;
  1. DIV ; -- get division details
  1.  D SET("Teams in  Division:",.SCINC,.SCDATA)
  1.  D SET("------------------",.SCINC,.SCDATA)
  1.  S SCI=0 F  S SCI=$O(^SCTM(404.51,"AINST",SCID,SCI)) Q:'SCI  D
  1.  . D SET($P($G(^SCTM(404.51,SCI,0)),U),.SCINC,.SCDATA)
  1.  Q
  1.  ;
  1. TEAM ; -- get team description
  1.  N SC,SCFLE,SCIEN,SCDEF
  1.  S SCFLE=404.51,SCIEN=SCID_",",SCDEF="<none specified>"
  1.  D GETS^DIQ(SCFLE,SCID_",",50,"","SC")
  1.  D SET("Team Description:",.SCINC,.SCDATA)
  1.  D SET("-----------------",.SCINC,.SCDATA)
  1.  IF $O(SC(SCFLE,SCIEN,50,0)) D
  1.  . S SCI=0 F  S SCI=$O(SC(SCFLE,SCIEN,50,SCI)) Q:'SCI  S X=SC(SCFLE,SCIEN,50,SCI) D
  1.  . . D SET(X,.SCINC,.SCDATA)
  1.  ELSE  D
  1.  . D SET(SCDEF,.SCINC,.SCDATA)
  1.  Q
  1.  ;
  1. PRAC ; -- get practitioner details
  1.  N SC,SCFLE,SCIEN,SCDEF
  1.  S SCFLE=200,SCIEN=SCID_",",SCDEF="<none specified>"
  1.  D GETS^DIQ(SCFLE,SCID_",","1;8;28","","SC")
  1.  D SET(" Initials: "_$S($G(SC(SCFLE,SCIEN,1))]"":SC(SCFLE,SCIEN,1),1:SCDEF),.SCINC,.SCDATA)
  1.  D SET("Mail Code: "_$S($G(SC(SCFLE,SCIEN,28))]"":SC(SCFLE,SCIEN,28),1:SCDEF),.SCINC,.SCDATA)
  1.  D SET("    Title: "_$S($G(SC(SCFLE,SCIEN,8))]"":SC(SCFLE,SCIEN,8),1:SCDEF),.SCINC,.SCDATA)
  1.  Q
  1.  ;
  1. ROLE ; -- get standard role description
  1.  N SC,SCFLE,SCIEN,SCDEF
  1.  S SCFLE=403.46,SCIEN=SCID_",",SCDEF="<none specified>"
  1.  D GETS^DIQ(SCFLE,SCID_",",1,"","SC")
  1.  D SET("Role Description:",.SCINC,.SCDATA)
  1.  D SET("-----------------",.SCINC,.SCDATA)
  1.  IF $O(SC(SCFLE,SCIEN,1,0)) D
  1.  . S SCI=0 F  S SCI=$O(SC(SCFLE,SCIEN,1,SCI)) Q:'SCI  S X=SC(SCFLE,SCIEN,1,SCI) D
  1.  . . D SET(X,.SCINC,.SCDATA)
  1.  ELSE  D
  1.  . D SET(SCDEF,.SCINC,.SCDATA)
  1.  Q
  1.  ;
  1. CLIN ; -- get clinic details
  1.  N SC,SCFLE,SCIEN,SCDEF
  1.  S SCFLE=44,SCIEN=SCID_",",SCDEF="<none specified>"
  1.  D GETS^DIQ(SCFLE,SCID_",","1;3.5","","SC")
  1.  D SET("Abbreviation: "_$S($G(SC(SCFLE,SCIEN,1))]"":SC(SCFLE,SCIEN,1),1:SCDEF),.SCINC,.SCDATA)
  1.  D SET("    Division: "_$S($G(SC(SCFLE,SCIEN,3.5))]"":SC(SCFLE,SCIEN,3.5),1:SCDEF),.SCINC,.SCDATA)
  1.  D SET(" ",.SCINC,.SCDATA)
  1.  D SET("Associated Teams and Positions:",.SCINC,.SCDATA)
  1.  D SET("-------------------------------",.SCINC,.SCDATA)
  1.  S SCI=0 F  S SCI=$O(^SCTM(404.57,"E",SCID,SCI)) Q:'SCI  D
  1.  . S X=$G(^SCTM(404.57,SCI,0))
  1.  . D SET("      Team: "_$P($G(^SCTM(404.51,+$P(X,U,2),0)),U),.SCINC,.SCDATA)
  1.  . D SET("  Position: "_$P(X,U),.SCINC,.SCDATA)
  1.  . D SET(" ",.SCINC,.SCDATA)
  1.  Q
  1.  ;
  1. USER ; -- get user class details
  1.  D SET("No additional information available at this time. ",.SCINC,.SCDATA)
  1.  Q
  1.  ;