Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCRPPRAH

SCRPPRAH.m

Go to the documentation of this file. 
  1. SCRPPRAH ;ALB/DJS - Preceptor Assignment History Extract for PCMMR Data Validation; 04/18/14
  1.  ;;5.3;Scheduling;**620**;AUG 13, 1993;Build 11
  1.  ;
  1. ENTER ; Entry point
  1.  ; 
  1.  ; Extract file will be a delimited text file (.TXT) that will provide information for PCMM data validation
  1.  ; Delimiter is a pipe ("|") character
  1.  ;
  1.  ; FILE OUTPUT:
  1.  ;
  1.  ; STANUM - Station #
  1.  ; PREAHIEN - IEN of Preceptor Assignment History
  1.  ; TPIEN - IEN of Team Position
  1.  ; TMPOS - Team Position
  1.  ; EFFDT - Effective Date
  1.  ; STATUS - Status
  1.  ; STATRSN - Status Reason
  1.  ; PRCTPIEN - IEN of Preceptor Team Position
  1.  ; PRETMPOS - Preceptor Team Position
  1.  ; DATEENT - Date/Time Entered
  1.  ; PRECPTNM - Preceptor Name
  1.  ;
  1.  N SCMCPATH,SCMCHFS,SCMCERR,SCMCMODE,MSG,IOF
  1.  N SCDATA,SCIENS,STANUM,PREAHIEN,TPIEN,TMPOS,EFFDT,STATUS,STATRSN,PRCTPIEN,PRETMPOS,DATEENT,PRECPTNM,SITE
  1.  S SITE=$$SITE^VASITE,STANUM=$P(SITE,"^",3)
  1.  S SCMCPATH=$$DEFDIR^%ZISH(),SCMCHFS=STANUM_"_PCMMPRECEPTORASSIGNMENTHISTORY.TXT",SCMCERR=0 U 0 W !!,SCMCPATH
  1.  D HFSOPEN("SCMCRP",SCMCPATH,SCMCHFS,"W") I SCMCERR G END
  1.  U IO
  1.  D COLHDR,SETREC G END
  1.  ;
  1. SETREC  ;$O through preceptor assignment history file
  1.     S PREAHIEN=0
  1.  F  S PREAHIEN=$O(^SCTM(404.53,PREAHIEN)) Q:PREAHIEN=""!(PREAHIEN'?.N)  D
  1.  .K SCDATA
  1.  .S SCIENS=+$G(PREAHIEN)_","
  1.  .D GETS^DIQ(404.53,SCIENS,".01;.02;.04;.05;.06;.07;.08;200","IE","SCDATA","")
  1.  .S TPIEN=$G(SCDATA(404.53,SCIENS,.01,"I"))
  1.  .S TMPOS=$G(SCDATA(404.53,SCIENS,.01,"E"))
  1.  .S EFFDT=$G(SCDATA(404.53,SCIENS,.02,"E"))
  1.  .S STATUS=$G(SCDATA(404.53,SCIENS,.04,"E"))
  1.  .S STATRSN=$G(SCDATA(404.53,SCIENS,.05,"E"))
  1.  .S PRCTPIEN=$G(SCDATA(404.53,SCIENS,.06,"I"))
  1.  .S PRETMPOS=$G(SCDATA(404.53,SCIENS,.06,"E"))
  1.  .S DATEENT=$G(SCDATA(404.53,SCIENS,.08,"E"))
  1.  .S PRECPTNM=$G(SCDATA(404.53,SCIENS,200,"E"))
  1.  .W STANUM_"|"_PREAHIEN_"|"_TPIEN_"|"_TMPOS_"|"_EFFDT_"|"_STATUS_"|"_STATRSN_"|"_PRCTPIEN_"|"_PRETMPOS_"|"_DATEENT_"|"_PRECPTNM,!
  1.  Q
  1.  ;
  1. COLHDR ;Create column header for Preceptor Assignment History extract file
  1.  W "Station #|Prec. Assign. Hist. IEN|Team Position IEN|Team Position|Effective Date|Status|Status Reason|Preceptor Team Position IEN|Preceptor Team Position|Date Entered|Preceptor Name",!
  1.  Q
  1.  ;
  1. END D HFSCLOSE("SCMCRP",SCMCHFS)
  1.  N I
  1.  I '+SCMCERR D  Q  ;Create pipe delimited output if no errors
  1.  .S MSG=$NA(^TMP("SCMC",$J))
  1.  ;Replace "##FFFF##" with Form Feeds - code needed for LINUX environments
  1.  S I=0 F  S I=$O(^TMP("SCMC",$J,1,I)) Q:'I  D
  1.  .S:^TMP("SCMC",$J,1,I)["##FFFF##" ^TMP("SCMC",$J,1,I)=$P(^TMP("SCMC",$J,1,I),"##FFFF##")_$C(13,12)_$P(^TMP("SCMC",$J,1,I),"##FFFF##",2)
  1.  .S ^TMP("SCMC",$J,1,I)=^TMP("SCMC",$J,1,I)_$C(13)
  1.  .S:^TMP("SCMC",$J,1,I)["$END" ^TMP("SCMC",$J,1,I)=""
  1.  S MSG=$NA(^TMP("SCMC",$J))
  1.  Q
  1.  ;
  1. HFSOPEN(HANDLE,SCMCPATH,SCMCHFS,SCMCMODE) ; Open File
  1.  N POP
  1.  D OPEN^%ZISH(HANDLE,SCMCPATH,SCMCHFS,$G(SCMCMODE,"W")) D:POP  Q:POP
  1.  .S SCMCERR=1,^TMP("SCMC",$J,1)="0^Unable to open file "
  1.  S IOF="$$IOF^SCRPPRAH"   ;resets screen position and adds page break flag - added to deal with Linux environments.
  1.  Q
  1.  ;
  1. HFSCLOSE(HANDLE,SCMHFS) ;Close HFS and unload data
  1.  D CLOSE^%ZISH(HANDLE)
  1.  Q
  1.  ;
  1. IOF() ;used to reset position and insert page break flag when @IOF is executed.
  1.  S $X=0,$Y=0
  1.  Q "##FFFF##"_$C(13,10)
  1.  ;